Discussion :

[sbell]

Bonjour

J'aimerais ajouter à cet macro une boucle et une requête mais je ne sais pas comment faire.

a l'heure actuelle la macro m'imprime l'onglet "synth" de tous les fichiers excel présent dans le dossier racine. J'aimerais garder ça mais imprimer un nombre qui serait demandé à la personne.
Il me faudrait en gros une boite de dialogue qui demanderait combien de fois veut on imprimer puis par la suite imprimer tout les onglet 1 par 1 et répéter cette action en fonction du nombre demandé, ce qui me permettrait de garder l'ordre de mes fichiers.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
Public Sub ImprimeClasseurs()
Dim NomClass As String, Feuille As Worksheet, Liste As Worksheet, LigListe As Integer
Set Liste = ThisWorkbook.Worksheets.Add()
 
 
NomClass = Dir(ThisWorkbook.Path & "\*.xls")
Do Until NomClass = ""
   If NomClass <> ThisWorkbook.Name Then
      Workbooks.Open ThisWorkbook.Path & "\" & NomClass
      LigListe = LigListe + 1
 
 
      Workbooks(NomClass).Sheets("synth").PrintOut
 
      Workbooks(NomClass).Close False
   End If
   NomClass = Dir()
Loop
 
End Sub

[Thautheme]

Bonjour Sbell, bonjour le forum,

Essaie comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Public Sub ImprimeClasseurs()
Dim NomClass As String, Feuille As Worksheet, Liste As Worksheet, LigListe As Integer, NB As Integer
 
Set Liste = ThisWorkbook.Worksheets.Add()
NB = Application.InputBox("Veuillez indiquer le nombre de copies.", "NOMBRE", Type:=1)
If NB = False Then Exit Sub
 
 
NomClass = Dir(ThisWorkbook.Path & "\*.xls")
Do Until NomClass = ""
   If NomClass <> ThisWorkbook.Name Then
      Workbooks.Open ThisWorkbook.Path & "\" & NomClass
      LigListe = LigListe + 1
        Workbooks(NomClass).Sheets("synth").PrintOut , copies:=NB
      Workbooks(NomClass).Close False
   End If
   NomClass = Dir()
Loop
End Sub

[sbell]

Bonjour

Merci pour ta réponse j'ai bien avancé. Ta boucle fonctionne correctement mais pas exactement de la manière que j'aimerais .

Je pense qu'elle doit être placé plus tard

Je t'explique , ça m'a bien imprimé le nombre de fois mes fichiers mais pas dans l'ordre souhaité

Exemple
fichier 1 onglet synth
fichier 2 onglet synth

J'ai mis deux exemplaires et ton correctif m'a donné
fichier 1 onglet synth
fichier 1 onglet synth
fichier 2 onglet synth
fichier 2 onglet synth

J'aurais voulu
fichier 1 onglet synth
fichier 2 onglet synth
fichier 1 onglet synth
fichier 2 onglet synth

En gros imprimer tout les fichiers excel dans le dossier racine et après répéter cette impression le nombre de fois demandé. Je continue de chercher mais si tu as la réponse merci d 'avance

cordialement

[Thautheme]

Bonjour Sbell, bonjour le forum,

Alors essaie comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Public Sub ImprimeClasseurs()
Dim NomClass As String, Feuille As Worksheet, Liste As Worksheet, LigListe As Integer, NB As Integer, I As Integer
 
Set Liste = ThisWorkbook.Worksheets.Add()
NB = Application.InputBox("Veuillez indiquer le nombre de copies.", "NOMBRE", Type:=1)
If NB = False Then Exit Sub
 
For I = 1 To NB
NomClass = Dir(ThisWorkbook.Path & "\*.xls")
    Do Until NomClass = ""
       If NomClass <> ThisWorkbook.Name Then
          Workbooks.Open ThisWorkbook.Path & "\" & NomClass
          LigListe = LigListe + 1
            Workbooks(NomClass).Sheets("synth").PrintOut
          Workbooks(NomClass).Close False
       End If
       NomClass = Dir()
    Loop
Next I
End Sub

[sbell]

Bonjour

Merci cela fonctionne parfaitement et répond à vos besoins.

Merci de votre aide ca me simplifie grandement mon travail

Merci a toute l'équipe