Effectuer la macro sur les onglets commencant par

**gilles171** · 21/11/2014, 09h36

Bonjour,

Je voudrais effectuer cette macro sur chaque onglet du classeur commentcant par Valor cependant cela ne semble pas marcher... A priori, le code est bon je ne comprends pas :/ j'ai essayé ces deux facons

For Each Worksheet In ActiveWorkbook.Sheets
If Left(sh.Name, 5) = "Valor" Then

et With Worksheets("Valor") If LCase(Left(Worksheets.Name, 5)) = "Valor" Then

Voici mon code :

Merci beaucoup pour votre aide

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
 
Sub Histo()
 
    Dim Plage As Range
    Dim Cel As Range
 
   For Each Worksheet In ActiveWorkbook.Sheets
   If Left(sh.Name, 5) = "Valor" Then
 
        Set Plage = .Range(.Cells(2, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
 
    For Each Cel In Plage
 
        'Condition 1) Si colonne A, B, non vide et si colonne F est en % alors copier E dans G
        If Cel.Value <> "" And Cel.Offset(, 1).Value <> "" And Cel.Offset(, 5).NumberFormat = "0.00%" Then
 
 
            Cel.Offset(, 10).Value = Cel.Offset(, 6).Value
 
        'Condition 2 ) Si colonne A, B, non vide, et si colonne F n'est pas en % alors copier F dans G
        ElseIf Cel.Value <> "" And Cel.Offset(, 1).Value <> "" And Cel.Offset(, 5).NumberFormat <> "0%" Then
 
            Cel.Offset(, 10).Value = Cel.Offset(, 5).Value
 
        End If
 
    Next Cel
 
  ActiveWorkbook.Save
    ActiveWorkbook.Close
 
 
End Sub

**vinc_bilb** · 21/11/2014, 10h14

Bonjour,

En fait, je vous suggère dans ce type de pb, de:

1. mettre un point d'arrêt sur la partie qui vous embête
2. de dérouler ensuite le code en mode pas à pas pour voir ce qui se passe

Votre test est bon il me semble, mais que se passe-t-il quand <> "Valor"? Vous avez un " End With" sans With il me semble .... Vous passez peut-être quand même à

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each Cel In Plage

Donc, pour un peu que Plage reste définie par la feuille d'avant, vous continuez votre procédure

Il suffit donc juste de remonter le traitement sur "Plage" dans votre partie test, comme

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
  If Left(sh.Name, 5) = "Valor" Then
 
        Set Plage = .Range(.Cells(2, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
   ' End With C'est quoi???????????????????????????
 
 
    For Each Cel In Plage
 
        'Condition 1) Si colonne A, B, non vide et si colonne F est en % alors copier E dans G
        If Cel.Value <> "" And Cel.Offset(, 1).Value <> "" And Cel.Offset(, 5).NumberFormat = "0.00%" Then
 
 
            Cel.Offset(, 10).Value = Cel.Offset(, 6).Value
 
        'Condition 2 ) Si colonne A, B, non vide, et si colonne F n'est pas en % alors copier F dans G
        ElseIf Cel.Value <> "" And Cel.Offset(, 1).Value <> "" And Cel.Offset(, 5).NumberFormat <> "0%" Then
 
            Cel.Offset(, 10).Value = Cel.Offset(, 5).Value
 
        End If
 
    Next Cel
 
End If

Bonne journée

**gilles171** · 21/11/2014, 10h26

Merci !
Mais en faisant point par point j'ai une erreur de compliation avec une erreur de reference au niveau de .cell de Range(.Cells(2, ..........

En parcourant l'aide je trouve "Un identificateur commençant par un point n'est valide qu'au sein d'un bloc With. Cause et solution de cette erreur : "

Est ce que je devrais mettre ce code ci dessous au sein d'un bloc with et end with pour contourner ce problème ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
If Left(sh.Name, 5) = "Valor" Then
 
        Set Plage = .Range(.Cells(2, 1), .Cells(.Rows.Count, 1).End(xlUp))

Très bonne journée également,

**Gado2600** · 21/11/2014, 10h34

Bonjour,

La première partie de ton code ne peut fonctionner tel que c'est écrit.

Essayes par contre, quelque chose comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
dim xlwksheet as worksheet
for each xlwksheet in activeworkbook.sheets
if ucase(xlwksheet.name) like "VALOR*" then
 Set Plage = xlwksheet.Range(xlwksheet.Cells(2, 1), xlwksheet.Cells(xlwksheet.Rows.Count, 1).End(xlUp))
end if
next

Après, je me suis pas attardé sur ton code car j'ai été demandé entre deux...

Cordialement,

**gilles171** · 21/11/2014, 10h50

Hello,

merci mais du coup votre code n'effectue pas mon code peut etre est ce à ucase(xlwksheet.name) like "VALOR*" then qui met tout en Majuscule alors que je voudrais "commencant par Valor et donc qu'il ne reconnait aucun onglet ? Le problème c'est que c'est ca que je ne sais pas faire.
J'ai remplacé Ucase par => mais ca bloque au niveau de Left... je ne comprends pas...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
    Dim Plage As Range
    Dim Cel As Range
  Dim xlwksheet As Worksheet
 
For Each xlwksheet In ActiveWorkbook.Sheets
If Left(xlwksheet.Name) = "Valor" Then
 Set Plage = xlwksheet.Range(xlwksheet.Cells(2, 1), xlwksheet.Cells(xlwksheet.Rows.Count, 1).End(xlUp))
End If
Next

**joe.levrai** · 21/11/2014, 12h20

Bonjour,

ci-après à tester

j'ai nettoyé les coquilles du code et rétabli le bon comportement sur la recopie des cellules pour que le comportement soit celui de tes commentaires

il faut juste ajouter le nom du classeur au début du code, dans l'instanciation de la variable Wb

attention : "valor" ne sera pas détecté, c'est du stricto "Valor" || le format de la cellule en pourcentage doit être avec deux chiffres après la virgule

à toi de nous dire s'il faut assouplir tout ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
 
Sub Histo()
 
Dim Plage As Range
Dim Cel As Range
Dim Wb As Workbook
Dim Sh As Worksheet
 
Set Wb = Workbooks("LeNomDeTonClasseur")
 
For Each Sh In Wb.Sheets
 
    If Left(Sh.Name, 5) = "Valor" Then
 
        Set Plage = Sh.Range(Sh.Cells(2, 1), Sh.Cells(Sh.Rows.Count, 1).End(xlUp))
 
        For Each Cel In Plage
 
            'Condition 1) Si colonne A, B, non vide et si colonne F est en % alors copier E dans G
            If Cel.Value <> "" _
            And Cel.Offset(0, 1).Value <> "" _
            And Cel.Offset(0, 5).NumberFormat = "0.00%" Then
 
                Cel.Offset(0, 6).Value = Cel.Offset(0, 4).Value
 
            'Condition 2 ) Si colonne A, B, non vide, et si colonne F n'est pas en % alors copier F dans G
            ElseIf Cel.Value <> "" _
            And Cel.Offset(0, 1).Value <> "" _
            And Cel.Offset(0, 5).NumberFormat <> "0.00%" Then
 
                Cel.Offset(0, 6).Value = Cel.Offset(0, 5).Value
 
            End If
 
        Next Cel
 
    End If
 
Next Sh
 
Set Plage = Nothing
Wb.Close True
 
End Sub

**gilles171** · 21/11/2014, 13h27

Bonjour,

Merci beaucoup !

Cependant il y a une macro initiale qui appelle cette Macro Histo pour effectuer l'action sur une centaine de classeur, donc comment pourrais modifier la ligne Set Wb = Workbooks("LeNomDeTonClasseur"), j'ai essayé ThisWorkbook mais ca ne marche pas..

Merci !

**vinc_bilb** · 21/11/2014, 13h49

Bonjour,

Il faudrait donc la passer avec des paramètres de type Workbook, du style

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Histo(Wbk As Workbook)
 
Dim Plage As Range
Dim Cel As Range
Dim Wb As Workbook
Dim Sh As Worksheet
 
For Each Sh In Wbk .Sheets
....

et dans la procédure d'appel, le faire de la forme Call Histo(ActiveWorkbook)

**joe.levrai** · 21/11/2014, 13h53

il faudrait voir le contenu de cette macro pour te donner la bonne méthode

mais il faut probablement passer un argument à ta Sub "Histo" qui provient de la macro qui l'appelle

dans ta macro principales, tu affectes le classeur sur lequel il travaille à une variable
et quand on appelle la macro histo, on lui passe le classeur en argument

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
Sub MacroPrincipale()
 
' blabla du code
 
' ici j'utilise le classeur où la macro est écrite
' mais il suffit de mettre sous variable le classeur sur lequel ça travaille
' et mettre la variable à la place de ThisWorkBook
Call Histo(ThisWorkbook)
 
' blabla du code
 
End Sub

et la macro histo devient :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
 
Sub Histo(Wb As Workbook)
 
Dim Plage As Range
Dim Cel As Range
Dim Sh As Worksheet
 
For Each Sh In Wb.Sheets
 
    If Left(Sh.Name, 5) = "Valor" Then
 
        Set Plage = Sh.Range(Sh.Cells(2, 1), Sh.Cells(Sh.Rows.Count, 1).End(xlUp))
 
        For Each Cel In Plage
 
            'Condition 1) Si colonne A, B, non vide et si colonne F est en % alors copier E dans G
            If Cel.Value <> "" _
            And Cel.Offset(0, 1).Value <> "" _
            And Cel.Offset(0, 5).NumberFormat = "0.00%" Then
 
                Cel.Offset(0, 6).Value = Cel.Offset(0, 4).Value
 
            'Condition 2 ) Si colonne A, B, non vide, et si colonne F n'est pas en % alors copier F dans G
            ElseIf Cel.Value <> "" _
            And Cel.Offset(0, 1).Value <> "" _
            And Cel.Offset(0, 5).NumberFormat <> "0%" Then
 
                Cel.Offset(0, 6).Value = Cel.Offset(0, 5).Value
 
            End If
 
        Next Cel
 
    End If
 
Next Sh
 
Set Plage = Nothing
Wb.Close True
 
End Sub

Effectuer la macro sur les onglets commencant par [XL-2010]

Macros et VBA Excel

Vue hybride

Discussions similaires

Partager

Partager