Discussion :

[Aquolost]

Bonjour à tous,

J'ai un souci avec ma programmation...
Je m'explique :

J'ai un formulaire avec 2 combobox : cbo_Type et cbo_Reference
Dans ma table j'ai X colonnes dont Type et Reference
Lorsque je sélectionne un choix dans mes cbo et que je clique sur un bouton Recherche j'affiche mes résultats dans une zone de liste appelé Resultat.

Jusque là pas de souci.

Cela ce complique lorsque je cherche à faire une mise en forme des colonnes dans la zone de liste en fonction de mes choix dans mes cbo.

En fait mon plus gros souci est que je veux mettre en forme ma zone de liste en fonction de la valeur de ma colonne Type même quand je cherche via une référence.
Lorsque je sélectionne via ma cbo_Type, pas de souci, j'ai trouvé comment faire.

Par contre lorsque je sélectionne une Reference dans ma cbo_Reference, je ne sais pas comment lui dire d'aller regarder dans la colonne Type la valeur correspondante et de me faire une mise en forme bien précise, dans ma zone de liste, en fonction de cette valeur.

J'espère avoir été suffisamment clair.

Merci d'avance de votre aide

[ClaudeLELOUP]

Bonjour et bienvenue parmi nous,

J'espère avoir été suffisamment clair.

Vu le nombre de réponses : sans doute que non !

Ce serait sans doute plus concret si tu postais quelques captures d'écran pour illustrer ta demande.

[Aquolost]

Merci pour l’accueil et pour ta remarque Claude, je vais essayer d'illustrer mon propos.

Formulaire vierge :




Mise en forme tableau avec cbo_Type rempli avec le mot "Connecteur SUB-D HD" :




Mise en forme tableau avec cbo_Type rempli avec le mot "Contact" :




Mise en forme tableau avec cbo_Reference rempli avec n'importe quelles valeurs :



Vous pouvez voir dans cette dernière capture que la mise en forme du tableau, quand je sélectionne une référence, est celle du tableau sans résultat du formulaire vierge.
Vous pouvez voir également, dans les résultat, que le Type associé à cette Référence est "Contact".
Je souhaiterais donc que la mise en forme de ce résultat soit la même que pour la 3e capture d’écran.
Et si le Type associé à une Référence est "Connecteur SUB-D HD", que la mise en forme soit la même que la 2e capture d'écran.

En espérant que cela ai pu vous aider...

Cordialement

[ClaudeLELOUP]

Bonjour,

Ai-je compris ?

Tu as 3 formats distincts :
1 Reference, Fabricant, Taille Contacts, Type de contact, Pince, Locator
2 Reference, Fabricant, Type de contact, Pince, Locator
3 Type, Reference, Fabricant, Type de contact, Pince, Locator, Type de raccord
Ils dépendent du choix opéré dans tes zones de liste modifiable.
Lorsque, c’est le format 3 qui serait normalement choisi, mais que Type s’avère être égal à « Contact », c’est le format 2 qui doit primer.

Je ferais comme ceci :
Trois requêtes enregistrées qui font référence au contenu du formulaire.
C’est l’événement Clic de Recherche qui déclenche l’affectation de la requête ad hoc en tant que source de ta liste.
Avant d’affecter le format 3, on teste d’abord (avec une fonction de domaine) si la colonne Type contient « Contact », si oui, on affecte le format 2. Sinon, format 3.

[Aquolost]

C'est exactement ca...

Avant d’affecter le format 3, on teste d’abord (avec une fonction de domaine) si la colonne Type contient « Contact », si oui, on affecte le format 2. Sinon, format 3.

Mais justement, ce que je n'arrive pas à faire, c'est cette vérification de la colonne Type et cet affichage conditionné par le résultat de cette vérification.
Je suis néophyte en vba et j'avoue que la fonction de domaine ne me parle pas.

J'ai essayé pleins de choses mais c'est toujours le format 3 qui ressort à l'affichage.

C'est surement tout bete mais je coince sur la rédaction du code lui-même.

[ClaudeLELOUP]

Peux-tu poster un échantillon de ta db avec la table et le formulaire dans une version compatible Access2000 ?

Cela me permettra de t'expliquer sur un exemple concret.

[Aquolost]

Voici ma table :


Et mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
 
 
Private Sub Btn_Recherche_Click()
 
