Discussion :

[LeoPaul]

Bonjour

Ayant peu de notion VBA, je vais essayer d'être le plus explicite possible

J'ai deux feuilles, contenant des données, chaque ligne contient un numéro ID dans la colonne A4:A15000. Certaines lignes sont aussi copiée dans la feuille-2 (pour l'instant manuellement)
J'aimerais, lorsque je modifie une infos dans une ligne depuis ma comboBox de ma feuille-1, que la macro cherche si le numéro ID de la ligne se trouve déjà dans la feuille-2.
Si c'est le cas, elle me met à jour la ligne entière de la feuille-2, sinon elle me copie la nouvelle ligne dans la cellule A4 de la feuille-2 ( ce qui sous-entend que les autres lignes se décalent vers le bas )

pfuii!

merci de votre aide
LeoPaul

[BENNASR]

bonjour
début de piste à adapter sachant que chui débutant aussi en VBA

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub chercheEtCopié()
Dim plage As Range
Set plage = Sheets("feuil2").Range("A2:A" & [A65536].End(xlUp).Row)
MonCode = ComboBox1.Value
For Each Cell In plage
 If Cell.Value = MonCode Then
 MsgBox ("Code existe déja")
 Else
 'ton code pour remplir feuil2
 End If
 Next Cell
End Sub

[LeoPaul]

Bonjour

c'est justement là que je bloque, je n'ai aucune idée comment faire pour que la macro "remplace / met à jour" la ligne contenant déjà le m ID dans la feuille.2.

[thebenoit59]

Bonjour LeoPaul, bonjour Bennasr.

Je te joins un exemple.

Le principe est le suivant :

1) A l'initialisation on enregistre deux dictionary.
Le premier correspond aux ID de la Feuil1, la clé étant l'ID et l'item le n° de la ligne.
Le second sera celui de la Feuil2 avec le même principe.

On alimente la Combobox avec les clés du premier dictionary.

2) En validant la combobox :
A toi d'insérer le code qui permet de modifier tes informations de la Feuil1 (je suppose plusieurs colonnes après la première)
Une fois modifiée, on vérifie si la valeur de la Combobox existe dans les clés du dico 2.
Ce qui revient à vérifier si l'ID de la Feuil1 que tu viens de modifier existe dans la Feuil2.
S'il existe, on copie la ligne correspondante de la Feuil1 (l'utilité d'avoir enregistré le n° de la ligne), sur la Feuil2 (ce qui remplacera toutes les valeurs par celles modifiées, plus simple que de faire cellule par cellule, mais on pourra limiter la zone si le nombre de colonnes est connu d'avance).
Si l'ID n'existe pas, on insère la ligne de la Feuil1 correspondante à la ligne 4 de la Feuil2 en décalant les autres lignes vers le bas.

J'espère répondre à la demande.
N'hésite pas si tu as d'autres questions.

Le code ci-dessous, en plus du fichier :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Dim f1 As Worksheet, f2 As Worksheet
Dim l1 As Long, l2 As Long
Dim d1 As Object, d2 As Object
Private Sub CommandButton1_Click()
    '--- Ajouter ton code qui enregistre les valeurs de modif dans ta Feuil1
    ' Tes modifications ici
    '--- On cherche si la valeur de la Combobox existe dans la Feuil2
    If IsNumeric(Me.ComboBox1.Value) = True Then
        v = CLng(Me.ComboBox1.Value)
            Else: v = Me.ComboBox1.Value
    End If
    '- Si l'ID existe en Feuil2, on copie colle la ligne au même emplacement
        If d2.Exists(v) Then
            f1.Rows(d1(v)).Copy f2.Rows(d2(v))
    '- Sinon on l'insère en ligne 4 de la Feuil2
                Else
                    f1.Rows(d1(v)).Copy: f2.Rows("4").Insert Shift:=xlDown
        End If
    '--- On décharge le presse papier
    Application.CutCopyMode = False
    '--- On décharge l'usf
    Unload Me
End Sub
 
Private Sub UserForm_Initialize()
    '--- On définit les variables
    Set f1 = Feuil1: Set f2 = Feuil2
    Set d1 = CreateObject("Scripting.Dictionary"): Set d2 = CreateObject("Scripting.Dictionary")
    l1 = f1.Cells.Find("*", , , , xlByRows, xlPrevious).Row: l2 = f2.Cells.Find("*", , , , xlByRows, xlPrevious).Row
        '--- On remplit les dictionary
        '- Feuil1
        For Each Cell In f1.Range("a1:a" & l1)
            If Cell.Value <> "" Then d1(Cell.Value) = Cell.Row
        Next Cell
        '- Feuil2
        For Each Cell In f2.Range("a1:a" & l2)
            If Cell.Value <> "" Then d2(Cell.Value) = Cell.Row
        Next Cell
            '--- On alimente la Combobox
            Me.ComboBox1.List = d1.Keys
End Sub

[BENNASR]

Merci thebenoit59 pour ta disponibilité , bonjour les membres de ce syper site
c'est la demande de LeoPaul mais j'ai beaucoup profité surtout que c'est la première fois que je comprends un peu l'utilisation du dictionnaire
c'est un tuto pour moi
BONNE JOURNÉE A VOUS TOUS

[LeoPaul]

youaaa !

Merci

je comprends pourquoi on t'appelle "The" Benoit59

au plaisir