Discussion :

[ivanG]

Bonjour à tous !

J'ai des données à renseigner dans certaines colonnes.
Ces données peuvent etre une heure 15 par exemple ou bien une date sous ce format 12/09.

Lorsque je renseigne un format 12/09, par exemple, Excel repère automatiquement une division et divise....

Je voudrais bloquer le format pour que 12/09 reste 12/09 lorsqu'on valide. Format texte.

Actuellement j'ai mis outil -> calcul -> Sur ordre

et j'ai fait ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub Worksheet_Change(ByVal Target As Range)
             If Target.Value = "NP" Or Target.Value = "AR" Or Mid(Target.Value, 3, 1) = "/" Then
                   Target.NumberFormat = "@"
            Else: Target.NumberFormat = "General"
            End If
End Sub

Evidement, ce code ne fonctionne pas...

Avez vous des idées ?

Merci d'avance !

Bonne après-midi !

[NVCfrm]

salut,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.NumberFormat = "d/m;@"

[ivanG]

Malheureusement ca ne fonctionne pas...

Par exemple : Si j'inscris dans une cellule 12/06, avant que

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worsheet_Change

s'active, il inscrit 2 puis ensuite exécute

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worsheet_Change

. Le Target.Value fait donc référence à la valeur 2 au lieu de 12/06.

[Docmarti]

Bonjour.

Comme tu l'as bien constaté, Il faut intervenir avant l'événement Change, sinon il est trop tard.
D'abord il faut mettre la cellule au format TEXTE pour éviter que Excel interprète l'entrée.
Ensuite dans l'événement Change, on peut faire tout ce qu'on veut.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
 
  If Target.Count = 1 Then
   If Not Intersect(Range("A:A"), Target) Is Nothing Then
    If Target = "" Then
     Target.NumberFormat = "@"
    End If
   End If
 End If
 
End Sub
 
Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
 
End Sub
 
Private Sub Worksheet_Change(ByVal Target As Range)
 
If Target.Count = 1 Then
 If Not Intersect(Range("A:A"), Target) Is Nothing And Target.NumberFormat = "@" And Target <> "" Then
 If IsNumeric(Target) Then
 
  answer = MsgBox("Voulez-vous appliquer le format numerique a cette cellule?", vbYesNoCancel, CDbl(Target))
   If answer = vbYes Then
    Cancel = True
    Target.NumberFormat = "General"
    Target = CDbl(Target)
   End If
 
 ElseIf IsDate(Target) Then
 
  answer = MsgBox("Voulez-vous appliquer le format Date a cette cellule?", vbYesNoCancel, CDate(Target))
 
  If answer = vbYes Then
   Cancel = True
   Target.NumberFormat = "m/d/yyyy"
   Target = CDate(Target)
  End If
 
 End If
 End If
 End If
End Sub

[ivanG]

Parfait, j'ai utilisé "Selection_Change" comme tu l'as mentionné et ca fonctionne nickel !

Merci beaucoup Docmarti !

Bonne journée !