Discussion :

[Daniel117]

Bonjour je cherche à recopier n fois la même plage de cellule sur sur la même feuille .
exemple n=100
j'ecris un code pour juste la recopier sur à partir de ligne 23 mais l'idée est de la recopier chaque juste à après l'autre

, j'ai ecris un code qui recopie mais j'ai juste evaluer le nombre de cellule qui seront concernées
en partant de la cellule 23 +1900 cellule ça fait environ 2000

mais comment recopier exactement le nombre de fois qu'on veut ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub recopie_plage()
 
Dim i As Integer
Dim y As Integer
y = 19
 
 
For i = 23 To 2000 Step 19
 
 
        Range("A3:O22").Copy Range("A" & i & ":o" & i + y)
 
    Next i
 
 
 
End Sub

[Theze]

Bonjour,

Une piste (sans copie mais avec affectation des valeurs) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Sub recopie_plage()
 
    Dim Plage As Range
    Dim NBFois As Long
    Dim I As Integer
 
    NBFois = 123
 
    With Worksheets("Feuil1")
 
        Set Plage = .Range("A3:O22")
 
        For I = 23 To NBFois Step 20
 
            .Range(.Cells(I, 1), .Cells(Plage.Rows.Count - 1 + I, Plage.Columns.Count)).Value = Plage.Value
 
        Next I
 
    End With
 
End Sub

Hervé.

[Daniel117]

Bonjour,

Merci teze pour ta reponse, mais en fait la recopie avec le code que tu as donné se fait jusqu'à la ligne nbfois c à d dans ton exple jusqu'à la ligne 123.
or il faudrait une recopie 123 fois soit 123*20 soit sur 2460 lignes donc on devrait se retrouver à la ligne 2483. et puis je prèfére une recopie simple pas une recopie sans valeur

j'ai introduis une variable

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub recopie_plage2()
 
    Dim Plage As Range
    Dim NBFois As Long
    Dim I As Integer
    Dim x As Integer
 
    x = 20
 
    NBFois = 123
 
    With Worksheets("Feuil1")
 
        Set Plage = .Range("A3:O22")
 
        For I = 23 To NBFois * x Step 20
 
            .Range(.Cells(I, 1), .Cells(Plage.Rows.Count - 1 + I, Plage.Columns.Count)).Value = Plage.Value
 
        Next I
 
    End With
 
End Sub

[Thautheme]

Bonjour Daniel, Hervé, bonjour le forum,

Une autre proposition :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Macro1()
Dim O As Worksheet 'déclare la variable O (Onglet)
Dim PL As Range 'déclare la variable PL (PLage)
Dim F As Variant 'déclare la variable F (Fois)
Dim DEST As Range 'déclare la variable DEST (cellule de DESTination)
Dim I As Byte 'déclare la variable I (Incrément)
 
Set O = Sheets("Feuil1") 'définit l'onglet O (à adapter)
Set PL = O.Range("A1").CurrentRegion 'définit la plage PL (à adapter)
F = Application.InputBox("Entrez le nombre de F que sera copiée la plage.", "COPIE", Type:=1) 'définit le noibre de fois F
If F = False Then Exit Sub 'si bouton "Annuler", sort de la procédure
For I = 1 To F 'boucle de 1 au nombre de fois F
    Set DEST = O.Cells(Application.Rows.Count, 1).End(xlUp).Offset(1, 0) 'définit la cellue de destination DEST
    PL.Copy DEST 'copie la plge PL et la colle dans DEST
Next I 'prochaine fois de la boucle
End Sub

[Daniel117]

Bonjour,

Merci thauteme et

ton code marche mais j'ai juste remplacé la ligne 9 par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Set PL = Range("A3:O22")

Merci beaucoup.
merci également à teze pour ta proposition.

[Marc-L]

Bonjour,

juste en passant une boucle n'est pas nécessaire ‼
Indiquer juste la plage complète en destination ou encore
en respectant la règle TBTO via un Resize :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub Demo()
    With [A3:O22].Rows
        .Copy .Offset(.Count).Resize(.Count * 100)
    End With
End Sub

_____________________________________________________________________________________________________

Merci de cliquer sur pour chaque message ayant aidé …

_____________________________________________________________________________________________________

Je suis Charlie, Bardo, Sousse

[Daniel117]

Bonjour Marc,


c'est géniale ton code et simple en plus franchement merci.

cdt