Discussion :

[ti_mouton]

Bonjour,

J'ai besoin d'aide afin d'appliquer 2 formules sur 2 colonnes avec VBA.
Dans un premier temps, je veux que la colonne L me renvoie le numéro de la semaine correspondant à la date saisie dans la colonne H.
Egalement, je veux que la colonne M applique la fonction Concatener(colonne D; ColonneE).

Merci pour votre aide.

[Fanfan2A]

Bonjour ti_mouton,

- pour le numéro de semaine, est-ce pour 1 cellule, une zone de cellules ou pour la colonne entière ?
- pour la concaténation, est-ce bien une concaténation (texte) ou une somme (nombres) ?
Doit-elle s'applique uniquement à une cellule ou bien à toute la colonne ?
Si c'est sur toute la colonne, merci de préciser si la zone de données est continue ou discontinue, et si les 2 colonnes ont le même nombre de données.

Cdlt

[ti_mouton]

Bonjour,

Dans les 2 cas je veux que la fonction s'applique pour toute la colonne à partir de la Ligne 2.
Pour la concatenation il s'agit bien d'une concaténation de texte, la zone de données est continue et les colonnes ont le même nombre données.

Pour le No.Semaine, j'ai essayé ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sub NoSemaine()
    Range("L2:L").Value = Application.WorksheetFunction.WeekNum(Range("H2:H"), 2)
End Sub

mais ca ne fonctionne pas.

[joe.levrai]

Bonjour,

un exemple commenté
adapter le nom de la feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Tableau()
Dim Tablo
Tablo = Worksheets("Feuil1").UsedRange ' chargement des données dans un tableau
For i = LBound(Tablo, 1) To UBound(Tablo, 1) 'boucle sur chaque ligne du tableau
    Tablo(i, 12) = Application.WorksheetFunction.WeekNum(Tablo(i, 8)) 'numéro de semaine de la date en H en L
    Tablo(i, 13) = Tablo(i, 4) & Tablo(i, 5) 'concaténation de D et E dans M
Next i
Worksheets("Feuil1").UsedRange.Value = Tablo ' restitution des données sur la plage
End Sub

[ti_mouton]

Bonjour Joe,

Merci pour votre réponse. Malheureusement je viens d'essayer votre code mais j'ai un message d'erreur qui s'affiche : Impossible de lire la propriété WeekNum... ?

[joe.levrai]

Bonjour,

je n'arrive pas à reproduire le problème

quel est le code tel que tu l'as utilisé ? Si tu as modifié quelque chose, tu peux me montrer à quoi ressemble ton code maintenant ?

j'ai essayé :

- avec une date dans la colonne H : OK
- avec une cellule vide dans la colonne H : OK, ça met un numéro de semaine "0"
- avec une chaine de caractère dans la colonne H : j'ai une erreur (ce qui est normal), mais c'est pas celle dont tu me parles


on est d'accord que ta colonne H ne contient QUE des dates ?
est-il possible de consulter le fichier, ou une simple copie épurée où le problème se produit quand même ?

[Fanfan2A]

Dans le même esprit que joe.levrai, voici 2 procédures séparées qui travaillent sur l'onglet actif (sinon remplacer with activesheet par with sheets("nomdelafeuille") ) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Sub Concaténer(ByVal ColSource1$, ByVal ColSource2$, ByVal ColDestination$)
Dim NbreLignes As Double, I As Double
Dim NbreLignes_ColSource1 As Double, NbreLignes_ColSource2 As Double
Dim TabloS1, TabloS2, TabloD()
Const NoLigne1 As Integer = 2
With ActiveSheet
    TabloS1 = .Range(.Range(ColSource1 & NoLigne1), .Range(ColSource1 & NoLigne1).End(xlDown))
    TabloS2 = .Range(.Range(ColSource2 & NoLigne1), .Range(ColSource2 & NoLigne1).End(xlDown))
    NbreLignes_ColSource1 = UBound(TabloS1)
    NbreLignes_ColSource2 = UBound(TabloS2)
    NbreLignes = WorksheetFunction.Min(NbreLignes_ColSource1, NbreLignes_ColSource2)
    ReDim TabloD(1 To NbreLignes, 1 To 1)
    For I = 1 To NbreLignes
        TabloD(I, 1) = TabloS1(I, 1) & TabloS2(I, 1)
    Next I
    .Range(ColDestination & NoLigne1).Resize(NbreLignes) = TabloD
End With
End Sub
 
Sub NoSemaine(ByVal ColSource$, ByVal ColDestination$)
Dim NbreLignes As Double, I As Double
Dim TabloS, TabloD()
Const NoLigne1 As Integer = 1
With ActiveSheet
    TabloS = .Range(.Range(ColSource & NoLigne1), .Range(ColSource & NoLigne1).End(xlDown))
    NbreLignes = UBound(TabloS)
    ReDim TabloD(1 To NbreLignes, 1 To 1)
    For I = 1 To NbreLignes
        TabloD(I, 1) = Format(TabloS(I, 1), "ww", vbMonday, vbFirstFourDays)
    Next I
    .Range(ColDestination & NoLigne1).Resize(NbreLignes) = TabloD
End With
End Sub

Exemple : Concaténer "D","E","M"
et NoSemaine "L","H"

En espérant que cela vous convienne.

Cdlt