Discussion :

[Julien91080]

Bonjour au forum,

Je voulais savoir s'il était possible, d'une quelconque manière, d'obtenir une transcodification automatique lors de la saisie?
Autrement dit, j'aimerai que lorsque dans une cellule d'une colonne définie, j'écrit Non, NON ou non j'obtienne un "N".

Je ne sais pas si cela relève du format de cellule, de la validation ou de VBA.

Qu'en pensez-vous?

Cordialement,

Julien

[Philippe Tulliez]

Bonjour,
Cela peux se faire à l'aide de la procédure événementielle Worksheet_Change de la feuille où à lieu l'encodage (C'est donc du VBA) ou la procédure événementielle B]Workbook_SheetChange[/B] du classeur (module ThisWorkbook)
Exemple pour la colonne B

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub Worksheet_Change(ByVal Target As Range)
 If Target.Column <> 2 Then Exit Sub
 Application.EnableEvents = False
  With Target
   Select Case LCase(Trim(.Value))
     Case "non": .Value = "N"
   End Select
  End With
 Application.EnableEvents = True
End Sub

[Julien91080]

Bonjour Philippe et merci de ta réponse.

Puis-je pousser le vice plus loin?

Dans ton exemple, tu défini en dure les "valeurs probables". Comment faire pour rendre ça dynamique?
Exemple, sur un onglet :

Code source Encodage Nombre de colonne
n N 2
Non N 2



Merci et a bientôt

Julien

[Philippe Tulliez]

Bonjour,

Dans une feuille paramètre dont la propriété CodeName est shtParam, tu commences une liste de deux colonnes à partir de la cellule A1
Par exemple

	A	B
1	non	N
2	oui	O
3	personnel	Perso

Dès que l'on rentrera une donnée correspondant en minuscule à la liste de la colonne A, la procédure renverra le caractère ou le mot se trouvant en colonne B de la même ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub Worksheet_Change(ByVal Target As Range)
 Dim lstParam(), r As Integer
 If Target.Column <> 2 Then Exit Sub
 Application.EnableEvents = False
  lstParam = shtparam.Range("A1").CurrentRegion
  With Target
   For r = 1 To UBound(lstParam)
    If LCase(Trim(.Value)) = lstParam(r, 1) Then .Value = lstParam(r, 2): Exit For
   Next
  End With
 Application.EnableEvents = True
End Sub

[Julien91080]

Un grand merci,

Cela ouvre pas mal de perspectives.

Je reste malgré tout étonné qu'il n'y ai pas un autre moyen que du VBA. Peut être un jour qui sait?

Excellente journée.

Cordialement,

Julien

[Philippe Tulliez]

Bonjour,

Pour des cas très simple et limités, il reste le format personnalisé
A lire Création, enregistrement et fusion de formats personnalisés