Discussion :

[Willsmeeth]

Bonjour à tous,
Voilà mon problème,
J'ai une UserForm où j'y es mis plusieurs ComboBox avec des listes de critères. Sur cette même UserForm j'y es mis un bouton "OK". Jusqu'ici tout va bien.
Mon problème est que j'aimerais, lors d'un appui sur mon bouton "OK", vérifier qu'une donnée soit bien rentrée dans mais ComboBox. Si cela n'est pas le cas j'aimerais qu'un MsgBox s'affiche en disant par exemple "Veuillez entre une donnée dans ComboBox1".

Le code que j'ai essayé est celui ci-dessous mais bien évidement il ne fonctionne pas:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub CommandButton_OK_Click() 
If fenginComboBox Is Not "INDEX!B3:B34" Then
MsgBox "Veuillez saisir une famille d'engins"
End If
End Sub

PS: je précise que je suis nouveau dans le domaine du VBA donc il se peut que je fasse d'énormes fautes .

Merci pour ceux qui prêteront attention à mon sujet!
Cordialement.

MARIAIS Gwénaël

[pijaku]

Bonjour,

Ta combobox fenginComboBox est "remplie" via son RowSource?

Si c'est le cas, il y a trois choix (et seulement 3) :
> soit elle est vide,
> soit elle a une valeur qui appartient au RowSource.
> soit un petit malin a saisi une valeur dans le combobox.

Pour éviter la saisie par un petit malin, il faut, dès l'initialisation de l'userform, paramétrer tes combobox comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

fenginComboBox.Style = fmStyleDropDownList

A partir de là, tu n'auras plus que deux possibilités, vide ou avec une valeur correspondante à ce que tu cherches.

Donc, ton test devient :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub CommandButton_OK_Click() 
If fenginComboBox = "" Then
    MsgBox "Veuillez saisir une famille d'engins"
End If
End Sub

[Willsmeeth]

Merci Pijaku de prêter attention à mon sujet .

Tout d'abord l'astuce fenginComboBox.Style = fmStyleDropDownList fonctionne ainsi que ma MsgBox.

Maintenant ce que j'aimerais savoir c'est que depuis ma commande fenginComboBox.Style = fmStyleDropDownList installée, dans ma ComboBox "fenginComboBox"" je ne vais plus voir de titre par exemple "Famille engin". En faite je ne vois plus le Text dans ma combobox.

En espérant avoir été assez clair. Merci.

[pijaku]

Donne moi ton code de remplissage des combobox.

[Willsmeeth]

Le voici:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
'Assignation de valeur aux combobox
      Me.nomComboBox.RowSource = "INDEX!A3:A34" & Sheets("INDEX").Cells(1, 1).End(xlDown).Row
      Me.fenginComboBox.RowSource = "INDEX!B3:B34" & Sheets("INDEX").Cells(1, 1).End(xlDown).Row
      Me.enginComboBox.RowSource = "INDEX!C3:C34" & Sheets("INDEX").Cells(1, 1).End(xlDown).Row
      Me.typeoperationComboBox.RowSource = "INDEX!D3:D34" & Sheets("INDEX").Cells(1, 1).End(xlDown).Row
      Me.tempsComboBox.RowSource = "INDEX!E3:E34" & Sheets("INDEX").Cells(1, 1).End(xlDown).Row

[pijaku]

Bon.
Plusieurs petites choses avant de continuer :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.nomComboBox.RowSource = "INDEX!A3:A34"

Ok, mais normalement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("INDEX").Cells(1, 1).End(xlDown).Row

te donne le numéro de la dernière ligne. Donc inutile d'ajouter 34.
Ceci devrait suffire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.nomComboBox.RowSource = "INDEX!A3:A" & Sheets("INDEX").Cells(1, 1).End(xlDown).Row

Comme tu utilises

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("INDEX").Cells(1, 1).End(xlDown).Row

plusieurs fois, il vaut mieux le stocker dans une variable. Comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Dim maLigne As Integer
maLigne = Sheets("INDEX").Cells(1, 1).End(xlDown).Row
      Me.nomComboBox.RowSource = "INDEX!A3:A" & maLigne
      Me.fenginComboBox.RowSource = "INDEX!B3:B" & maLigne
      Me.enginComboBox.RowSource = "INDEX!C3:C" & maLigne
      Me.typeoperationComboBox.RowSource = "INDEX!D3:D" & maLigne
      Me.tempsComboBox.RowSource = "INDEX!E3:E" & maLigne

