Discussion :

[Averell1976]

Bonjour à toutes et à tous,

D'avance, merci pour votre aide.

En fait, je ne comprends pas bien le fonctionnement des Listbox, mais dans le fichier joint, j'ai un userform qui s'ouvre dès l'ouverture, avec un combobox, un textbox (alimenté automatiquement en fonction du contenu du combobox) et un listbox.
Je voudrai récupéré (sur 2 colonnes) dans ce listbox les valeurs du combobox et du textbox; j'arrive à récupérer la valeur du combobox mais pas celle du textbox. Je bloque.....

Ensuite, en cliquant sur le bouton, je voudrai copier ces valeurs contenues dans la listbox dans la feuille "Feuil1" dans les colonnes correspondantes (Résidents sortants et Pavillon).

Je n'ai pas vraiment essayé la programmation sur le bouton vu que déjà je bloque sur la récupération des données dans la listbox.
J'ai vu qu'on pouvait paramétrer une listbox pour qu'elle aie x colonnes, et ainsi récupérer des données qui seraient balancées dans chacune de ces colonnes, mais je n'y arrive pas....

Un grand merci pour votre aide.

[eric4459]

Bonjour Averell,
A priori ce n'est pas toi qui a crée cette macro, dans ce cas je te conseille de faire tourner la macro en mode "pas a pas" (tu affiche le code et tu mets ton curseur sur la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Private Sub UserForm1_Initialize()

puis avec la touche F8 tu fais défiler ta macro).
Un bon moyen de contrôle également est l'utilisation des "Espions" : sélectionnes une variable , ici j'ai choisi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

TextBox1.Value

et avec un clic droit tu sélectionnes "Ajouter un espion" une fenêtre apparaîtra avec la variable sélectionnée (tu peux en sélectionner plusieurs) et tu verra la valeur que prend ta variable en cours de traitement par ton code.

C'est ce que j'ai fait et j'ai remarqué que dans cette ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

TextBox1.Value = Range("A" & a).Value

le code compare la valeur de la textBox1 ou se trouve les noms des personnes et la colonne A de l'onglet "Données" ou se trouvent les noms des pavillons : ces deux données ne seront jamais égales, essayes plutôt

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

TextBox1.Value = Range("B" & a).Value

En scrutant ce que fait le code, tu verra comment il fonctionne et tu pourra modifier en conséquence.
Bon courage
Eric

[Theze]

Bonjour,

Deux choses, parente tes Ranges :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
If ComboBox_Resident = Worksheets("Données").Range("B" & a).Value Then
    TextBox1.Value = Worksheets("Données").Range("A" & a).Value
    '...

ça évite souvent des prises de tête !
Ensuite, pour avoir des valeurs affichées sur plusieurs colonnes dans une ListBox ou ComboBox, il faut en définir le nombre, pour toi, "ColumnCount" doit être sur 2 !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
Private Sub ComboBox_Resident_Change()
 
    Dim a As Integer
 
    For a = 2 To 53
 
        If ComboBox_Resident = Worksheets("Données").Range("B" & a).Value Then
            TextBox1.Value = Worksheets("Données").Range("A" & a).Value
 
            Exit For
        End If
 
    Next a
 
    'il faut que la propriété ColumnCount soit sur 2 si tu veux 2 colonnes !!!
    With List_Residents
 
        .AddItem ComboBox_Resident.Text
        .List(.ListCount - 1, 1) = TextBox1.Text
 
    End With
 
End Sub

Autre chose, évites, autant que possible, les "GoTo quelque chose", le code est plus difficile à maintenir par la suite ! Dans une boucle, un Exit For va très bien.

[Philippe Tulliez]

Bonjour,
Comment alimenter un contrôle ListBox ?
A condition que la liste comprenne tous les lignes de la plage de données, le plus simple est l'utilisation de la propriété RowSource
Exemple : sSi la liste de données se trouve dans la feuille nommée db et est comprise entre A1 et F11 avec comme première ligne les étiquettes de colonnes,
La syntaxe est RowSource = db!A2:F11

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub UserForm_Initialize()
 With Me.ListBox1
 .RowSource = "db!A2:F11"
 .ColumnCount = 6 ' Nbre de colonnes affichées
 .ColumnHeads = True ' Affiche les étiquettes de colonnes
 End With
End Sub

Comment récupérer les données sélectionnées par le clic dans la liste ?
La propriété ListIndex du contrôle ListBox permet de connaître la ligne sélectionnée dans la liste. Le premier élément sélectionné étant égal à 0

Voici un code rapide qui charge la liste contenue dans une feuille à condition que cette liste contienne en première ligne les étiquettes de colonnes et qu'elle débute en cellule A1
Il faut dans le UserForm : 1 contrôle ListBox1 et 2 contrôles TextBox1 et TexBox2
Modifié le nom de la feuille ;qui se trouve dans la constante SheetName. Cette feuille doit se trouver dans le classeur où se trouve le UserForm
Procédure à placer dans le code du UserForm

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Option Explicit
Const SheetName As String = "db" ' Nom de la feuille
Dim rng As Range, rngdata As Range
 
Private Sub ListBox1_Click()
 With Me.ListBox1
  TextBox1 = rngdata(.ListIndex + 1, 1) ' 1ère colonne de la ligne sélectionnée
  TextBox2 = rngdata(.ListIndex + 1, 2) ' 2ème colonne de la ligne sélectionnée
 End With
End Sub
 
Private Sub UserForm_Initialize()
 Set rng = ThisWorkbook.Worksheets(SheetName).Range("A1").CurrentRegion
 With rng
  Set rngdata = .Offset(1).Resize(.Rows.Count - 1)
 End With
 With Me.ListBox1
 .RowSource = rngdata.Address(external:=True)
 .ColumnCount = rngdata.Columns.Count ' Nbre de colonnes affichées
 .ColumnHeads = True ' Affiche les étiquettes de colonnes
 End With
End Sub

A lire éventuellement USERFORM - Créer, Consulter, Modifier et Supprimer des enregistrements à l'aide d'un formulaire.


[EDIT]
A la ligne 13 du code publié, j'avais laissé la valeur constante "db", alors qu'il fallait placer à la place la constante nommée SheetName
La correction a été faite.

[Averell1976]

Merci infiniment pour votre aide.
Avec tout cela, je vais pouvoir me débrouiller.
J'avais malgré tout avancé un peu sur le sujet me suis confronté à un autre problème que j'ai exposé ce jour dans un autre post.

Merci encore!!