Discussion :

[fmris]

Bonjour
Je veux creer une Listbox1dont les rowsource seraient bien defini (exemple A1:D5).
Je voudrais offrir la possiblité de sélectionner plusieurs lignes de cette Listbox1 et les "transférer" dans une Listbox2 en les validant par un bouton.
Comment procéder ?????????

[Philippe Tulliez]

Bonjour,
Voici un exemple d'une procédure qui transfère les lignes d'un ListBox vers un autre.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub MoveListBox(FromListBox As MSForms.ListBox, ToListBox As MSForms.ListBox)
 Dim c As Integer
 With FromListBox
  ToListBox.AddItem .List(.ListIndex, 0)
  For c = 1 To .ColumnCount: ToListBox.List(ToListBox.ListCount - 1, c) = .List(.ListIndex, c): Next
  .RemoveItem (.ListIndex)
 End With
End Sub

Les procédures événementielles qui l'appelle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
  MoveListBox Me.ListBox1, Me.ListBox2
End Sub
Private Sub ListBox2_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
  MoveListBox Me.ListBox2, Me.ListBox1
End Sub

Dans cet exemple, le ListBox1 est le seul qui a des données au chargement du UserForm et il y a plus d'une colonne dans les ListBox.

[fmris]

bonjour
j'ai testé les codes (que je n'ai pas compris) et ca fonctonne pas.

erreur de compilation dans .removeitem.
Peux tu me renvoyer une feuille .xls avec les procédures et fonction associés et qui fonctionne. Ce sera plus simple et cela me permettra de voir si je me suis bien fait comprendre dans ma demande.
merci !!

[Philippe Tulliez]

Bonjour,
Le code que j'ai publié ne fonctionnait pas avec la propriété RowSource mais avec la méthode AddItem ce qui explique sans doute que le programme n'a pas fonctionné.
La procédure MoveListBox ne fonctionne pas non plus avec la multi-sélection. Je suis en train de l'adapter et la publierai dès que mes tests seront terminés avec un classeur l'accompagnant.
Le but était de montrer un exemple.
Voici le code complet. Le UserForm a deux ListBox (1 & 2). Un double Clic sur une ligne sélectionnée fait passer cette ligne dans l'autre ListBox

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Option Explicit
Dim rng As Range, sht As Worksheet
Private Sub UserForm_Initialize()
  InitData
  InitListBox
End Sub
Private Sub InitData()
  Set sht = ThisWorkbook.Worksheets("db")
  Set rng = sht.Range("A1").CurrentRegion
End Sub
Private Sub InitListBox()
  Dim r As Long, c As Integer, ColWidth As String
  ColWidth = "0;50;50;50"
  With ListBox1
  .ColumnCount = rng.Columns.Count
  .ColumnWidths = ColWidth
    For r = 2 To rng.Rows.Count ' Maximum 9
     'If rng.Cells(r, 5) = "F" And rng.Cells(r, 6) = "C" Then
       .AddItem r
       For c = 1 To rng.Columns.Count: .List(.ListCount - 1, c) = sht.Cells(r, c): Next
     'End If
    Next r
  End With
  With ListBox2
  .ColumnCount = rng.Columns.Count
  .ColumnWidths = ColWidth
  End With
End Sub
Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
  MoveListBox Me.ListBox1, Me.ListBox2
End Sub
Private Sub ListBox2_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
  MoveListBox Me.ListBox2, Me.ListBox1
End Sub
Sub MoveListBox(FromListBox As MSForms.ListBox, ToListBox As MSForms.ListBox)
 Dim c As Integer
 With FromListBox
  ToListBox.AddItem .List(.ListIndex, 0)
  For c = 1 To .ColumnCount: ToListBox.List(ToListBox.ListCount - 1, c) = .List(.ListIndex, c): Next
  .RemoveItem (.ListIndex)
 End With
End Sub

[Phil'oche]

Il me semblait bien avoir déjà vu une solution ailleurs...

Va faire un tour PAR ICI, je pense que tu trouveras ton bonheur...