Attention, ceci ne fonctionnera que si, dans la feuille INDEX, les cellules A1, A2 et A3 au minimum sont remplies. Si l'une des trois est vide, ce code ne fonctionnera alors pas.

Dernière question subsidiaire (pas facile sans avoir le fichier sous la main ;-)) :
Ta ligne d'entête dans la feuille INDEX possède quel numéro? 2? 3?

[Willsmeeth]

Je vais tester cela de suite!

Autrement ma ligne d'entête de la feuille "INDEX" est en ligne 1.

[Willsmeeth]

Afin que cela soit un peu plus clair pour vous:

Mon tableau dans la feuille INDEX ci-dessus.

Pour le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

maLigne = Sheets("INDEX").Cells(1, 7).End(xlDown).Row

j'ai mis Cells(1,7) pour être sur qu'il m'affiche toutes mes données.

Alors ce que je souhaiterais, pour revenir à nos moutons, c'est que dans mes comboxbox soit afficher avant de choisir un critère son titre par exemple nom,famille engin etc...

Le code que je dispo dans ma useform est:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Private Sub UserForm_Initialize()
 
'Empêcher de rentrer une valeur à la main dans les combobox
nomComboBox.Style = fmStyleDropDownList
fenginComboBox.Style = fmStyleDropDownList
enginComboBox.Style = fmStyleDropDownList
typeoperationComboBox.Style = fmStyleDropDownList
tempsComboBox.Style = fmStyleDropDownList
 
'Assignation de valeur aux combobox
     Dim maLigne As Integer
maLigne = Sheets("INDEX").Cells(1, 7).End(xlDown).Row
      Me.nomComboBox.RowSource = "INDEX!A2:A" & maLigne
      Me.fenginComboBox.RowSource = "INDEX!B2:B" & maLigne
      Me.enginComboBox.RowSource = "INDEX!C2:C" & maLigne
      Me.typeoperationComboBox.RowSource = "INDEX!D2:D" & maLigne
      Me.tempsComboBox.RowSource = "INDEX!E2:E" & maLigne
 
'Inscription dans la textbox*
ListBox1.ColumnCount = 8
ListBox1.ColumnHeads = True
 
'Ne prendre que les 10 dernières saisies
Dim DerniereLigneSaisie As Integer, PremiereLigne As Integer
DerniereLigneSaisie = Columns(2).Find("*", , , , xlByColumns, xlPrevious).Row
If DerniereLigneSaisie - 8 < 2 Then
    PremiereLigne = 2
Else
    PremiereLigne = DerniereLigneSaisie - 8
End If
 
ListBox1.RowSource = "EVENEMENTS!A" & PremiereLigne & ":G" & DerniereLigneSaisie
End Sub

Merci.

[pijaku]

Bon...
Dans ton cas je ferais comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Private Sub UserForm_Initialize()
   'Assignation de valeur aux combobox
   Me.nomComboBox.RowSource = "INDEX!A1:A" & Sheets("INDEX").Cells(1, 1).End(xlDown).Row
   Me.fenginComboBox.RowSource = "INDEX!B1:B" & Sheets("INDEX").Cells(1, 2).End(xlDown).Row
   Me.enginComboBox.RowSource = "INDEX!C1:C" & Sheets("INDEX").Cells(1, 3).End(xlDown).Row
   Me.typeoperationComboBox.RowSource = "INDEX!D1:D" & Sheets("INDEX").Cells(1, 4).End(xlDown).Row
   Me.tempsComboBox.RowSource = "INDEX!E1:E" & Sheets("INDEX").Cells(1, 5).End(xlDown).Row
   'Empêcher de rentrer une valeur à la main dans les combobox
   nomComboBox.Style = fmStyleDropDownList
   nomComboBox.ListIndex = 0
   fenginComboBox.Style = fmStyleDropDownList
   fenginComboBox.ListIndex = 0
   enginComboBox.Style = fmStyleDropDownList
   enginComboBox.ListIndex = 0
   typeoperationComboBox.Style = fmStyleDropDownList
   typeoperationComboBox.ListIndex = 0
   tempsComboBox.Style = fmStyleDropDownList
   tempsComboBox.ListIndex = 0
   'Inscription dans la textbox*
   ListBox1.ColumnCount = 8
   ListBox1.ColumnHeads = True
   'Ne prendre que les 10 dernières saisies
   Dim DerniereLigneSaisie As Integer, PremiereLigne As Integer
   DerniereLigneSaisie = Columns(2).Find("*", , , , xlByColumns, xlPrevious).Row
   If DerniereLigneSaisie - 8 < 2 Then
       PremiereLigne = 2
   Else
       PremiereLigne = DerniereLigneSaisie - 8
   End If
   ListBox1.RowSource = "EVENEMENTS!A" & PremiereLigne & ":G" & DerniereLigneSaisie
