Discussion :

[Tancuda]

Bonjour à tous,
voici mon tout premier post (sur ce forum), je me réfère à vous pour amener
une correction que je ne peux faire dù à mon manque de connaissances dans
ces macros. Je désire en apprendre plus, et je sais que dans ces forums, il y a
de biens bonnes personnes très compétentes.

Voici la macro: elle copie des cellules Excel (A1 à G13), ouvre une boite de dialogue pour
enregistrer les cellules copiées dans un fichier texte. Tous fonctionne bien, mais
quand la boite de dialogue est ouverte et que je clique sur "annuler", cela va créer
un fichier texte nommé: "faux.txt". J'aimerais empêcher cela et simplement fermer la boite de dialogue.

Merci d'avance de m'éclairer et de m'apprendre.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub Save_en_txt()
Dim wbSource As Workbook
Dim wsSource As Worksheet
Dim wbDest As Workbook
Dim fName As String
 
'References
Set wbSource = ActiveWorkbook
Set wsSource = ActiveSheet
Set wbDest = Workbooks.Add
 
'Copy range on original sheet
wsSource.Range("A1:G13").Copy
 
'----------------------------
'Save in new workbook
wbDest.Worksheets(1).Cells(1, 1).PasteSpecial Paste:=xlPasteValuesAndNumberFormats
Application.CutCopyMode = False
 
'Get file name and location from user
fName = Application.GetSaveAsFilename(FileFilter:="Text Files (*.txt), *.txt", Title:="Save As")
If fName = "" Then Exit Sub '//user cancelled
 
'Save new tab delimited file
wbDest.SaveAs fName, xlText
 
wbDest.Close SaveChanges:=True
'----------------------------
 
MsgBox "FICHIER EXPORTÉ"
 
End Sub

[tototiti2008]

Bonsoir Tancuda,

Si tu cliques sur Annuler dans GetSaveAsFileName, il renvoie la valeur False
Je laisserais donc fName en variant pour pouvoir tester s'il est booléen, et sortir dans ce cas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Dim fName
...
...
fName = Application.GetSaveAsFilename(FileFilter:="Text Files (*.txt), *.txt", Title:="Save As")
If vartype(fName) = vbBoolean or fName = "" Then Exit Sub
...

Essaie d'utiliser la balise Code (#) quand tu postes du code

[Tancuda]

Merci de votre réponse, mais j'ai pas très bien compris, je suis vraiment débutant, comment laisser fName en variant ?

Et que veux tu dire par "utiliser la balise Code (#)..." pouvez-vous élaborer? svp merci

[tototiti2008]

Re,

Quand tu postes un message, tu as des boutons au-dessus
Le bouton # permet de mettre en forme le code

comment laisser fName en variant ?

Si tu ne précise pas le type d'une variable quand tu la déclares, elle sera en Variant

donc

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim fName

ou

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim fName as Variant

c'est pareil

un bon tuto : http://silkyroad.developpez.com/VBA/LesVariables/

[Tancuda]

Merci Tototiti2008,
j'ai finalement écrit tes lignes correctement
dans ma macro, et ca fonctionne,
je m'avais trompé la première fois, j'avais laisser "Dim fName as string"
et non "Dim fname"