Discussion :

[ArnaudYes]

Bonjour,

J'espère que vous allez bien. Encore merci pour l'aide fournie sur les précédents posts.

Je reviens vers vous aujourd'hui car j'ai liste de valeurs triées par ordre alphabétique et/ou croissant dans une colonne.

Certaines de ces valeurs se répètent plusieurs fois et j'aimerais pouvoir aller au dernier résultat de cette valeur.

Ex :
A
A
A
B
B
C

En cherchant B, je veux pouvoir aller sur le deuxième B.
La valeur à chercher est contenue dans une combobox.

Je vous remercie par avance. Cordialement,
Arnaud

[Theze]

Bonjour,

Teste ce code pour voir si il te convient et adapte :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
Private Sub ComboBox1_Click()
 
    Dim Plage As Range
    Dim Cel As Range
    Dim Adr As String
    Dim I As Long
 
    With Worksheets("Feuil1")
 
        Set Plage = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
    Set Cel = Plage.Find(ComboBox1.Text, , xlValues, xlWhole)
 
    If Not Cel Is Nothing Then
 
        Adr = Cel.Address
 
        Do
 
            If I < Cel.Row Then I = Cel.Row
 
            Set Cel = Plage.FindNext(Cel)
 
        Loop While Adr <> Cel.Address
 
        MsgBox "La dernière cellule contenant '" & ComboBox1.Text & "' est la cellule " & Range("A" & I).Address(0, 0)
 
    End If
 
End Sub

Hervé.

[Nico Chg]

Bonjour,

Une autre méthode, avec Find et xlPrevious, pour rechercher dans la colonne en partant du bas :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With Worksheets("MaFeuille")
    lastValue = .Columns(2).Find("B", , , , xlByColumns, xlPrevious).Row
End With

Avec ça tu recherche dans la colonne 2 la valeur "B" en partant du bas, tu auras donc la dernière valeur recherchée.

[ArnaudYes]

Merci Beaucoup !! Ça marche impec !

Passez une bonne soirée !

Cordialement,
Arnaud