End Sub

Puis, dans la Private Sub CommandButton_OK_Click() :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub CommandButton_OK_Click()
'test le contenu des combobox
If nomComboBox.ListIndex = 0 Then
   MsgBox "Veuillez saisir un nom"
   Exit Sub
End If
If fenginComboBox.ListIndex = 0 Then
   MsgBox "Veuillez saisir une famille d'engin"
   Exit Sub
End If
'etc....
 
'l'action que doit réaliser ton bouton OK
End Sub

[Willsmeeth]

Ok super ça marche!

Par contre (dsl je suis pénible...) dans ma listbox vous avez pu le voir j'ai mis:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ListBox1.ColumnHeads = True

Alors en faite j'aimerais avoir mes titres en haut pour chaque colonne de ma listbox. Le fait est que cela marche bien jusqu'à mes 9 premières saisies (rappel je ne garde que les 10 premières saisies visibles pour l'utilisateur dans la listbox). Ce qu"il se passe c'est qu'a ma 10ème saisie la colonne titre de ma listbox saute pour prendre la saisie numéro 1 et ainsi de suite.
Je vous fait voir cela en image:
Jusqu'à ma 9ème saisie

A ma 10ème saisie


Mon code est celui-ci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Private Sub UserForm_Initialize()
 
'Empêcher de rentrer une valeur à la main dans les combobox
nomComboBox.Style = fmStyleDropDownList
fenginComboBox.Style = fmStyleDropDownList
enginComboBox.Style = fmStyleDropDownList
typeoperationComboBox.Style = fmStyleDropDownList
tempsComboBox.Style = fmStyleDropDownList
 
'Assignation de valeur aux combobox
    Me.nomComboBox.RowSource = "INDEX!A2:A" & Sheets("INDEX").Cells(1, 1).End(xlDown).Row
    Me.fenginComboBox.RowSource = "INDEX!B2:B" & Sheets("INDEX").Cells(1, 2).End(xlDown).Row
    Me.enginComboBox.RowSource = "INDEX!C2:C" & Sheets("INDEX").Cells(1, 3).End(xlDown).Row
    Me.typeoperationComboBox.RowSource = "INDEX!D2:D" & Sheets("INDEX").Cells(1, 4).End(xlDown).Row
    Me.tempsComboBox.RowSource = "INDEX!E2:E" & Sheets("INDEX").Cells(1, 5).End(xlDown).Row
 
'Inscription dans la textbox*
ListBox1.ColumnCount = 8
ListBox1.ColumnHeads = True
 
'Ne prendre que les 10 dernières saisies
Dim DerniereLigneSaisie As Integer, PremiereLigne As Integer
DerniereLigneSaisie = Columns(2).Find("*", , , , xlByColumns, xlPrevious).Row
If DerniereLigneSaisie - 8 < 2 Then
    PremiereLigne = 2
Else
    PremiereLigne = DerniereLigneSaisie - 8
End If
 
ListBox1.RowSource = "EVENEMENTS!A" & PremiereLigne & ":G" & DerniereLigneSaisie
End Sub

Merci!

[pijaku]

Pour cela, tu ne peux pas faire comme ça.
Enlève la propriété ColumnHeads = True, mets la sur False

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ListBox1.ColumnHeads = False

Remplace cette possibilité en plaçant au dessus de chacune des colonnes de ta listbox des label avec les noms souhaités dans leurs caption.

[Willsmeeth]

Ok très bien je vous remercie!

Continuer à faire ce que vous faites!

Cordialement.

M.Gwénaël