Discussion :

[Jibjab]

Bonjour,
Certains me diront que c'est un sujet redondant.
Effectivement j'ai vu des posts en ce sens, mais je n'ai pas réussi à adapter le code à mon feuille / mon classeur.

Je vais tenter de décrire précisément mes attentes.

J'aimerais que ma colonne "Client" et la colonne "N° de compte" se remplissent automatiquement si l'un OU l'autre est renseigné.

Ils sont dans la feuille "Liste" de mon classeur.

J'ai une feuille "Données" dans laquelle se situe ma matrice (B6:C949) colonne B les noms des clients et colonne C les numéros de compte associés;

J'ai besoin de traiter ces infos, J'ai donc des validations de données. ce qui empêche de mettre n'importe quel nom de client, il doit figurer dans la liste. Idem pour les numéros.

http://www.developpez.net/forums/d15...ction-d-liste/

J'ai tenté d'adapter le code du lien ci dessus, mais à l'exécution de la macro rien ne se passe... Elle est bien dans le module de la feuille "Liste".

Merci d'avance pour votre aide.

[Theze]

Bonjour,

A mettre dans le module de la feuille où tu veux inscrire le nom du client et son n° de compte. Les colonnes cibles sont B (pour les noms) et C (pour les n° de compte) comme dans la feuille "Données", si différent, adapte :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
 
Private Sub Worksheet_Change(ByVal Target As Range)
 
    Dim Plage As Range
    Dim Cel As Range
 
    If Target.Count > 1 Then Exit Sub
 
    If Target.Column = 2 Then 'ici, colonne B pour la colonne "Clients"
 
        'défini la plage sur la colonne B de la feuille "Données"
        With Worksheets("Données"): Set Plage = .Range(.Cells(1, 2), .Cells(.Rows.Count, 2).End(xlUp)): End With
 
        'effectue la recherche du client. Attention, si plusieurs clients ayant le même nom, le premier trouvé sera pris en compte !
        Set Cel = Plage.Find(Target.Value, , xlValues, xlWhole)
 
        'si trouvé, inscrit le N° de compte
        If Not Cel Is Nothing Then Target.Offset(, 1) = Cel.Offset(, 1).Value
 
    End If
 
    If Target.Column = 3 Then 'ici, colonne C pour la colonne "N° de compte"
 
        'défini la plage sur la colonne C de la feuille "Données"
        With Worksheets("Données"): Set Plage = .Range(.Cells(1, 3), .Cells(.Rows.Count, 3).End(xlUp)): End With
 
        'effectue la recherche du n° de compte. Ici pas de problème, les n° de compte étant uniques !
        Set Cel = Plage.Find(Target.Value, , xlValues, xlWhole)
 
        'si trouvé, inscrit le nom du client
        If Not Cel Is Nothing Then Target.Offset(, -1) = Cel.Offset(, -1).Value
 
    End If
 
End Sub