Discussion :

[gd74ad]

Bonjour à tous,

Cela fait un moment que j'essaie de trouver une solution avec des formules mais on m'a dit que ca serait plus simple en VBA, le problème c'est que je débute vraiment la dedans

Voici mon problème, j'ai un tableau comme celui ci :

COLONNE A	| COLONNE B
C1,C3,C5 	| C100NF
C2,C4,C6 	| C47UF
R1,R2		| R1K

Et je voudrais pouvoir le trier automatiquement comme ceci :

COLONNEA	| COLONNE B
C1		| C100NF
C2		| C47UF
C3		| C100NF
C4		| C47UF
C5		| C100NF
C6		| C47UF
R1		| R1K
R2		| R1K

On m'a parlé de split mais sans plus de précision, auriez vous une solution ?
Merci beaucoup

[Theze]

Bonsoir,

Teste ceci, le résultat est en colonne D et E, si tu le veux en colonne A et B, il te suffit d'effectuer un remplacement de valeurs :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
 
Sub Test()
 
    Dim Plage As Range
    Dim Cel As Range
    Dim Tbl
    Dim I As Integer
    Dim J As Long
 
    With Worksheets("Feuil1")
 
        'défini la plage en colonne A sur la feuille "Feuil1"
        Set Plage = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
        'boucle sur les cellules de la plage
        For Each Cel In Plage
 
            'splite...
            Tbl = Split(Cel.Value, ",")
 
            'sur la même feuille en colonne D et E
            For I = 0 To UBound(Tbl)
 
                J = J + 1
                .Cells(J, 4) = Tbl(I)
                .Cells(J, 5) = Cel.Offset(0, 1).Value
 
            Next I
 
        Next Cel
 
        'redéfini la plage sur les colonnes D et E
        Set Plage = .Range(.Cells(1, 4), .Cells(.Rows.Count, 5).End(xlUp))
 
        'tri en ordre croissant
        Plage.Sort .Cells(1, 4), xlAscending
 
    End With
 
End Sub