Discussion :

[stracoma]

Bon soir à tous. J'ai besoin de votre aide.
J'ai une liste de noms que j'appelle: Noms
Je fais entrer tous les noms qui se terminent par "id" dans une autre liste que je nomme: noms_Id
pour afficher le contenu de noms_Id, pas de problème avec ce code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Imports System.Collections
Module Module1
 
    Sub Main()
        Dim noms As New List(Of String) From {"Kalid", "Ahmed", "Walid", "Said", "Aziz", "Rachid", "mourad"}
        Dim noms_Id As New List(Of String)
        noms_Id = noms.FindAll(AddressOf SeTermineParId)
        For Each elem In noms_Id
            Console.WriteLine(elem)
        Next
        Console.ReadKey()
        'noms_Id.affiche
    End Sub
    Function SeTermineParId(s As String) As Boolean
        If s.Length > 2 And s.Substring(s.Length - 2) = "id" Then
            Return True
        Else
            Return False
        End If
    End Function
    'Sub affiche(ByVal lis As List(Of String))
    '    For Each elem In lis
    '        Console.WriteLine(elem)
    '    Next
    'End Sub
End Module

mais, pourquoi le code n’accepte pas :noms_Id.affiche ?
Merci

[Sehnsucht]

Concernant le "problème" évoqué : La classe List(Of T) ne possède aucune méthode affiche ; ce que tu cherches à faire serait plutôt affiche (noms_Id)

Maintenant quelques remarques diverses :
Tu n'as pas besoin du If dans ta fonction SeTermineParId ; en effet tel quel ton code dit "si ma condition est vraie renvoyer vrai sinon (si ma condition est fausse) renvoyer faux" ; autant directement renvoyer le résultat de ta condition

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Function SeTermineParId(s As String) As Boolean
    Return s.Length > 2 AndAlso s.Substring(s.Length - 2) = "id"
End Function

Après on pourrait encore simplifier en utilisant déjà ce qui existe à savoir la méthode EndsWith de la classe String Return s.EndsWith ("id") ou encore passer par l'opérateur Like Return s Like "*id"

Sur un autre plan tu pourrais utiliser pour affiche la même logique que celle utilisée avec FindAll en utilisant List(Of T).ForEach avec quelque chose dans ce style :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
noms_Id.ForEach (AddressOf Afficher)
 
Sub Afficher (ByVal s As String)
    Console.WriteLine (s)
End Sub

Et/ou carrément se passer de la méthode afficher (parce qu'après tout ce n'est qu'un nouveau nom pour la méthode Console.WriteLine déjà existante dans ce cas) avec noms_Id.ForEach (AddressOf Console.WriteLine)

[rv26t]

Bonjour,

Et si le but est seulement l'affichage sur la console,
Pour compléter la ligne tracée par Sehnsucht

... Après on pourrait encore simplifier ...

on peut appliquer le tout directement sur "noms"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

        noms.FindAll(AddressOf SeTermineParId).ForEach(AddressOf Console.WriteLine)

On perçoit la puissance des outils mis à notre disposition pour manipuler les collections.

[stracoma]

Merci à vous.
Return s.EndsWith, facilite bcp les choses (je ne savais pas que ça existe)
Salut