Discussion :

[capi81]

Salut le forum

Je viens sollicité votre aide pour adapté mon code.
Avec le code ci-dessous, je copie les données de mon usf vers la feuille PARAMETRE.
Voici les difficultés rencontrées:
- je constate que le collage ne se fait pas au fur et à mesure (le collage se fait toujours sur la même ligne ce qui n'est pas bon)
Cela ne me permet de vérifier la 2è condition qui est que lorsque dans la plage B6:B il y'a déjà la valeur de la textbox1, que le message suivant apparaisse:"Ce user est déjà enregistré"
ci-dessous le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Private Sub bt_add_Click()
Dim TB(6) As String
Dim LigneVide As Long, i As Integer
 
'verification des identifiants
 
If Application.WorksheetFunction.CountIf(Sheets("PARAMETRE").Range("B6:B" & Sheets("PARAMETRE").Range("B65536").End(xlUp).Row), TextBox1.Value > 0) Then
MsgBox ("Ce user est déjà enregistré")
Exit Sub
End If
 
With Sheets("PARAMETRE")
'copie des cellules
TB(1) = Me.TextBox1.Value 'date
TB(2) = Me.TextBox2.Value 'Cpte
TB(3) = Me.TextBox3.Value 'Intitulé
TB(4) = Me.TextBox4.Value 'Téléphone
TB(5) = Me.TextBox5.Value 'ref pièce
TB(6) = Me.TextBox6.Value 'Code agent
 
End With
 
'Avec la feuille de destination
With Sheets("PARAMETRE")
'selection de la première cellule vide
LigneVide = .Cells(Rows.Count, 2).End(xlUp).Row
If LigneVide > 1 Then LigneVide = LigneVide + 1
'Copie les données
For i = 1 To 6
.Cells(LigneVide, i + 1) = TB(i)
Next i
 
End With
End Sub

[typoussin]

Je n'arrive pas à comprendre à quoi sert ta ligne
if ligne vide>1 then lignevide = lignevide + 1
Sinon à écrire dans la ligne suivant la première ligne vide trouvée. Supprime cette ligne de code pour essayer.

[Thautheme]

Bonsoir le fil, bonsoir le forum,

Peut-être comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub bt_add_Click()
Dim P As Object 'déclare la variable P (onglet Parametre)
Dim DL As Integer 'déclare la variable DL (Dernière Ligne)
Dim PL As Range 'déclare la variable PL (PLage)
Dim I As Integer 'déclare la variable I (Incrément)
 
Set P = Sheets("PARAMETRE") 'définit l'onglet P
DL = P.Cells(Application.Rows.Count, 2).End(xlUp).Row 'définit la dernière ligne éditée DL de la colonne 2 (=B) de l'onglet P
Set PL = P.Range("B2:B" & DL) 'définit la plage PL
'verification des identifiants
If Application.WorksheetFunction.CountIf(PL, TextBox1.Value) > 0 Then
    MsgBox ("Ce user est déjà enregistré")
    Exit Sub
End If
For I = 1 To 6 'boucle sur les 6 textboxes
    'envoie la valeur de la textbox dans la cellule ligne DL+1, colonne I+1 de l'onglet P
    P.Cells(DL + 1, I + 1).Value = Me.Controls("TextBox" & I).Value
Next I
End Sub

[capi81]

Salut Thautheme et typoussin

Merci pour vos solutions qui fonctionnent bien.
J'ai beaucoup aimé le code de Thautheme qui est très simple.