Discussion :

[mouftie]

Bonjour,
J'ai créé un tableau nommé Tablo et je voudrais colorer les lignes en fonction des valeurs positionnées dans la 1ère colonne nommée D.
J'ai essayé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub BouclRows()
Dim  i As Long
i = 1
    For Each Row In Range("Tablo [D]")
Sheets("Feuil2").ListObjects("Tablo ").ListRows(i).Range.Select
     With Selection
        If Range("A" & i).Value = "u" Then Rows(i).Interior.ColorIndex = 4  'Vert brillant
        If Range("A" & i).Value = "t" Then Rows(i).Interior.ColorIndex = 7  'Rose fluo
        If Range("A" & i).Value =  "R" Then Rows(i).Interior.ColorIndex = 6  'Jaune fluo
     End With
     i = i + 1
    Next Row
End Sub

Mais dès que la condition est réalisée, toute la ligne est colorée et non la ligne limitée au Tablo
Merci de bien vouloir m'aider, svp

[Philippe Tulliez]

Bonjour,
Exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 Dim list As ListObject
 Set list = ThisWorkbook.Sheets("T_Client").ListObjects("Tablo")
 list.DataBodyRange.Rows(2).Interior.Color = vbRed

[mouftie]

Bonsoir Philippe,
Merci pour ton aide, j'avais bien essayé de passer par ListObject, mais je n'y suis pas arrivée
Avec ton exemple, j'ai écrit ça (si cça peut servir..)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub BouclRow3()
 Dim list As ListObject, i As Long
 Set list = ThisWorkbook.Sheets("Modèle").ListObjects("Tablo")
i = 2   'pour tenir compte des titres
 For Each Row In Range("Tablo[D]")
 If Range("G" & i).Value = "u" Then list.DataBodyRange.Rows(i - 1) _
    .Interior.ColorIndex = 4  'Vert brillant
 If Range("G" & i).Value = "t" Then list.DataBodyRange.Rows(i - 1) _
    .Interior.ColorIndex = 7  'Rose fluo
  If Range("G" & i).Value = "R" Then list.DataBodyRange.Rows(i - 1) _
    .Interior.ColorIndex = 6   'Jaune fluo
    i = i + 1
  Next Row
End Sub

Encore merci

[Philippe Tulliez]

Bonjour,
Tu mélanges des objets de la feuille (Range) et les objets de ListObject
Dans ce cas précis, si tu souhaites utiliser une variable incrémentée (i) utilise la boucle For to Next
Exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub MiseEnCouleurLigneTableauSuivantCondition()
 Dim list As ListObject, r As Long
 Set list = ThisWorkbook.Sheets("T_Client").ListObjects("Tablo")
 With list.DataBodyRange
  For r = 1 To .Rows.Count
   Select Case LCase(.Cells(r, 2)) ' Test sur la valeur minuscule de colonne B
    Case "a": .Rows(r).Interior.Color = vbRed
    Case "d": .Rows(r).Interior.Color = vbYellow
    Case Else: .Rows(r).Interior.Color = vbWhite
   End Select
  Next
 End With
End Sub

Une autre solution est possible bien entendu avec la boucle For Each In ... Next.