Dim strField As String
Dim strCriteria As String
Dim strCriteria2 As String
Dim strCriteria3 As String
Dim strCriteria4 As String
Dim strSql As String
Dim strSql2 As String
Dim strSql3 As String
Dim strSql4 As String
 
strCriteria = ""
strCriteria2 = ""
strCriteria3 = ""
strCriteria4 = ""
 
' compose le critere de recherche
If Not IsNull(Me.cbo_Type.Value) And Me.cbo_Type.Value <> "" Then
    strCriteria = " WHERE BDD.Type Like " & Chr(34) & cbo_Type.Value & Chr(34)
    If Not IsNull(Me.cbo_Reference.Value) And Me.cbo_Reference.Value <> "" Then
        strCriteria = strCriteria & " AND BDD.Reference Like " & Chr(34) & Me.cbo_Reference.Value & Chr(34)
    End If
Else
    If Not IsNull(Me.cbo_Reference.Value) And Me.cbo_Reference.Value <> "" Then
        strCriteria = " WHERE BDD.Reference Like " & Chr(34) & Me.cbo_Reference.Value & Chr(34)
    End If
End If
 
If Not IsNull(Me.cbo_Reference.Value) And Me.cbo_Reference.Value <> "" Then
    strCriteria = " WHERE BDD.Reference Like " & Chr(34) & cbo_Reference.Value & Chr(34)
    If Not IsNull(Me.cbo_Fabricant.Value) And Me.cbo_Fabricant.Value <> "" Then
        strCriteria = strCriteria & " AND BDD.Fabricant Like " & Chr(34) & Me.cbo_Fabricant.Value & Chr(34)
    End If
Else
    If Not IsNull(Me.cbo_Fabricant.Value) And Me.cbo_Fabricant.Value <> "" Then
        strCriteria = " WHERE BDD.Fabricant Like " & Chr(34) & Me.cbo_Fabricant.Value & Chr(34)
    End If
End If
 
 
' construit la requête sql
strSql = "SELECT DISTINCTROW BDD.*"
strSql = strSql & " FROM BDD "
If strCriteria <> "" Then
    strSql = strSql & strCriteria
End If
 
strSql2 = "SELECT DISTINCTROW BDD.Reference, BDD.Fabricant, BDD.[Type de contact], BDD.Pince, BDD.Locator"
strSql2 = strSql2 & " FROM BDD "
If strCriteria Like "*Contact*" Then
    Me.Resultat.ColumnCount = 5
    Me.Resultat.Width = 8500
    Me.Resultat.Left = 4200
    Me.Resultat.ColumnWidths = "3cm;2cm;4cm;3cm;3cm"
    strSql = strSql2 & strCriteria
End If
 
strSql3 = "SELECT DISTINCTROW BDD.Reference, BDD.Fabricant, BDD.Taille, BDD.[Type de raccord]"
strSql3 = strSql3 & " FROM BDD "
If strCriteria Like "*Raccord*" Then
    Me.Resultat.ColumnCount = 4
    Me.Resultat.Width = 8000
    Me.Resultat.Left = 4300
    Me.Resultat.ColumnWidths = "3cm;2cm;2cm;4cm"
    strSql = strSql3 & strCriteria
End If
 
strSql4 = "SELECT DISTINCTROW BDD.Reference, BDD.Fabricant, BDD.Taille, BDD.Contacts, BDD.[Type de contact], BDD.Pince, BDD.Locator"
strSql4 = strSql4 & " FROM BDD"
If strCriteria Like "*Connecteur*" Then
    Me.Resultat.ColumnCount = 7
    Me.Resultat.Width = 12000
    Me.Resultat.Left = 2200
    Me.Resultat.ColumnWidths = "3cm;2cm;2cm;4cm;4cm;3cm;3cm"
    strSql = strSql4 & strCriteria
End If
 
'Debug.Print strSql
 
Me.Resultat.RowSource = strSql ' affecte sql au tableau
 
 
End Sub
 
 
Private Sub cbo_Fabricant_Change()
    Me.cbo_Type.RowSource = " SELECT DISTINCT BDD.Type FROM BDD WHERE BDD.Fabricant = " & Chr(34) & cbo_Fabricant.Value & Chr(34)
    Me.cbo_Reference.RowSource = " SELECT DISTINCT BDD.Reference FROM BDD WHERE BDD.Fabricant = " & Chr(34) & cbo_Fabricant.Value & Chr(34)
