Discussion :

[mercatog]

Bonjour Cathodique, casefayere, clementmarcotte et le forum.

Une autre proposition

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub HP()
Dim LastLig As Long
Dim c As Range
 
Application.ScreenUpdating = False
With Worksheets("Feuil1")
    .PageSetup.PrintTitleRows = "$2:$4"
    .ResetAllPageBreaks
 
    LastLig = .Cells(.Rows.Count, "B").End(xlUp).Row
    Set c = .Range("B" & LastLig).MergeArea(1, 1)
    Do While c.Row > .Range("B4").MergeArea.Count + 4
        .HPageBreaks.Add Before:=c
        Set c = c.Offset(-1, 0).MergeArea
    Loop
    Set c = Nothing
End With
End Sub

EDIT: Valable même si un groupe contient une seule ligne (pas de fusion)

[casefayere]

Bonjour mercatog,

Ta solution pour les sauts de page me plait (toujours aussi efficace), vois-tu une solution plus rationnelle que la mienne quant à créer les cellules fusionnées ?

Ce n'est pas pour moi mais ça instruit toujours,

Bonne journée

[mercatog]

Bonjour Dominique

Pour fusionner et appliquer les sauts de pages, je ferai à la PCMan

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Fusion()
Dim LastLig As Long, i As Long
 
Application.ScreenUpdating = False
With Worksheets("Feuil1")
    LastLig = .Cells(.Rows.Count, "B").End(xlUp).Row
    For i = LastLig To 5 Step -1
        If .Range("B" & i) = .Range("B" & i - 1) Then
            .Range("B" & i - 1).ClearContents
            .Range("B" & i - 1 & ":B" & i).Merge
        Else
            If i > 5 Then .HPageBreaks.Add Before:=.Range("B" & i - 1)
        End If
    Next i
End With
End Sub

[casefayere]

Merci,



sauf que j'ai remarqué, d'après le fichier envoyé par cathodique que tes sauts de page se retrouvent décalés, je corrigerais donc cette ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

            If i > 5 Then .HPageBreaks.Add Before:=.Range("B" & i)

[mercatog]

Oui effectivement tu as raison Dominique.

[Invité]

Bonjour Mercatog, Casefayere, Clementmarcotte, le forum,

Rien à redire, ça confirme ce que je pense Mercatog tu es un AS. Casefayere ne démérite pas non plus.

Quant à Clementmarcotte, il a le mérite de m'avoir incité à orienter mes recherches ailleurs que sur Developpez.com.

Et je dois dire que mes récentes recherches ont été payantes. je n'ai effectué que quelques modifications.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub SautDePage()
'saut de page par rapport à des cellules fusionnées
Dim DerLig, Lig
 
ActiveSheet.PageSetup.PrintTitleRows = "$2:$4" 'entete tableau
ActiveSheet.ResetAllPageBreaks ' raz saut
 
    DerLig = Range("B" & Rows.Count).End(xlUp).Row
 
    For Lig = 4 To DerLig
        Cells(Lig + 1, "B").Select
        If Selection.Count > 1 Then
            ActiveWindow.SelectedSheets.HPageBreaks.Add Before:=Cells(Lig + Selection.Count + 1, "A")
            Lig = Lig + Selection.Count - 1
        End If
    Next Lig
End Sub

Je vous remercie tous autant que vous êtes. Toute ma gratitude.

Cordialement,

Cat