Discussion :

[agtim]

Bonjour tout le monde!

J'ai un problème sur EXCEL 2010!
Voila j'ai mon classeur excel avec des donnés brutes sur la feuille 1... Je souhaiterais extraire toutes les données du mois d'aout vers une autre feuille, jusqu'ici tout va bien!
Mais voila je souhaites ensuite faire des calculs avec ces données et je voudrais trouver une formule qui me permette de rechercher automatiquement la valeur min (par exemple) afin que celui-ci se remplisse automatiquement et que je n'ai pas à recopier à la main! En gros pour ma colonne Bradesco Nominale, je souhaiterais avoir une formule qui aille directement chercher la valeur min, Q1, mediane, Q3 et max... Pensez vous que c'est possible?
Je vous joint un fichier pour rendre plus claire mes explications, n'hésitez pas à me poser des questions pour avoir plus de renseignements!

Merci

Exemple.xlsx

[Alex vba]

Bonjour agtim,

C'est possible via des formules matricielles, cette formule vous donne le minimum pour la colonne Bradesco Nominale du mois Agosto.

A placer en K11 pour le minimum :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MIN(SI('Données Brutes'!A4:A1000="AGOSTO";SI('Données Brutes'!B4:B1000="BRADESCO";'Données Brutes'!D4:D1000)))

Les formules matricielles sont à valider avec Ctrl + Maj + Entrée.

Pour le Q1, médiane, Q3 et maximum il faut remplacer les plages que vous aviez saisies par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SI('Données Brutes'!A4:A1000="AGOSTO";SI('Données Brutes'!B4:B1000="BRADESCO";'Données Brutes'!D4:D1000))

Ce qui donne pour Q1 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=QUARTILE(SI('Données Brutes'!A4:A1000="AGOSTO";SI('Données Brutes'!B4:B1000="BRADESCO";'Données Brutes'!D4:D1000));1)

Médiane :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MEDIANE(SI('Données Brutes'!A4:A1000="AGOSTO";SI('Données Brutes'!B4:B1000="BRADESCO";'Données Brutes'!D4:D1000)))

Q3 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=QUARTILE(SI('Données Brutes'!A4:A1000="AGOSTO";SI('Données Brutes'!B4:B1000="BRADESCO";'Données Brutes'!D4:D1000));3)

Max :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MAX(SI('Données Brutes'!A4:A1000="AGOSTO";SI('Données Brutes'!B4:B1000="BRADESCO";'Données Brutes'!D4:D1000)))

Je vous laisse adapter ces formules aux autres colonnes. Vous devrez changer le "BRADESCO" en fonction des noms de banques. Pour passer de nominal a liquide vous devez changer le dernier argument de chaque fonction ci dessus tel que :'Données Brutes'!E4:E1000


Si vous avez des questions sur ces formules je me ferais un plaisir d'y répondre.

Alex.

[agtim]

Merci beaucoup Alex!

Si je pousse un peu plus loin mais tu me dis si j'abuse un peu de tes compétences est ce que tu crois qu'il est possible de créer un formulaire pour demander quel moi la personne voudrait analyser? et si oui serait-il possible de rajouter un filtre comme la région par exemple?
Du genre: Quel mois souhaitez vous analyser?
Une région particulière?
Et la boum tout sort automatiquement ?

Merci encore en tout cas de prendre du temps pour répondre à mes questions!

[Alex vba]

Bonjour agtim,

Ce que tu demandes est réalisable en VBA mais je ne me débrouille pas assez bien pour faire ce que tu demande...

En revanche je peut te proposer une autre solution, sans macro et facile a mettre en place, qui permet de sélectionner un mois de l'année dans une liste en conservant le format actuel de ton rapport.

Dans les formules précédente, on peux changer les paramètre "AGOSTO" et "BRASDECO" par l'emplacement d'une cellule. Il suffit d'appliquer une liste de choix à cette cellule et le tour est joué !

Imaginons que le choix du mois se fasse dans la grande cellule fusionnée en A2, il faut dans un premier temps créer une liste dans cette cellule. Pour cela, sélectionnez la cellule, puis dans le ruban cliquer sur "Donnée" puis "Validation des données".
Dans l'onglet option : sélectionnez autoriser "Liste", cochez les des cases "autoriser si vide" et "Liste déroulante dans la cellule". Dans le champs Source entrez les mois de l'année séparés d'un point virgule. Par exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

AGOSTO;MIAO;JUNHO

Ensuite il faut remplacer dans toutes les formules le paramètre "AGOSTO" par "A2". Et ne pas oublier de les valider par Ctrl + Maj + Entrée (formule matrcielle oblige...). Par exemple la formule du minimum pour Bradesco / Nominal (la formule en K11) deviendrait :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MIN(SI('Données Brutes'!A4:A1000=A2;SI('Données Brutes'!B4:B1000="BRADESCO";'Données Brutes'!D4:D1000)))

Voilà avec ça vous pouvez sélectionner un mois de l'année et votre tableau se recalcule automatiquement.

Pour ce qui est de la sélection de la région, comme vous ne me l'aviez pas demandé dans votre précédent message et que ça n'intervient pas dans votre tableau récapitulatif, les formules que je vous ais envoyé ne prennent pas en compte un filtre sur la région. Si vous souhaitez ajouter un filtre sur une région, les formules seront à modifier et probablement qu'il faudra créer une nouvelle feuille dans le classeur. Cette nouvelle feuille serais une vision plus fine par région, l'ancienne feuille serait la vision générale de vos données.

[Marc-L]

Je rejoins l'avis d'Alexandre : envisager d'abord les solutions purement Excel avant d'attaquer du code …

Pour filtrer vers une nouvelle feuille, consulter le tutoriel Les filtres avancés ou élaborés dans Excel …

[agtim]

Bonjour,

Alex merci pour ta proposition, je l'ai déjà mise en place comme ca pas besoin de faire une feuille par mois!
J'ai aussi créer une macro pour me permettre d'importer les données voulues et une pour les supprimer.
C'est pour ca que j'aurais voulu un formulaire pour que quand la personne clique sur mon bouton importer des données (j'ai affecté une macro) une formulaire vienne demander quel mois et si il voulait ajouter d'autres filtres...

Mais bon pour l'instant ca fonctionne très bien!

Merci encore