Discussion :

[naniesnv]

Bonjour,

J'ai un fichier dans lequel j'importe des données dans le 1er onglet. Le nombre de lignes étant variable, j'ai créé des plages avec par exemple "plage_type" =DECALER('Actions usagers'!$I$1;;;NBVAL('Actions usagers'!$A:$A);1)

Dans mon 2ème onglet, j'ai mes stats avec des formules qui font appels à ces plages.

Ex (les données dans les lignes 6,7,8 et dans les colonnes E,G,H sont "en dur") :

=SOMMEPROD((plage_realisation=$G$6)*(plage_type=$E9))+SOMMEPROD((plage_realisation=$G$7)*(plage_type=$E9))+SOMMEPROD((plage_realisation=$G$8)*(plage_type=$E9))+SOMMEPROD((plage_realisation=$G$6)*(plage_type="")*(plage_types=$E9))+SOMMEPROD((plage_realisation=$G$7)*(plage_type="")*(plage_types=$E9))+SOMMEPROD((plage_realisation=$G$8)*(plage_type="")*(plage_types=$E9)

Quand on décompose cette formule, je vois que c'est toujours pareil et je me demande s'il n'y a pas possibilité de la simplifier (avec un OU?).

Merci à tout le monte !

Parce que j'en suis à créer ce genre de formule :/
=SOMMEPROD((plage_realisation=I$6)*(plage_type=$E12)*(plage_participation=I$9))+SOMMEPROD((plage_realisation=I$6)*(plage_type=$E12)*(plage_participation=I$10))+SOMMEPROD((plage_realisation=I$6)*(plage_type=$E12)*(plage_participation=I$11))+SOMMEPROD((plage_realisation=I$7)*(plage_type=$E12)*(plage_participation=I$9))+SOMMEPROD((plage_realisation=I$7)*(plage_type=$E12)*(plage_participation=I$10))+SOMMEPROD((plage_realisation=I$7)*(plage_type=$E12)*(plage_participation=I$11))+SOMMEPROD((plage_realisation=I$8)*(plage_type=$E12)*(plage_participation=I$9))+SOMMEPROD((plage_realisation=I$8)*(plage_type=$E12)*(plage_participation=I$10))+SOMMEPROD((plage_realisation=I$8)*(plage_type=$E12)*(plage_participation=I$11))+SOMMEPROD((plage_realisation=I$6)*(plage_type="")*(plage_types=$E12)*(plage_participation=I$9))+SOMMEPROD((plage_realisation=I$6)*(plage_type="")*(plage_types=$E12)*(plage_participation=I$10))+SOMMEPROD((plage_realisation=I$6)*(plage_type="")*(plage_types=$E12)*(plage_participation=I$11))+SOMMEPROD((plage_realisation=I$7)*(plage_type="")*(plage_types=$E12)*(plage_participation=I$9))+SOMMEPROD((plage_realisation=I$7)*(plage_type="")*(plage_types=$E12)*(plage_participation=I$10))+SOMMEPROD((plage_realisation=I$7)*(plage_type="")*(plage_types=$E12)*(plage_participation=I$11))
+SOMMEPROD((plage_realisation=I$8)*(plage_type="")*(plage_types=$E12)*(plage_participation=I$9))+SOMMEPROD((plage_realisation=I$8)*(plage_type="")*(plage_types=$E12)*(plage_participation=I$10))+SOMMEPROD((plage_realisation=I$8)*(plage_type="")*(plage_types=$E12)*(plage_participation=I$11))

[papouclo]

Bonjour,

je me demande s'il n'y a pas possibilité de la simplifier (avec un OU?)

Les connecteurs logiques OU,ET « dysfonctionnent » dans les formules matricielles et j’ai bien peur qu’il en soit de même dans une formule employant la fonction SOMMEPROD.
Remplacer la première formule par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(ESTNUM(EQUIV(plage_realisation;$G$6:$G$8;0)) *(( plage_type =$E$9)+( plage_type ="")*( plage_types =$E$9)))

et la deuxième formule par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(ESTNUM(EQUIV(plage_realisation;$I$6:$I$8;0))*ESTNUM(EQUIV(plage_participation;$I$9:$I$11;0))*(( plage_type =$E$12)+( plage_type ="")*( plage_types =$E$12)))

Cordialement
Claude

[naniesnv]

Bonjour,
Les connecteurs logiques OU,ET « dysfonctionnent » dans les formules matricielles et j’ai bien peur qu’il en soit de même dans une formule employant la fonction SOMMEPROD.
Remplacer la première formule par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(ESTNUM(EQUIV(plage_realisation;$G$6:$G$8;0)) *(( plage_type =$E$9)+( plage_type ="")*( plage_types =$E$9)))

et la deuxième formule par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(ESTNUM(EQUIV(plage_realisation;$I$6:$I$8;0))*ESTNUM(EQUIV(plage_participation;$I$9:$I$11;0))*(( plage_type =$E$12)+( plage_type ="")*( plage_types =$E$12)))

Cordialement
Claude

Bonjour Claude et merci, je vais tenter vos formules.
Si elles fonctionnent, est-ce que vous cherchez un boulot ? ^^