IdentifiantMot de passe
Loading...
Mot de passe oublié ?Je m'inscris ! (gratuit)
Navigation

Inscrivez-vous gratuitement
pour pouvoir participer, suivre les réponses en temps réel, voter pour les messages, poser vos propres questions et recevoir la newsletter

SPARQL Discussion :

Requête SPARQL dBpedia


Sujet :

SPARQL

  1. #1
    Membre du Club
    Inscrit en
    novembre 2009
    Messages
    68
    Détails du profil
    Informations forums :
    Inscription : novembre 2009
    Messages : 68
    Points : 56
    Points
    56
    Par défaut Requête SPARQL dBpedia
    Salut,

    Je veux extraire à partir de DBpedia quelques informations sur le film "Toy Story".
    Pour cela , j'ai mis la requête suivante :
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    PREFIX rdf:<http://www.w3.org/1999/02/22-rdf-syntax-ns#>
    PREFIX dbpprop:<http://dbpedia.org/property/>
    PREFIX dbpedia-owl: <http://dbpedia.org/ontology/>
    PREFIX dcterms: <http://purl.org/dc/terms/>
    select * where {
    ?film  rdf:type <http://dbpedia.org/ontology/Film>.
    ?film dbpprop:name  "Toy story".
    ?film dbpprop:title ?title.
    ?film dbpedia-owl:cinematography ?cinematography.
    ?film dbpedia-owl:director  ?director.
    ?film dbpedia-owl:editing   ?editing.
    ?film dbpedia-owl:musicComposer ?musicComposer.
    ?film dbpedia-owl:starring  ?starring.
    ?film dbpedia-owl:writer ?writer.
    ?film dbpprop:artist ?artist.
    ?film dbpprop:country ?country.
    ?film dbpprop:distributor ?distributor.
    ?film dcterms:subject  ?subject.
    }
    Mais elle me retourne vide?

    Pouvez-vous m'aider s'il vous plaît?

  2. #2
    Membre éprouvé
    Avatar de Sapience
    Homme Profil pro
    Consultant sémantique & data à sparna.fr
    Inscrit en
    avril 2005
    Messages
    305
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : France, Indre et Loire (Centre)

    Informations professionnelles :
    Activité : Consultant sémantique & data à sparna.fr
    Secteur : High Tech - Éditeur de logiciels

    Informations forums :
    Inscription : avril 2005
    Messages : 305
    Points : 901
    Points
    901
    Par défaut
    1. Remplace :


    ?film dbpprop:name "Toy story".

    Par :


    ?film dbpprop:name "Toy Story"@en.

    (attention aux majuscules / minuscules, et les infos sont en langue anglaise).

    Et certaines propriétés ne sont sans doute pas renseignées, donc met tous tes critères entre OPTIONAL :

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    PREFIX rdf:<http://www.w3.org/1999/02/22-rdf-syntax-ns#>
    PREFIX dbpprop:<http://dbpedia.org/property/>
    PREFIX dbpedia-owl: <http://dbpedia.org/ontology/>
    PREFIX dcterms: <http://purl.org/dc/terms/>
    select * where {
    ?film  rdf:type <http://dbpedia.org/ontology/Film>.
    ?film dbpprop:name  "Toy Story"@en.
    OPTIONAL { ?film dbpprop:title ?title. }
    OPTIONAL { ?film dbpedia-owl:cinematography ?cinematography. }
    OPTIONAL { ?film dbpedia-owl:director  ?director. }
    OPTIONAL { ?film dbpedia-owl:editing   ?editing. }
    OPTIONAL { ?film dbpedia-owl:musicComposer ?musicComposer. }
    OPTIONAL { ?film dbpedia-owl:starring  ?starring. }
    OPTIONAL { ?film dbpedia-owl:writer ?writer. }
    OPTIONAL { ?film dbpprop:artist ?artist. }
    OPTIONAL { ?film dbpprop:country ?country. }
    OPTIONAL { ?film dbpprop:distributor ?distributor. }
    OPTIONAL { ?film dcterms:subject  ?subject. }
    }

    Ceci étant dit ça ne me parait pas une bonne approche car le résultat te donne le produit cartesien entre toutes les variables, tu as donc un tableau de résultats très long.

    J'utiliserai plutôt un DESCRIBE :


    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    DESCRIBE <http://dbpedia.org/resource/Toy_Story>

Discussions similaires

  1. [Jena] Requête SPARQL sur une ontologie
    Par lalalala75 dans le forum Frameworks
    Réponses: 9
    Dernier message: 14/04/2012, 07h55
  2. Réponses: 1
    Dernier message: 18/03/2012, 09h59
  3. Requête sur dbpedia
    Par ebenmous dans le forum SPARQL
    Réponses: 1
    Dernier message: 18/07/2011, 15h54
  4. Interface graphique pour générer des requêtes SPARQL
    Par SonyBlack dans le forum SPARQL
    Réponses: 2
    Dernier message: 16/08/2010, 14h11

Partager

Partager
  • Envoyer la discussion sur Viadeo
  • Envoyer la discussion sur Twitter
  • Envoyer la discussion sur Google
  • Envoyer la discussion sur Facebook
  • Envoyer la discussion sur Digg
  • Envoyer la discussion sur Delicious
  • Envoyer la discussion sur MySpace
  • Envoyer la discussion sur Yahoo