Discussion :

[guihu]

Bonjour à tous !

Je suis nouveau sur le forum et tout d'abord un grand merci d'avance pour votre aide et vos conseils.

Je suis de niveau débutant-intermédiaire et je bloque sur le problème suivant :

J'ai la liste suivante :
Pierre
Caillou
Feuille
Ciseau

Et j'aimerai créer un userform où l'utilisateur en ouvrant l'userform doit donner une valeur pour Pierre, cliquer sur le bouton "VALIDER", que la valeur correspondante soit enregistrée dans mon tableau puis à nouveau l'utilisateur doit donner une valeur pour Caillou, clique sur le bouton "VALIDER", que la valeur correspondante soit enregistrée dans mon tableau et ainsi de suite pour toutes les valeurs ...

L'exemple est assez simpliste mais la liste peut varier et je peux avoir plusieurs dizaines de données et j'aimerai comprendre comment je peux y arriver...

Merci par avance pour votre aide,
Guihu

[Mr Poulpe]

Bonjour,

Tu devrais faire un truc qui ressemble à :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("Feuil1").cells(1,1) = Textbox1.text

Avec comme évènement le clic sur le bouton

[helas]

Bonjour,
Peut-être plus simple sans formulaire mais en utilisant InputBox
sachant que la liste commence en A2 d'où ligne = 2
la boucle s'arrête dès la première cellule vide

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Sub saisie()
 Dim ligne As Long, s As String
 ligne = 2
 Do Until Sheets("Feuil1").Cells(ligne, 1) = ""
  s = InputBox("Entrer la valeur pour " & Sheets("Feuil1").Cells(ligne, 1) & " : ", "Saisie", vbOKCancel)
  Sheets("Feuil1").Cells(ligne, 2) = s
  ligne = ligne + 1
 Loop
End Sub

[Theze]

Bonjour,

Si tu veux malgré tout une Form, voici un petit exemple. Tu pose sur ta Form 1 Label, 1 TextBox et 1 bouton (dans un premier temps sans les renommer) puis tu colle le code ci-dessous dans le module de ta Form :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
 
Dim Tbl() As String
Dim TblIntitule
Dim I As Integer
 
Private Sub UserForm_Initialize()
 
   TblIntitule = Array("Pierre", "Ciseaux", "Feuille", "Cailloux")
   Label1.Caption = TblIntitule(0)
 
End Sub
 
Private Sub CommandButton1_Click()
 
    'redimensionne le tableau
    I = I + 1
    ReDim Preserve Tbl(1 To I)
 
    'y stocke la valeur
    Tbl(I) = TextBox1.Text
 
    'vide le TextBox
    TextBox1.Text = ""
 
    'si le compte est bon (ici, 4 valeurs)
    If I = 4 Then
 
        'petit message (à virer !)
        MsgBox "C'est fini !" & vbCrLf & _
               "Vous avez saisi les valeurs suivantes :" & vbCrLf & _
               Tbl(1) & vbCrLf & _
               Tbl(2) & vbCrLf & _
               Tbl(3) & vbCrLf & _
               Tbl(4)
 
        'inscrit les valeurs saisies dans la colonne A
        Range("A1:A" & UBound(Tbl)).Value = Application.WorksheetFunction.Transpose(Tbl())
 
        'vide le tableau
        Erase Tbl()
 
        'repart à zéro
        I = 0
 
        'et fin
        Exit Sub
 
    End If
 
    'défini le titre
    Label1.Caption = TblIntitule(I)
 
    'redonne le focus au TextBox
    TextBox1.SetFocus
 
End Sub

Hervé.

[guihu]

Merci à tous pour vos réponses.

La solution de Theze est tip top ce que je recherche, ça marche d'enfer !

A+