End Sub
 
Private Sub cbo_Reference_Change()
    Me.cbo_Type.RowSource = " SELECT DISTINCT BDD.Type FROM BDD WHERE BDD.Reference = " & Chr(34) & cbo_Reference.Value & Chr(34)
    Me.cbo_Fabricant.RowSource = " SELECT DISTINCT BDD.Fabricant FROM BDD WHERE BDD.Reference = " & Chr(34) & cbo_Reference.Value & Chr(34)
End Sub
 
Private Sub cbo_Type_Change()
    Me.cbo_Reference.RowSource = " SELECT DISTINCT BDD.Reference FROM BDD WHERE BDD.Type = " & Chr(34) & cbo_Type.Value & Chr(34)
    Me.cbo_Fabricant.RowSource = " SELECT DISTINCT BDD.Fabricant FROM BDD WHERE BDD.Type = " & Chr(34) & cbo_Type.Value & Chr(34)
 
End Sub
 
Private Sub RAZ_Click()
    DoCmd.Close acForm, "Recherche", acSaveNo
    DoCmd.OpenForm "Recherche"
End Sub

Je n'arrive pas à mettre ma mdb directement en pièce jointe

[ClaudeLELOUP]

C'est probablement le formulaire qui fait problème.

Prends un copie de ta db.

Dans cette copie, ne garde que la table et alors sauve cette copie sous le format Access2000.

[Aquolost]

Non ca ne fonctionne pas non plus, cela me marque fichier non valide...

EDIT : Je viens de voir que le .mdb n'était pas dans la liste des fichiers acceptés

EDIT 2 : En le zippant ca marche ^^
Référentiel.rar

[ClaudeLELOUP]

Ok, maintenant, je peux lire.

Quelles colonnes veux-tu afficher lorsque l'utilisateur recherche par "Fabricant" ?

Veux-tu que l'utilisateur puisse rechercher selon plusieurs critères à la fois (ex : tel Type et tel fabricant) ou bien 1 seul critère à la fois ?

Lorsque tu recherches par Référence, as-tu la garantie qu'un seul enregistrement sera trouvé. En d'autres mots, pas de risque de rencontrer des enregistrements Type "Contact" et des Type "Autre" simultanément.

[Aquolost]

Quelles colonnes veux-tu afficher lorsque l'utilisateur recherche par "Fabricant" ?

Tous mes affichages de colonne se feront en fonction de la valeur du Type.
Ici : 1 affichage pour le type "Connecteur", 1 pour "Contact" et dans mon code j'avais prévu aussi un affichage pour un type "Raccord" mais je n'en ai pas encore mis dans ma table.

Veux-tu que l'utilisateur puisse rechercher selon plusieurs critères à la fois (ex : tel Type et tel fabricant) ou bien 1 seul critère à la fois ?

Je souhaite qu'il puisse chercher avec 1, 2 ou les 3 critères.

Lorsque tu recherches par Référence, as-tu la garantie qu'un seul enregistrement sera trouvé. En d'autres mots, pas de risque de rencontrer des enregistrements Type "Contact" et des Type "Autre" simultanément.

Cela ne devrait, normalement, jamais arrivé mais je ne suis malheuresement pas maitre des références données par les fabricants, mais je pense que cela est peu probable.
Par contre dans la recherche sur le seul critère de "Fabricant", cela va inévitablement arrivé car un même fabricant peut fabriquer des connecteurs et des contacts.
Je pense que dans ce cas là, seul un affichage de la colonne "Type" et de la colonne "Référence" sera utile.
L'utilisateur pourra ainsi affiner sa recherche avec les combobox.

[ClaudeLELOUP]

D’une manière générale

- prends l’habitude de donner une clé à tes tables : un champ type NuméroAuto et un nom qui se termine par PK (Primary Key)
- évite les espaces et les caractères spéciaux dans les noms d’objets et de contrôles ;



- dans les modules, ajoute systématiquement l’option Explicit



- compacte la db lors de sa fermeture



- pour les sources de tes zones de liste, fais en sorte que chaque choix n’ait qu’une occurrence, par exemple pour cbo_Type :



-----------
L’idée

Plusieurs requêtes enregistrées pour présenter les résultats

