Code sur excel 2003 non compatible sur excel 2007!

**Patscaph** · 09/07/2014, 04h16

Bonjour,
J'ai trouvé un fichier excel sur http://boisgontierjacques.free.fr/ à l'item Formulaire "Formulaire liste multi-colonnes" FormIntuitifMultiColonnes ou le ficheir porte le nom de formulintuitive42.xls. Et bien je souhaite l'utiliser avec excel 2007 et ce dernier affiche un message d'erreur (Impossible de définir la propriété columwidths. Le type ne correspond pas.) Que dois-je modifier pour permettre à ce programme de fonctionner correctement? Je vous avoue que je suis très dépassé par ce type de problème et je souhaite que quelqu'un puisse m'aider. Merci à l'avance. Je met le fichier en question pour vous permettre de tester la problématique : recherchemulticolonne.xls
Au plaisir de vous lire à ce sujet...

**Menhir** · 09/07/2014, 10h12

Pourquoi ne poses-tu pas la question au créateur du code ?

**Docmarti** · 09/07/2014, 11h41

Bonjour Patscaph.

Quelle est la valeur qui est attribuée à .ColumnWidths ?
Est-ce une valeur de type STRING ?

**Patscaph** · 10/07/2014, 03h01

Bonjour Docmarti,

Je présume que la valeur de columnwidth est fonction de la largeur que le programme identifie aux cellules du tableau excel. Pour vous permettre de mieux comprendre quelque chose que je risque de trop mal expliquer, je vous suggère d'accéder au fichier joint initialement et de faire un déroulement pas à pas si ce n'est pas trop demandé. merci pour votre aide.

Pour répondre à Menhir,
Le site en question de JacquesBoisGontier ne m'indique pas comment joindre la personne en question et il y présente une multitude de code VBA et conseil très utile. Sans doute qu'il très connu de votre côté de l'atlantique alors peut être avez vous une adresse pour moi. merci à l'avance.

Au plaisir de voir lire.....

**Patscaph** · 10/07/2014, 04h34

Bonjour,
J'ai du développement pour ceux qui veulent bien m'aider. Et bien j'ai mis en commentaire la ligne de code problématique et maintenant le code passe. Toutefois, j'ai quand même besoin de l'inclure au code pour que la considération de la largeur des colonnes soit tenue en compte pour positionner les 'label' dans mon formulaire. Je pense que la solution est très simple et a trait à la syntaxe de 2003 qui ne serait pas compatible avec 2007. Voici la ligne provenant du userform:
'Me.ListBox1.ColumnWidths = temp
Que dois-je modifier pour cette ligne soit bien prise en compte?

Le code complet est le suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Private Sub UserForm_Initialize()
  Set f = Sheets("BD")
  nbcol = f.[A1].CurrentRegion.Columns.Count
  Me.ListBox1.ColumnCount = nbcol
  Set plage = f.[A1].CurrentRegion
  Set plage = plage.Offset(1).Resize(plage.Rows.Count - 1)
  Me.ListBox1.List = plage.Value
  i = 1
  x = 15
  For i = 1 To nbcol
    retour = Me.Controls.Add("Forms.Label.1", "Label" & i, True)
    Me("label" & i).Caption = f.Cells(1, i)
    Me("label" & i).Top = 45
    Me("label" & i).Left = x
    x = x + f.Columns(i).Width * 1.1
    temp = temp & f.Columns(i).Width * 1.1 & ";"
  Next
 
  'Me.ListBox1.ColumnWidths = temp      <---Code mit en commentaire
 
  For b = 1 To nbcol: Set Lbl(b).GrLabel = Me("Label" & b): Next b
End Sub

Pour plus de détail svp vous référer au fichier mit en pièce jointe au post initial.

**Menhir** · 10/07/2014, 10h18

Est-ce que tu as essayé, juste avant la ligne qui ne marche pas, de regarder le contenu de ta variable temp et de Me.ListBox1.ColumnWidths ?
Essaye de mettre avant cette ligne simplement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Debug.Print Me.ListBox1.ColumnWidths
Debug.Print temp

**Docmarti** · 10/07/2014, 15h40

Je pense comme Menhir que c'est la valeur de TEMP qui doit être modifiée:

Essayons d'abord d'y ajouter une précision : PT

Remplace

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

temp = temp & f.Columns(i).Width * 1.1 & ";"

par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

temp = temp & f.Columns(i).Width * 1.1 & " pt;"

**parmi** · 10/07/2014, 16h00

Bonjour,

Il y a combien de colonnes à ton fichier ?
Au cas où, une Listbox ne peut avoir plus de 10 colonnes (index 0 à 9)

**Patscaph** · 12/07/2014, 15h28

RE- Bonjour Docmarti et Menhir
Désolé du délais de retour de mes posts, je suis en transit et difficile de se connecter.

Bon, j'ai fait les vérifications du contenu de la variable temp et de Me.ListBox1.ColumnWidths

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

temp = temp & f.Columns(i).Width * 1.1 & ";"

et aussi avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

temp = temp & f.Columns(i).Width * 1.1 & " pt;".

et la valeur de temp est de la forme:
"34.95;38.98;54.899;85.95;"
et dans le second cas:
"34.95 pt;38.98 pt;54.899 pt;85.95 pt;"

