Discussion :

[Youpla Boum]

Bonjour,
J'ai passé la matinée à essayer de comprendre mon erreur sans succès.
Le but est de créer un graphique à partir de données présentes sur la feuille et en passant ainsi en revue 47 feuilles de mon classeur (dont les noms sont : "1", "2", etc).
J'ai essayé divers syntaxes, dont la dernière que je vous présente ici et que la plupart des gens ont l'air d'utiliser. Au passage, si vous avez une proposition de code sans passer par activechart ce serait formidable.
Malgré la simplicité de la demande, je suis coincée. J'espère que vous pourrez m'aider...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Public Sub Graphiques()
 
Dim feuillexploit As Integer
Dim feuillexploitstr As String
Dim ligne As Integer
Dim x As String
Dim y As String
Dim r As Range
 
For feuillexploit = 2 To 47
<div style="margin-left:40px">feuillexploitstr = CStr(feuillexploit)
Sheets(feuillexploitstr).Shapes.AddChart
Set r = Sheets(feuillexploitstr).Range("G2:I16")
ActiveChart.SetSourceData Source:=r 'C'est à cette ligne que ça coince
ActiveChart.ChartType = xlColumnStacked
ActiveChart.SeriesCollection(1).XValues = Sheets(feuillexploitstr).Range(Cells(2, 1), Cells(16, 1))</div>Next
End Sub

[mercatog]

Peut être comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub Graphiques()
Dim Ch As Chart
Dim Sr As Series
Dim i As Integer
Dim k As Byte
 
For i = 2 To 47
    With Worksheets(CStr(i))
        Set Ch = .ChartObjects.Add(100, 100, 500, 350).Chart
        Ch.ChartType = xlColumnStacked
 
        For k = 0 To 1
            Set Sr = Ch.SeriesCollection.NewSeries
            Sr.XValues = .Range("A2:A16")
            Sr.Values = .Range("G2:G16").Offset(, k)
            Set Sr = Nothing
        Next k
        Set Ch = Nothing
    End With
Next i
End Sub

[Youpla Boum]

Super, merci beaucoup !
Au moins, ça se déroule et je vais essayer de l'adapter pour avoir le graphique que je veux.
Quand savoir s'il faut utiliser "with" et "set" ? Qu'est ce que sont les objets ou types de données series et byte ?

[Gado2600]

Le set est pour attribuer une variable à un objet afin de l'utiliser plus tard.
Exemples :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
dim rec as dao.recordset
set rec = currentdb.openrecordset("Nom_Table", dbopendynaset)
rec.fields(1).value = 1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
dim oOutlook as Outlook.Application
set oOutlook = createboject("Outlook.Application")

le with sert plutôt pour éviter de répéter de grands appels
Exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
pptActivepresentation.slides(1).shapes(1).textframe.textrange.text = "Alpha"
pptActivepresentation.slides(1).shapes(2).textframe.textrange.text = "Beta"
pptActivepresentation.slides(1).shapes(3).textframe.textrange.text = "Delta"
pptActivepresentation.slides(1).shapes(4).textframe.textrange.text = "Gamma"

peut se remplacer par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
with pptActivepresentation.slides(1)
     .shapes(1).textframe.textrange.text = "Alpha"
     .shapes(2).textframe.textrange.text = "Beta"
     .shapes(3).textframe.textrange.text = "Delta"
     .shapes(4).textframe.textrange.text = "Gamma"
end with

Le set et le with peuvent se cumuler dans le besoin.

Cordialement,

[Youpla Boum]

Un grand merci à tous les deux : j'aurai appris quelque chose aujourd'hui !