Discussion :

[neGo33]

Bonjour,
J'ai une macro qui fait plusieurs traitements sur des cellules d'une feuille Excel.
J'enlève les espaces en début et fin avec la fonction Trim.

J'aimerai également enlever les espaces à l'intérieur de la chaîne de caractères lorsqu'il y en a plusieurs qui se suivent.
Comment faire? Existe-t-il une fonction pour ça?
Je ne sais pas combien d'espaces se suivent, c'est aléatoire.

D'avance merci de vos réponses.

[Thautheme]

Bonjour neGo, bonjour le forum,

Pas très académique j'utilise la fonction remplacer. Je remplace "deux espaces" par "un espace" jusqu'à ce qu'Excel me dise qu'il ne trouve plus...

[antonysansh]

Bonjour neGo33,

Voilà une proc qui fait la manip sur le range [B2:B10] de la feuille active

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub supp_dbl_space()
    Dim rg As Range, c As Range
        Set rg = ActiveSheet.[B2:B10]
        For Each c In rg
            While InStr(c.Value, "  ") > 0
                c = Replace(c.Value, "  ", " ")
            Wend
        Next
End Sub

Si ta plage est très grande, parcourir toutes les cellules peut être très lourd pour Excel.

Voilà une méthode moins couteuse toujours avec le même principe, temps qu'il y a des doubles espaces je les remplace par des simples.

Foncions pour enlever les doubles espaces :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Function supprimer_double_espace(texte As Variant) As String
    While InStr(texte, "  ") > 0
        texte = Replace(texte, "  ", " ")
    Wend
    supprimer_double_espace = texte
End Function

Boucle sur toutes les cellules en passant par un tableau :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub supp_dbl_space_by_tab()
    Dim rg As Range, c As Range, t(), nb_l&, nb_c&, i&, j&
        Set rg = ActiveSheet.[B2].CurrentRegion
            nb_l = rg.Rows.Count
            nb_c = rg.Columns.Count
        t() = rg
        For i = 1 To nb_l
            For j = 1 To nb_c
                t(i, j) = supprimer_double_espace(t(i, j))
            Next j
        Next i
        rg = t()
        Set rg = Nothing
End Sub

[Marc-L]

Bonjour, bonjour !

L'efficience - et donc le moins coûteux - est d'utiliser le B-A-BA d'Excel : la fonction de feuille de calculs SUPPRESPACE,

Application.Trim en VBA, en une unique instruction !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sub Demo()
    MsgBox Application.Trim("  Penser   Excel   avant   du   pur   VB   est   bien   plus   efficace   !   ")
End Sub

_____________________________________________________________________________________________________

Merci de cliquer sur pour chaque message ayant aidé puis sur pour clore cette discussion …

_____________________________________________________________________________________________________
Je suis Charlie - Je suis Bardo