Et pour le juste avant ...Me.ListBox1.ColumnWidths contient "49,5 pt;49,5 pt;49,5 pt;49,5 pt" ... et ce serait des valeurs inscrite par défaut, je crois.

Là c'est une question de syntaxe (je crois) entre "," et "." Je présume qu'une vigule est requise pour la décimale n'est-ce pas?
Aussi je remarque qu'il y a un ";" à la fin qui ne doit pas aider la cause.

Donc bravo à vous deux

, vous aviez parfaitement raison pour la source du problème. J'espère vous informer adéquatement et que votre solution sera conséquente. Merci Merci J'attends de vous relire.

Bonjour "Parmi", le nombre de colonne ne dépassera pas 10. Merci de cette précision.

**Docmarti** · 13/07/2014, 02h04

C'est bizarre de voir la propriété ColumnWidths du Listbox utiliser la virgule comme séparateur décimal alors que la valeur temp utilise le point.

temp = "34.95 pt;38.98 pt;54.899 pt;85.95 pt;"

.Me.ListBox1.ColumnWidths contient "49,5 pt;49,5 pt;49,5 pt;49,5 pt"

Ca vaut la peine de tenter de remplacer les points par des virgules dans la valeur Temp juste pour voir.

Que donne les Debug.Print dans le code suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Private Sub UserForm_Initialize()
  Set f = Sheets("BD")
  nbcol = f.[A1].CurrentRegion.Columns.Count
  Me.ListBox1.ColumnCount = nbcol
  Set plage = f.[A1].CurrentRegion
  Set plage = plage.Offset(1).Resize(plage.Rows.Count - 1)
  Me.ListBox1.List = plage.Value
  i = 1
  x = 15
 
  For i = 1 To nbcol
    retour = Me.Controls.Add("Forms.Label.1", "Label" & i, True)
    Me("label" & i).Caption = f.Cells(1, i)
    Me("label" & i).Top = 45
    Me("label" & i).Left = x
    x = x + f.Columns(i).Width * 1.1
    'temp = temp & f.Columns(i).Width * 1.1 & ";"
    temp = temp & f.Columns(i).Width * 1.1 & " pt;"
 
  Next
 Debug.Print "---------------"
 Debug.Print "0. temp = " & temp
 Debug.Print "1. Me.ListBox1.ColumnWidths = " & Me.ListBox1.ColumnWidths
 
  Debug.Print "1a. Replace(temp, ., ,)" & Replace(temp, ".", ",")
 
  Me.ListBox1.ColumnWidths = Replace(temp, ".", ",")
 
  Debug.Print "2. Me.ListBox1.ColumnWidths = " & Me.ListBox1.ColumnWidths
 
  Me.ListBox1.ColumnWidths = temp
 
  Debug.Print "3. Me.ListBox1.ColumnWidths = " & Me.ListBox1.ColumnWidths
 
  Debug.Print "4. Application.International(xlCountrySetting) = " & Application.International(xlCountrySetting)
 
   Debug.Print "5. Format(0, .) = " & Format(0, ".")
 
 
  For b = 1 To nbcol: Set Lbl(b).GrLabel = Me("Label" & b): Next b
End Sub

**Patscaph** · 13/07/2014, 15h17

Bonjour Docmarti
Tu es vraiment très gentil et ton support est très apprécié.
Avec ton dernier conseil, la lumière est apparue.
J'ai simplement fait les manipulations d'usage du contenu de la variable "temp" pour la formater au gout du code et le tour est joué. Tout fonctionne Nickel maintenant.
Merci à Docmarti et aussi à d'autres d'où j'ai lu que ma façon de poster méritait des ajustements. Je vais en tenir conte et au plaisir de vous relire sur une prochaine de mes questions.

Remplacer les "." par ";"
temp = Replace(temp, ".", ",")

Ensuite je supprimer le dernier ";"
temp = Mid(temp, 1, Len(temp) - 1)

Donc au final on a le code suivant qui passe tès bien le test pour la version excel 2007:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
Private Sub UserForm_Initialize()
  Set f = Sheets("BD")
  nbcol = f.[A1].CurrentRegion.Columns.Count
  Me.ListBox1.ColumnCount = nbcol
  Set plage = f.[A1].CurrentRegion
  Set plage = plage.Offset(1).Resize(plage.Rows.Count - 1)
  Me.ListBox1.List = plage.Value
  i = 1
  x = 15
  For i = 1 To nbcol
    retour = Me.Controls.Add("Forms.Label.1", "Label" & i, True)
    Me("label" & i).Caption = f.Cells(1, i)
    Me("label" & i).Top = 45
    Me("label" & i).Left = x
    x = x + f.Columns(i).Width * 1.1
    temp = temp & f.Columns(i).Width * 1.1 & " pt;"
  Next
  temp = Mid(temp, 1, Len(temp) - 1)
  temp = Replace(temp, ".", ",")
  Me.ListBox1.ColumnWidths = temp
 
  For b = 1 To nbcol: Set Lbl(b).GrLabel = Me("Label" & b): Next b
End Sub

Code sur excel 2003 non compatible sur excel 2007! [XL-2003]

Macros et VBA Excel

Discussions similaires

Partager

Partager