Discussion :

[ldescham]

Bonjour,

suite à un travail d'annotation vidéo, j'obtiens un tableur récapitulatif qui contient, pour chaque annotation, le temps de début, le temps de fin, la durée et la valeur de l'annotation (ex : A) en fonction de catégories fixées à l'avance (ex : Comportement1).

Ex de données brutes :

Temps_début----Temps_fin---Durée---Comportement1---Comportement2---Comportement3
0--------------------60------------60--------A-----------------------------------------------------------------
0--------------------160-----------160-----------------------------------------------------A------------------
80------------------100------------20------------------------------A------------------------------------------
120-----------------200-----------80-------B-----------------------------------------------------------------
180-----------------280-----------100-----------------------------------------------------B-----------------
220-----------------260-----------40-------------------------------B-----------------------------------------
280-----------------320-----------40-------C-----------------------------------------------------------------
300-----------------420-----------120-----------------------------------------------------C-----------------
340-----------------420-----------80-------------------------------C-----------------------------------------

Or, comme vous en conviendrez, ce type de tableur complique l'analyse descriptive...

Je me trouve donc devant un problème de restructuration de mes données. L'idée serait de pouvoir réarranger les données en fonction d'une chronologie commune.

Ex de structuration espérée :

Temps---Comportement1---Comportement2---Comportement3
0-----------A---------------------------------------------A------------------
20---------A---------------------------------------------A------------------
40---------A---------------------------------------------A------------------
60---------A---------------------------------------------A------------------
80--------------------------------A----------------------A------------------
100------------------------------A-----------------------A-----------------
120-------B----------------------------------------------A------------------
140-------B----------------------------------------------A-----------------
160-------B----------------------------------------------A-----------------
180-------B----------------------------------------------B-----------------
200-------B----------------------------------------------B-----------------
220------------------------------B-----------------------B-----------------
240------------------------------B-----------------------B-----------------
260------------------------------B-----------------------B-----------------
280-------C----------------------------------------------B-----------------
300-------C----------------------------------------------C-----------------
320-------C----------------------------------------------C-----------------
340-----------------------------C------------------------C-----------------
360-----------------------------C------------------------C-----------------
380-----------------------------C------------------------C-----------------
400-----------------------------C------------------------C-----------------
420-----------------------------C------------------------C-----------------

J'ai essayé plusieurs formules, principalement à partir de la fonction SI (j'ai une expérience limitée d'Excel), mais je ne trouve pas de solution pour automatiser cette restructuration (j'ai en réalité un nombre de lignes très important et un nombre élevé de catégories de comportements).
Pouvez-vous me conseiller des fonctions ou formules qui me mettraient sur la bonne piste ? Pensez-vous qu'il soit nécessaire de passer par VBA ?

A toutes fins utiles, je peux joindre les fichiers de mes exemples, pour ne pas avoir à les saisir.

Je vous remercie pour tout conseil que vous pourrez m'apporter.

Cordialement,

Loïc.

[mercatog]

Solution VBA avec 3 comportements en utilisant une variable tableau. (Je ne sais pas si ainsi je vous aide vraiment)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Sub Traitement()
Dim LastLig As Long, i As Long, j As Long
Dim N As Long, M As Long, Nb As Long
Dim k As Byte
Dim Tb, Res()
 
Application.ScreenUpdating = False
With Worksheets("Feuil1")
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    N = Application.Min(.Range("C2:C" & LastLig))
    If N > 0 Then
        M = Application.Max(.Range("B2:B" & LastLig))
        Nb = M / N + 1
        Tb = .Range("A2:F" & LastLig)
        ReDim Res(1 To Nb, 1 To 4)
 
        For i = 1 To Nb
            Res(i, 1) = N * (i - 1)
            For j = 1 To LastLig - 1
                If Res(i, 1) >= Tb(j, 1) And Res(i, 1) <= Tb(j, 2) Then
                    For k = 2 To 4
                        If Res(i, k) = "" And Tb(j, k + 2) <> "" Then Res(i, k) = Tb(j, k + 2)
                    Next k
                End If
            Next j
        Next i
    End If
 
    With .Range("H1")
        .Resize(1, 4) = Array("Temps", "Comportement1", "Comportement2", "Comportement3")
        .Offset(1).Resize(Nb, 4) = Res
    End With
