Discussion :

[leosalex]

Bonjour, je suis bloquer sur mon code VBA et j’aurais besoin d’aide. Je vous explique mon problème.

J’ai un fichier 1 dans lequel ma première feuille il y a une liste avec certain articles (un article par ligne). J’ai ensuite un fichier 2 dans lequel il y a tous les articles (base de données).
Je souhaiterais lorsque j’appuie sur mon bouton il mette à jour ma liste du fichier 1 (il sélectionne et copie la colonne ou il y a liste d’article de mon fichier 2 et la colle à la place de ma liste fichier 1.)

J’ai commencé à codé mais cela ne fonctionne pas. Est-il possible d’avoir un peu d’aide ? =)

Encore merci d’avance =)

Ps : Code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Private Sub CommandButton19_Click()
 
Dim Nouveau As String
Dim NomFichier As String
Dim x As Integer
Dim y As Integer
Dim LigneF
Dim vect(1 To 10000) As String            ' vecteur a remplir d'info
Dim vect2(1 To 10000) As String            ' vecteur a remplir d'info
 
Nouveau = Dir("D:\9404124z\Documents\ESTIA\Alex\fichier2.xlsm") 
Workbooks.Open Filename:=Nouveau     
Nouveau = Right(Nouveau, Len(Nouveau) - InStrRev(Nouveau, "\"))   
Workbooks(Nouveau).Worksheets("Feuille1"). 
With Workbooks(Nouveau).Worksheets("Feuille1")   
LigneF = .Range("A" & .Rows.Count).End(xlUp).Row
End With
 
For x = 1 To LigneF             
    vect(x) = Cells(x, 1)
    vect2(x) = Cells(x, 2)
Next
 
Workbooks("fichier1").Worksheets("Feuil1").Activate      
For x = 1 To LigneF                         
    Cells(x, 1) = vect(x)
    Cells(x, 2) = vect2(x)
Next
 
Workbooks(Nouveau).Close   'Pour fermer le fichier
 
End Sub

[joe.levrai]

Bonjour,

une proposition commentée

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Private Sub CommandButton19_Click()
Dim WbSource As Workbook
Dim Listing()
 
' ouverture du fichier
Set WbSource = Workbooks.Open("D:\9404124z\Documents\ESTIA\Alex\fichier2.xlsm")
With WbSource.Worksheets("Feuille1")
    ' on prend la plage active de la colonne A et B
    ' on la met dans un tableau
    Listing = .Cells(1, 1).Resize(.UsedRange.Rows.Count, 2).Value
End With
' fermeture du fichier
WbSource.Close False
 
With ThisWorkbook.Worksheets("Feuil1")
    ' on efface la colonne A et B
    .Columns(1).Resize(, 2).Clear
    ' on y injecte les données du tableau
    .Cells(1, 1).Resize(UBound(Listing, 1), 2).Value = Listing
End With
 
End Sub

[leosalex]

Merci beaucoup ça fonctionne parfaitement =)