Discussion :

[citro]

Bonjour

je debute en VBA et je me casse la tete sur ce pb

je voudrais remplir ma combobox CboNom avec les données de la colonne A de la feuille Data.
Le souci est que le nombre de ligne de la colonne A est variable.

voici mon code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Sub userform_initialize()
 
'Récupération des listes permettant de remplir les différentes Combobox
Me.CboNom.RowSource = Sheets("Data").Range("a2", Range("a2").End(xlDown)) 'Liste des Noms
Me.CboBout.RowSource = "data!c2:c26" 'Liste des Bouteilles
Me.CboGil.RowSource = "data!d2:d28" 'Liste des Gilets
Me.CboDet.RowSource = "data!e2:e21" 'Liste des Détendeurs
Me.CboCombi.RowSource = "data!f2:f19" 'Liste des Combinaisons

Il me renvoie une erreur '1004'

Quelqu'un peut il m'aider ?

Merci

[casefayere]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub userform_initialize()
Dim Derlg As Range, Tbl
'Récupération des listes permettant de remplir les différentes Combobox
With Sheets("Data")
  Set Derlg = .Range("A" & .Rows.Count).End(xlUp)
  Tbl = .Range("A2", Derlg)
  cbonom.List = Tbl
  'ci-dessous, tu peux adapter ou laisser tel quel
  CboBout.RowSource = "data!C2:C26" 'Liste des Bouteilles
  CboGil.RowSource = "data!d2:d28" 'Liste des Gilets
  CboDet.RowSource = "data!e2:e21" 'Liste des Détendeurs
  CboCombi.RowSource = "data!f2:f19" 'Liste des Combinaisons
End With
End Sub

[citro]

Merci casefayere, cela marche nickel.

Je n'ai pas tout compris dans le code, mais le resultat est là.

Si tu peux m'éclairer sur 2 petit points , cela m'aidera pour l'avenir (c'est le pb lorsque l'on débute, on a tendance à poser des questions qui peuvent paraitre évidentes)
1 - dans la déclaration de la variable Derlg, tu la définis comme Range : OK. mais pourquoi mets tu ensuite ,Tbl ?
2 - Pourquoi, dans la commande Set, mets tu un point avant range et avant rows.count ? Cela vient il du fait que tu as utilisé la commande With Sheets("data") et que le . permet de dire que cela s'y rapporte ?

Merci

[Jean-Philippe André]

Salut,
l'erreur 1004 est ici due au fait que tu utilises un niveau Sheets dans ta ligne, mais aussi un niveau range

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.CboNom.RowSource = Sheets("Data").Range("a2", Range("a2").End(xlDown)) 'Liste des Noms

essaie avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.CboNom.RowSource = Sheets("Data").Range("a2", Sheets("Data").Range("a2").End(xlDown)) 'Liste des Noms

[casefayere]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub userform_initialize()
Dim Derlg As Range, Tbl
'Récupération des listes permettant de remplir les différentes Combobox
With Sheets("Data") 'donc avec feuille("Data")
  'c'est pour ça qu'il faut le point
  Set Derlg = .Range("A" & .Rows.Count).End(xlUp) 'une variable range qui stocke la cellule
  'cela remplace Sheets("Data").Range("A" & Sheets("Data").Rows.Count).End(xlUp)
  Tbl = .Range("A2", Derlg) 'Tbl est une variable tableau, ici elle remplace la plage spécifiée
  'plus pratique pour grands tableau, on gagne du temps
  cbonom.List = Tbl 'dans ce cas on utilise la propriété "List"
  'ci-dessous, tu peux adapter ou laisser tel quel
  CboBout.RowSource = "data!C2:C26" 'Liste des Bouteilles
  CboGil.RowSource = "data!d2:d28" 'Liste des Gilets
  CboDet.RowSource = "data!e2:e21" 'Liste des Détendeurs
  CboCombi.RowSource = "data!f2:f19" 'Liste des Combinaisons
End With
End Sub

[citro]

Merci beaucoup pour le temps que tu m'as accordé. C'est vraiment très sympa

Donc, tu as défini la variable Derlg à la fois comme cellule et comme tableau.
Je ne savais pas que l'on pouvait donner 2 types de données à la même variable.
Très pratique.

J'ai adapté ton code au reste de mes combobox.

Génial

[casefayere]

Donc, tu as défini la variable Derlg à la fois comme cellule et comme tableau.

non ce n'est pas une variable tableau, c'est un range !, le tableau sera en mémoire
ici :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Tbl = .Range("A2", Derlg)

remplace

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Tbl = .Range("A2", "la derniere cellule")

donc tbl qui est un tableau prend les valeurs de la plage

je reviens pour que tu comprennes :

1 - ouvres un nouveau fichier
2 - remplis la feuille1 de A1 à A20 de ce que tu veux
3 - essayes ce code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub test()
Dim Derlg As Range, Tbl, x As Integer
With Sheets("Feuil1")
  Set Derlg = .Range("A" & .Rows.Count).End(xlUp)
  Tbl = .Range("A1", Derlg)
  MsgBox "Valeur : " & Derlg & " adresse : " & Derlg.Address & " couleur police : " & Derlg.Font.Color
End With
For x = 1 To UBound(Tbl)
  MsgBox Tbl(x, 1)
Next x
End Sub

sinon voir la manipulation des tableaux, ici, entre autres http://silkyroad.developpez.com/vba/tableaux/

[citro]

Ok, alors pourquoi avoir écrit cela ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim Derlg As Range, Tbl

Je ne pige pas


En plus, j'ai essayé en l'enlevant et ça marche nickel aussi.
A quoi ça sert ?

Désolé d'être un boulet

[casefayere]

tu n'es pas un boulet mais tu n'as peut-être pas vu mon dernier post, regardes-le et dis-moi

[citro]

Yes, j'ai pigé.

Merci beaucoup.
Au plaisir