Discussion :

[Tchebichef]

Bonjour,
J'ai un soucis probablement très bête mais je n'arrive pas à le résoudre.
Je cherche à remplir une listbox à partir de données d'une feuille excel en fonction d'une condition.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub CommandButton2_Click()
        k = 0
Me.ListBox1.Clear
With Sheets("BDD")
    DernLigne = .Range("A" & Rows.Count).End(xlUp).Row
    For Each cellule In .Range("A2:A" & DernLigne)
        If cellule = Me.TextBox1.Value Then
            Me.ListBox1.AddItem
            Me.ListBox1.List(k, 0) = cellule
            Me.ListBox1.List(k, 1) = cellule.Offset(0, 1)
            Me.ListBox1.List(k, 2) = cellule.Offset(0, 2)
            Me.ListBox1.List(k, 3) = cellule.Offset(0, 3)
        End If
        k = k + 1
    Next cellule
End With
End Sub

Bien que la condition soit vérifiée, le remplissage ne se fait pas... Même lorsque cellule=Me.TextBox1.Value est vérifié, rien ne se passe.
Dans le Range, les données saisies sont des années. Dans le TextBox l'utilisateur saisit également une année.
Ce qui est étrange c'est que si je saisis dans le Range '2011 au lieu de 2011 par exemple, alors ça marche. Ce qui me fait penser qu'il s'agit simplement d'un problème de format, mais je ne trouve pas la solution...
D'avance merci pour votre aide!

[lionel86500]

Bonjour,

Ta donnée cellule est considérée comme OBJECT
transfert la dans une donnée string et fait le test avec la donnée string et ca marche

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
dim s1 as string
s1 = cellule
If s1 = Me.TextBox1.Value Then

[Tchebichef]

merci mais ça ne fonctionne pas
par contre ce code fonctionne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
With Sheets("BDD")
    DernLigne = .Range("A" & Rows.Count).End(xlUp).Row
    For i = 2 To DernLigne
        If .Range("A" & i) Like Me.ComboBox2 Then
            Me.ListBox1.AddItem
            Me.ListBox1.List(k, 0) = .Range("A" & i)
            Me.ListBox1.List(k, 1) = .Range("B" & i)
            Me.ListBox1.List(k, 2) = .Range("C" & i)
            Me.ListBox1.List(k, 3) = .Range("D" & i)
        End If
        k = k + 1
    Next i
End With

mais j'ai un autre soucis...
lorsque je sélectionne la première valeur de ma combobox comme critère de remplissage de la listbox, ça fonctionne.
mais quand je sélectionne la seconde valeur, j'ai un message d'erreur : impossible de définir la propriété list index de table de propriétés non valide
l'erreur pointe sur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.ListBox1.List(k, 0) = .Range("A" & i)

je ne comprends pas...

[lionel86500]

Comment est créé ton combobox

[Philippe Tulliez]

Bonjour,
Un petit exemple qui fonctionne.
La liste de données commence en cellule A1 de la feuille nommée [db] et les étiquettes de colonnes se trouvent en ligne 1.
Le contrôle ListBox1 est alimenté par le nom et le prénom (Colonne 2 et 3 de la liste des données ) des personnes de sexe féminin ("F" dans la colonne 4 de la liste des données)
La procédure avec en tête de module la déclaration des variables rng et rng_Data ainsi que la constante ConditionValue

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Option Explicit
Const ConditionValue As String = "F"
Dim rng As Range, rng_Data As Range
Private Sub UserForm_Initialize()
 Dim r As Long
 Set rng = ThisWorkbook.Worksheets("db").Range("A1").CurrentRegion
 With rng: Set rng_Data = .Offset(1).Resize(.Rows.Count - 1): End With
 With Me.ListBox1
 .ColumnCount = 3: .ColumnWidths = "25;50;50" ' Remplacer 25 par 0 pour ne pas afficher la première colonne
 End With
 With rng_Data
  For r = 1 To .Rows.Count ' Nbre de lignes de la liste de données
   If .Cells(r, 4).Value = ConditionValue Then
    Me.ListBox1.AddItem r ' N° de la ligne où se trouve les données répondant à la condition
    Me.ListBox1.List(Me.ListBox1.ListCount - 1, 1) = .Cells(r, 2).Value
    Me.ListBox1.List(Me.ListBox1.ListCount - 1, 2) = .Cells(r, 3).Value
   End If
  Next r
 End With
End Sub

[Osaka2017]

Merci pour ce code très utile Philippe

Néanmoins, serait-il éventuellement possible d'y insérer la largeur automatique des colonnes ?

Les largeurs fixes ne sont pas vraiment esthétiques ni faciles à déterminer quand on ne connait pas préalablement les données.

Merci d'avance.

Vincent