End With
End Sub

[ldescham]

Bonjour,

c'est impeccable, j'en espérais pas tant !! Avec ça, je pense pouvoir me débrouiller pour l'adapter à mes données.

Merci beaucoup !

Cordialement,

Loïc.

[mercatog]

(Je ne sais pas si ainsi je vous aide vraiment)

[ldescham]

Bonjour,

je me permets de relancer cette discussion, parce que je rencontre un problème avec un des fichiers que je dois traiter.

Le code fourni par mercatog marchait parfaitement, jusqu'à la survenue d'une "incompatibilité de type" avec l'un de mes fichiers...

Voici le code en question, avec en rouge, la ligne incriminée par le débogueur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Option Explicit

Sub b_Reclassement_Donnees_v2()

Dim LastLig As Long, i As Long, j As Long
Dim N As Long, M As Long, Nb As Long
Dim LastCol As Integer, k As Integer
Dim Tb, Res()

Application.ScreenUpdating = False
Sheets.Add After:=ActiveSheet
ActiveSheet.Name = "Final Data"

With Worksheets("Data")
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    LastCol = .Cells(1, .Columns.Count).End(xlToLeft).Column
    
    N = 20 
    If N > 0 Then
        M = Application.Max(.Range("B2:B" & LastLig)) 
        Nb = M / N + 1
        Tb = .Cells(2, 1).Resize(LastLig - 1, LastCol)
        ReDim Res(1 To Nb, 1 To LastCol - 2)
 
        For i = 1 To Nb
            Res(i, 1) = N * (i - 1)
            For j = 1 To LastLig - 1
                If Res(i, 1) >= Tb(j, 1) And Res(i, 1) <= Tb(j, 2) Then
                    For k = 2 To LastCol - 2
                        If Res(i, k) = "" And Tb(j, k + 2) <> "" Then Res(i, k) = Tb(j, k + 2)
                    Next k
                End If
            Next j
        Next i
    End If
      
    With Sheets("Final Data").Range("A1")
        .Resize(1, LastCol - 2).Value = Worksheets("Data").Cells(1, 3).Resize(1, LastCol - 2).Value
        .Offset(1).Resize(Nb, LastCol - 2) = Res
    End With
End With

Worksheets("Final Data").Range("A1").Value = "Temps (msec)"

End Sub

Ne maîtrisant toujours pas les variables tableau, malgré mes efforts pour y remédier, je ne trouve pas d'explication. Comme cette erreur est probablement due au fichier qui la provoque, je me permets de le joindre ici :

Fichier.xlsx

Je vous remercie d'avance pour toute l'aide que vous pourrez apporter, sachant que cette étape de mon traitement est la seule que je ne peux pas réaliser "à la main"...

Loïc.

[Philippe Tulliez]

Bonjour,
Sans avoir analysé le code, j'ai tendance à utiliser la fonction Len. Len(variable) = 0 ou Len(Variable)<>0 à la place de Variable = "" ou Variable <> "").
La fonction Len() fonctionne quel que soit le type de variable (Alphanumérique ou numérique)
Dans cet exemple, la ligne 3 renvoie un message d'erreur Incompatibilité de type alors que la ligne 2 fonctionne.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 Dim Var As Integer
 If Len(Var) Then MsgBox "Vide"
 If Var = "" Then MsgBox "Vide"

Si tu es certain que ta variable est numérique, il est préférable bien entendu de faire le test par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Var = 0 Then ....

[ldescham]

Bonjour,

si j'ai bien compris la syntaxe, ça donne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Len(Res(i, k)) = 0 And Len(Tb(j, k + 2)) <> 0 Then Res(i, k) = Tb(j, k + 2)

Mais je rencontre toujours une incompatibilité de type... J'ai aussi tenté de modifier la déclaration de la variable k pour la passer en As Long, mais sans succès. C'est très étrange sachant que ce code a parfaitement fonctionné jusque là.

Au passage, j'en profite pour mettre à jour le fichier d'exemple, qui ne permettait pas de tester directement le code :

Fichier.xlsx