Discussion :

[fabien85320]

Bonjour,

Je suis actuellement en stage dans un service de contrôle de gestion où je fais du VBA, et je recherche à récupérer des données d'une dernière version.
Je m'en explique :

J'ai copié une feuille d'un classeur 1 sur une autre feuille d'un autre classeur 2 appelé "copie FAE". Elle contient un ensemble de prévi de différents projets. En revanche, il est possible que des fois, le même prévi d'un même projet s'affiche sur cette feuille "copie FAE". Mon but est de récupérer à chaque fois la dernière version de chacun des prévi présents sur cette feuille. Par exemple, récupérer le dernier "940027" (le plus récent on le voit dans une colonne AF avec la date) En revanche, je ne vois pas comment il est possible de faire ce genre de manip. Quelqu'un aurait il une idée ? Je suis un débutant en macro VBA.

Cordialement,

Fabien

[Theze]

Bonjour,

Une piste, je suis partis du postulat que les codes sont en colonne A de la feuille "copie FAE" et les dates à comparer sont en colonne AF :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
 
Sub Test()
 
    Dim Plage As Range
    Dim Cel As Range
    Dim Code As String
    Dim Adr As String
    Dim DateMax As Date
    Dim PosCel As String
 
    Code = InputBox("Indiquez le numéro du code !")
 
    If Code = "" Then Exit Sub
 
    'défini la plage de recherche sur la colonne A (colonne où se trouvent les codes)
    With Worksheets("copie FAE")
 
        Set Plage = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
    'lance la recherche
    Set Cel = Plage.Find(Code, , xlValues, xlWhole)
 
    'si trouvé...
    If Not Cel Is Nothing Then
 
        'mémorise l'adresse de la 1 ère cellule
        Adr = Cel.Address
 
        Do
            'si la date en colonne AF est supérieure à la valeur de la variable
            'récupére cette date et mémorise le numéro de ligne
            If Cel.Offset(, 31).Value > DateMax Then
 
                DateMax = Cel.Offset(, 31).Value
                PosCel = Cel.Row
 
            End If
 
            'continue la recherche...
            Set Cel = Plage.FindNext(Cel)
 
        Loop While Adr <> Cel.Address
 
        MsgBox "La date la plus récente est le '" & Format(DateMax, "dd/mm/yyyy") & "' à la ligne '" & PosCel & "' !"
 
    Else
 
        MsgBox "Code '" & Code & "' non trouvé !"
 
    End If
 
End Sub

Hervé.