Discussion :

[Alex1788]

Bonjour,

Je souhaite à partir d'une réponse donnée par l'utilisateur dans un userform déterminer une liste de données. Dans la colonne F, je cherche la donnée et quand elle y est, j'agrémente ma liste avec le texte de la colonne G de la même ligne.
Cette liste sera ensuite dans une listbox dans un autre userform.

Dès que je lance ma macro j'ai l'erreur d'exécution 13 : incompatibilité de type et je n'arrive pas à trouver le probleme.

VOici mon code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub userform_initialize()
 
Worksheets("Cartographie").Select
Dim nompilote As String
i = 3
Do While Cells(i, 15) <> identifiant
i = i + 1
Loop
nompilote = Cells(i, 14) 'définition le pilote en fonction de l'identifiant
 
Worksheets("Suivi des documents").Activate
Dim j, k As String
Dim listetitre(7 To 800) As Integer
For j = 7 To 800
    If Cells(j, 6).Text = nompilote Then
    listetitre(j) = Cells(j, 7).Text
    End If     
   Me.ListBox1.AddItem listetitre(k)
Next j
 End Sub

Merci d'avance

[halaster08]

Bonjour, pourrais-tu baliser ton code? (avec le bouton #) Car sinon c'est difficile à lire.
Sur quelle ligne obtient tu cette erreur?
La variable identifiant n'est pas renseignée c'est normal?

[Alex1788]

désolée c'est la première fois que je participe à une discussion

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub userform_initialize()
 
Worksheets("Cartographie").Select
Dim nompilote As String
 
i = 3
Do While Cells(i, 15) <> identifiant
i = i + 1
Loop
nompilote = Cells(i, 14) 'définition le pilote en fonction de l'identifiant
 
Worksheets("Suivi des documents").Activate
Dim j, k As String
Dim listetitre(7 To 800) As Integer
 
For j = 7 To 800
    If Cells(j, 6).Text = nompilote Then
    listetitre(j) = Cells(j, 7).Text
    End If      
   Me.ListBox1.AddItem listetitre(k)
Next j

Ca fait parti du problème, je n'ai aucune ligne surlignée.
LA variable identifiant est déclarée dans un autre module en public.

[halaster08]

Ca fait parti du problème, je n'ai aucune ligne surlignée.

Lance le code en mode pas à pas (touche F8) tu verras alors où il s'arrête.

LA variable identifiant est déclarée dans un autre module en public.

Si tu ne l'as pas déjà affiché dans le menu: View -> Locals Window
Tu peux voir le type et la valeur de chaque variable au moment de l'erreur.
Vu l'erreur indiquée tu as surement une variable mal renseignée.

Ps: je ne suis pas expert en variable public mais ne faut il pas qu'elle soit déclarée dans le même module?

Edit: Les balises codes ça aide, je viens de voir ça:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Dim listetitre(7 To 800) As Integer    
listetitre(j) = Cells(j, 7).Text

[unparia]

Bonjour

En plus :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Dim j, k As String '----> k est donc de type string
Dim listetitre(7 To 800) As Integer  '---> listetitrre est donc un tableau dynamique
For j = 7 To 800
  If Cells(j, 6).Text = nompilote Then
    listetitre(j) = Cells(j, 7).Text
  End If
  Me.ListBox1.AddItem listetitre(k)  ' ------>> k ne saurait être de type string (un index n'est pas de type string)
Next j

J'ajoute que ton code est étrange, dans la mesure ou k est toujours = 0, puisque non initialisé !

[Theze]

Bonjour,

Je vois bien l'erreur due à une valeur de type String affectée à ton tableau ce qui bien évidemment génère une erreur car tu le déclare "Integer". Donc, dans un premier temps pour simplifier déclare-le Variant pour voir si l'erreur disparaît et ensuite, je verrai ton code plutôt de cette façon :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
 
Private Sub UserForm_Initialize()
 
    Dim Identifiant As String
 
    Dim ListeTitre()
    Dim NomPilote As String
    Dim I As Integer
    Dim J As Integer
    Dim K As Integer
 
    I = 3
 
    With Worksheets("Cartographie")
 
        Do While .Cells(I, 15) <> Identifiant
            I = I + 1
        Loop
 
        NomPilote = .Cells(I, 14) 'définition le pilote en fonction de l'identifiant
 
    End With
 
    With Worksheets("Suivi des documents")
 
        For J = 7 To 800
 
            If .Cells(J, 6).Text = NomPilote Then
 
                K = K + 1
                ReDim Preserve ListeTitre(1 To K)
                ListeTitre(K) = .Cells(J, 7).Text
 
            End If
 
        Next J
 
    End With
 
    Me.ListBox1.List = ListeTitre()
 
End Sub

[Alex1788]

Ps: je ne suis pas expert en variable public mais ne faut il pas qu'elle soit déclarée dans le même module?

Quand tu déclares en public tout le programme peut utiliser tes variables. J'ai pour habitude de créer un module avec toutes mes variables public au lieu de les déclarer à chaque module.

[unparia]

Bonjour Alex1788

Quand tu déclares en public tout le programme peut utiliser tes variables. J'ai pour habitude de créer un module avec toutes mes variables public au lieu de les déclarer à chaque module.

Fort mauvaise habitude. Il faut savoir à la fois être économe et raison garder.
On ne déclare public que ce qui est nécessaire. (un sou, c'est un sou).