Discussion :

[Invité]

Bonjour,

Je voudrais compléter le tableau TB à partir du tableau TD. TB est en feuille BD et TD en feuille donnees.

correspondances des données:

TB------------colB-----------colC-----------colD------------colE-----------colF-----------colG
TD------------colA-----------colB-----------colC------------colD-----------colE-----------colF

suivant la correspondance de colonne les données sont identiques.

Sur la feuille donnees (TD), en colF figure des noms que je voudrais inscrire en colG de la feuille BD (TB).

En vous remerciant beaucoup pour votre précieuse aide.

Cordialement,

[Marc-L]

Bonjour, bonjour,

c'est quoi la question ? Quelle est la difficulté rencontrée ? Où est le code ? (entre balises, merci !)

[Invité]

Bonjour,

La question est comment reporter les données de la colonne F de la feuille "donnees" dans la colonne G de la feuille "BD".

Les critères sont l'égalité des données entre les colonnes des 2 feuilles:

feuille "donnees".........colA..............colB............colC...........colD
feuille "BD".................colB..............colC............colD...........colE

la colonne D feuille "donnees" contient des décimaux nous prendrons l'entier. c'est identique pour la colonne E de la feuille "BD".
Je ne maitrise pas bien (pour ne pas dire pas du tout) les tableaux, je n'arrive pas à traduire ce que je faire en code.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Option Explicit
 
Sub completer_bd()
Dim LastLig As Long, i As Long, j As Long
Dim Tb, Td
 
With Worksheets("donnees")
LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
Td = .Range("A2:F" & LastLig)
End With
 
With Worksheets("bd")
    LastLig = .Cells(.Rows.Count, "B").End(xlUp).Row
    Tb = .Range("B2:G" & LastLig)
    For i = 1 To LastLig - 1
    'comment utiliser les tableaux, pour faire comparaison et inscrire appareil en colonne G
      If Td(i, 1) = Tb(j, 1) And Td(i, 2) = Tb(j, 2) And Td(i, 3) = Tb(j, 3) And Int(Td(i, 4)) = Int(Tb(j, 4)) Then
      Tb(j, 6) = Td(i, 6)
 
    Next i
    .Range("C2:G" & LastLig) = Tb
End With
End Sub

En vous remerciant par avance.

Cordialement,

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Option Explicit
 
Sub Completer_Bd()
Dim LastLigD As Long, LastLigB As Long, i As Long, j As Long
Dim Tb, Td
 
With Worksheets("DONNEES")
    LastLigD = .Cells(.Rows.Count, "A").End(xlUp).Row
    Td = .Range("A2:F" & LastLigD)
End With
 
With Worksheets("BD")
    LastLigB = .Cells(.Rows.Count, "B").End(xlUp).Row
    Tb = .Range("B2:G" & LastLigB)
    For i = 1 To LastLigD - 1
        For j = 1 To LastLigB - 1
            If Td(i, 1) = Tb(j, 1) And Td(i, 2) = Tb(j, 2) And Td(i, 3) = Tb(j, 3) And Int(Td(i, 4)) = Int(Tb(j, 4)) Then Tb(j, 6) = Td(i, 6)
        Next j
    Next i
    .Range("B2:G" & LastLigB) = Tb
End With
End Sub

[Invité]

Bonjour Mercatog,

Je te remercie beaucoup. Comme à l'accoutumée, tes codes sont parfaits.

je t'avoue que j'ai fait un effort pour comprendre le fonctionnement des tableaux. J'ai étudié quelques les tutoriaux sur le sujet, effectué quelques exercices simples proposés. Mais comme tout se passe en mémoire et que je n'arrive pas à les conceptualiser dans ma petite, ça me déroute complétement.

Encore merci. Joyeuses fêtes de Pâques.

Cordialement,

[mercatog]

Il suffit de faire une analogie entre Cellules d'une plage sur une feuille et les cases d'une variable tableau.

En effet quant tu écris Tb=Feuil1.Range("B4:E25").Value -
Tb(3,2) correspond à Feuil1.Range("B4:E25").Cells(3,2) càd Feuil1.Cells(6, 3) ou Feuil1.Range("C6") -

Tb(1,1) correspond à Feuil1.Range("B4:E25").Cells(1,1) càd Feuil1.Cells(4, 2) ou Feuil1.Range("B4")Fais une petite illustration.