Discussion :

[Feupy]

Bonjour,

J'ai trouvé le code ci dessous pour supprimer les lignes de mon tableau lorsque les cellules de la colonne D sont égale à zéro.
Le traitement est beaucoup trop long, avez vous une astuce ?
Merci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub Sup()
    Dim compt as Integer
    compt = 2
    Do While compt <= 7000
        If Cells(compt,4).Value = 0 Then
            Cells(compt,4).EntireRow.Delete
        Else
            compt = compt + 1
        End if
    Loop
End Sub

[cerede2000]

Il faudrait commencer par désactiver le rafraîchissement de l'affichage pendant que tu supprime tes lignes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Sup()
    Dim compt As Integer
    Application.ScreenUpdating = False
 
    compt = 2
 
    Do While compt <= 7000
        If Cells(compt, 4).Value = 0 Then
            Cells(compt, 4).EntireRow.Delete
        Else
            compt = compt + 1
        End If
    Loop
 
    Application.ScreenUpdating = True
End Sub

Ensuite en appliquant un filtre pour n'avoir que les lignes vides d'un coup et obtenir une Range qui tu pourra supprimer d'un coup.

As tu des entêtes sur tes colonnes ?

[illight]

Bonjour,


Ta suppression risque de poser souci car tu fais une boucle progressive. Normalement, quand on supprime des lignes, il faut faire une boucle à l'envers :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Sup()
    Dim compt As long
    Application.ScreenUpdating = False
 
    compt = 7000
 
    Do While compt > 0
        If Cells(compt, 4).Value = 0 Then
            rows(compt).Delete
        Else
            compt = compt - 1
        End If
    Loop
 
    Application.ScreenUpdating = True
End Sub

Après, effectivement comme l'a dit la personne ci-dessus, le mieux serait de faire une filtre sur ta 4e colonne, de façon à avoir tous les 0 regroupés. Tu pourras alors supprimer toute une plage de lignes à supprimer d'un coup, plutôt que de faire ligne par ligne.

[Philippe Tulliez]

Bonjour,
Une autre solution qui évite la boucle, est l'utilisation de la méthode AdvancedFilter de l'objet Range, combinée avec la méthode Delete des cellules vides (SpecialCells(xlCellTypeVisible).EntireRow.Delete)
La suppression est instantanée

Voir exemple dans ce billet Excel VBA – Supprimer des lignes suivant critères avec la méthode AdvancedFilter
Pour en savoir plus sur les filtres avancés d'excel, lire ce tutoriel Les filtres avancés ou élaborés dans Excel

[casefayere]

Bonjour,
en m'excusant auprès de Philippe qui, j'en suis convaincu, a raison (j'avais preparé, alors) et pour apprendre la manip des variables tableaux, à adapter

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub Sup()
Dim Tbl, DerCel As Range, x As Long, Result(), i As Long, y As Long
With Sheets("Feuil1") 'à remplacer par le nom de ta feuille
  Set DerCel = .Range("D" & .Rows.Count).End(xlUp)
  ReDim Result(1 To DerCel.Row + 1, 1 To 4) '4 si 1ere colonne est en A, derniere colonne est D, 5 si E, 6 si F....
  Tbl = .Range("A2", DerCel) 'imaginons que ton tableau commence en A et termine en D, sinon .Range("A2", DerCel(1,5)) pour E etc.
  i = 1
  For x = 1 To UBound(Tbl, 1)
    If Val(Tbl(x, 4)) <> 0 Then
      For y = 1 To UBound(Tbl, 2)
        Result(i, y) = Tbl(x, y)
      Next y
      i = i + 1
    End If
  Next x
  .Range("A2", DerCel).ClearContents
  .Range("A2").Resize(UBound(Result, 1), UBound(Result, 2)) = Result
End With
End Sub

[Feupy]

Merci pour toutes vos réponses.

Je trouve que les traitements sont un peu long, j'ai opté pour un filtre avec suppression des lignes.

Encore merci !