Discussion :

[Blaiz58]

Bonjour,

Je cherche une petite fonction permettant de m'afficher un message avant de modifier une cellule qui demanderait à l'utilisateur si il est sur de vouloir changer les données.

J'ai trouvé une solution pour quand on clique sur la cellule mais je veux quand on essaye de modifier la cellule. Et sans utiliser le verrouillage des feuilles.

Merci beaucoup

[parmi]

Bonjour,

Comme il n'y a pas d'événement déclenché par l'entrée de données, ce sera difficile.
Il y a Selection_Change et Change, mais un est quand on entre dans la cellule et l'autre quand on en sort...

Une solution serait de faire apparaître un textbox au-dessus de la cellule sélectionnée et d'agir sur un des événements de ce textbox (KeyUp, KeyDown ou KeyPress.

[Philippe Tulliez]

Bonjour,
Voici un exemple combinant les deux procédures événementielles.
S'il y a modification dans la colonne A de la feuille où se trouve ces deux procédures, un message de confirmation est affiché avec les boutons Oui, Non (Le focus étant sur ce dernier).
Si l'on répond Non, la valeur qui était dans la cellule précédemment est remise.
Pour que cela fonctionne, il faut déclarer la Variable ValCell en tête de module

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Option Explicit
Dim ValCell As Variant
Private Sub Worksheet_Change(ByVal Target As Range)
 If Target.Column = 1 And Target.Count = 1 Then
  Application.EnableEvents = False
   If MsgBox("Êtes-vous certain de modifier ", vbYesNo + vbExclamation + vbDefaultButton2) = vbNo Then
    Target.Value = ValCell
   End If
  Application.EnableEvents = True
 End If
End Sub
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
 If Target.Column = 1 And Target.Count = 1 Then
   ValCell = Target
 End If
End Sub

[Blaiz58]

Excellent ! Vraiment génial ça ! parce que le verrouillage des feuilles c'est pas très pratique et mes macros ne marchent plus après.


Merci beaucoup