Discussion :

[Sabrina0021]

Bonjour à tous,

J'étais assez fière de mon petit programme qui ouvre tous les fichiers (données de spectroscopie) d'un dossier et récupère la colonne 2 pour la coller dans un fichier de synthèse mais je viens de voir que lorsqu'il y a trop de fichiers à ouvrir le programme plante lors de l’exécution. Je suppose que j'utilise trop la mémoire mais je ne sais pas comment faire. Quelqu'un pourrait améliorer le code? pour info j'ai environ 500 fichiers à ouvrir

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Sub ouvrirfichiers()
 
    Dim Fichier As String
    Dim Chemin As String
    Dim Wb As Workbook
    Dim NB_SPECTRES As Integer
 
    Chemin = "C:\test\"
 
    Fichier = Dir(Chemin & "*.*")
 
    Do While Fichier <> ""
    Set Wb = Workbooks.Open(Chemin & Fichier)
 
 
    NB_SPECTRES = NB_SPECTRES + 1
 
    Columns("B:B").Select
    Selection.Copy
 
 
    Windows("programme_FTIR.xlsm").Activate
    Columns(NB_SPECTRES).Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    Application.CutCopyMode = False
 
    Wb.Close True
 
    Set Wb = Nothing
 
    Fichier = Dir
 
    Cells(1, NB_SPECTRES) = Fichier
 
    Loop
 
    ActiveWorkbook.Save
 
    End Sub

[Sabrina0021]

J'ai réussi, j'ai mis wb.close False et j'ai créé une autre variable nom_de_colonne au lieu de Fichier pour à la fin du programme

[joe.levrai]

Bonjour,

et en optimisant ainsi ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub ouvrirfichiers()
Dim Feuille_Destination As Worksheet
Dim NB_SPECTRES As Integer
Dim Fichier As String
Const Chemin As String = "C:\test\"
 
Set Feuille_Destination = Workbooks("programme_FTIR.xlsm").ActiveSheet
Fichier = Dir(Chemin & "*.*")
 
Application.ScreenUpdating = False
    Do While Fichier <> ""
        With Workbooks.Open(Chemin & Fichier)
            NB_SPECTRES = NB_SPECTRES + 1
            Feuille_Destination.Columns(NB_SPECTRES).Value = .ActiveSheet.Columns(2).Value
            .Close False
        End With
 
        Fichier = Dir
        Feuille_Destination.Cells(1, NB_SPECTRES).Value = Fichier
    Loop
Application.ScreenUpdating = True
 
Feuille_Destination.Parent.Save
End Sub

j'ai simplifié les variables, on n'utilise plus le copier-coller, le rafraichissement d'écran est arrêté, et on n'enregistre plus les fichiers sources en les fermant (ça ne sert à rien puisqu'ils ne sont pas modifiés)

[Sabrina0021]

Merci Joe pour les améliorations c'est plus clair et c'est stable.

J'ai encore eu un plantage après mes modifications mais avec tes corrections ça marche bien.

Par contre étonnamment c'est plus lent (même si le temps n'est pas un problème, cela à pris environ 5 minutes pour 450 fichiers)

[joe.levrai]

Oui c'est assez surprenant que ça soit plus long, dans la mesure où il n'y a plus de Select, Copy et Paste


après, 5 minutes pour les 450 fichiers qui sont ouverts puis fermés, ça reste honorable ... 0.7 secondes par fichier

peut être qu'en travaillant sur les classeurs fermés ça irait encore plus vite ? Mais pas sûr, puisque 450 connexions ADO à effectuer quand même
http://silkyroad.developpez.com/VBA/ClasseursFermes/