Principe :
- elle contient les colonnes souhaitées, dans l’ordre ;
- la colonne qui correspond au critère cliqué est comparée à la valeur du choix opéré ;
- les colonnes qui correspondent aux autres critères sont comparées au choix éventuel opéré pour ces critères.
Exemple pour rFabricant :



- deux exceptions :
pour rContact, où les colonnes sont comparées au choix éventuel opéré pour les critères




et pour rTous, où aucune limite n’est posée




Comment ça marche

À l’ouverture du formulaire, on affiche tous les enregistrements de la table

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub Form_Open(Cancel As Integer)
  'Afficher tous les enregistrements
   Me.Resultat.RowSource = "rTous"
   Me.Resultat.ColumnCount = CurrentDb.QueryDefs("rTous").Fields.Count
End Sub

Remarque

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.Resultat.ColumnCount = CurrentDb.QueryDefs("rNomDeLaRequête").Fields.Count

qui permet d’attribuer le nombre de colonnes à la zone de liste

Si l’utilisateur choisit un type, de deux choses l’une :
ou bien il a choisi « Contact » et c’est rContact qui doit être assignée ;
ou bien il a choisi autre chose et c’est rType qui doit être assignée.
Voici le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub cbo_Type_AfterUpdate()
  If Me.cbo_Type = "Contact" Then
      Me.Resultat.RowSource = "rContact"
      Me.Resultat.ColumnCount = CurrentDb.QueryDefs("rContact").Fields.Count
    Else
      Me.Resultat.RowSource = "rType"
      Me.Resultat.ColumnCount = CurrentDb.QueryDefs("rType").Fields.Count
  End If
End Sub

Si l’utilisateur choisit une référence, si l’enregistrement levé est de type « contact », c’est le format rContact. Sinon, c’est le format rReference. Voici le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub cbo_Reference_AfterUpdate()
  'La sélection contient-elle des enregistrements du type contact ?
  If DCount("Type", "rReference", "Type=""Contact""") = 0 Then    'ce n'est le cas => rReference
      Me.Resultat.RowSource = "rReference"
      Me.Resultat.ColumnCount = CurrentDb.QueryDefs("rReference").Fields.Count
    Else                                                          'c'est le cas => rContact
      Me.Resultat.RowSource = "rContact"
      Me.Resultat.ColumnCount = CurrentDb.QueryDefs("rContact").Fields.Count
  End If
End Sub

N.B. Dcount est une fonction de domaine.
Pour te documenter à ce sujet, ma référence, c’est le tutoriel de Philippe JOCHMANS Les fonctions de domaine.

Pour les autres choix, il suffit d’affecter la requête ad hoc :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub cbo_Fabricant_AfterUpdate()
   Me.Resultat.RowSource = "rFabricant"
   Me.Resultat.ColumnCount = CurrentDb.QueryDefs("rFabricant").Fields.Count
End Sub
 
Private Sub cbo_Raccord_AfterUpdate()
   Me.Resultat.RowSource = "rRaccord"
   Me.Resultat.ColumnCount = CurrentDb.QueryDefs("rRaccord").Fields.Count
End Sub

Pour réinitialiser les choix : clic sur le bouton RAZ

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub RAZ_Click()
  Dim ctl As Control
  'Réinitialiser les choix
  For Each ctl In Me.Controls
    If ctl.Name Like "cbo_*" Then
        ctl = Null
    End If
  Next ctl
  'Afficher tous les enregistrements
   Me.Resultat.RowSource = "rTous"
   Me.Resultat.ColumnCount = CurrentDb.QueryDefs("rTous").Fields.Count
End Sub

Cela suppose que tous les contrôles nommés « cbo_nnn » sont des critères.


La db exemple est ici : http://claudeleloup.developpez.com/F...03Aquolost.mdb

[Aquolost]

Je prends en compte les remarques générales et me les note dans un coin

Merci beaucoup pour toutes ces explications, c'est tout de suite plus clair.

Je vais regarder la db jointe et je reviens vers toi très vite...

[Aquolost]

Bonjour Claude,

Après avoir parcouru la db ce week-end, je ne peux dire autre chose qu'un grand merci à toi.
J'ai apporté juste quelques petites touches personnelles mais c'est exactement ce que je voulais faire.

Merci infiniment de ton aide car tu m'as enlevé une bonne épine du pied

Peu être à bientôt lors d'un autre post qui sait

[ClaudeLELOUP]

Au plaisir de te recroiser.
À+