Discussion :

[Gegedj]

Bonjour,

Voila je m'explique, j'ai un fichier excel avec 1 seul colonne comme suit :

1. Vide
2. Vide
3. Vide
4. Vide
5. NOM Prenom
6. Adresse
7. Ville
8. Nom Prenom
9. Adresse
10. Ville
11. NOM Prenom
12. Adresse
13. Ville
14. Nom Prenom
15. Adresse
16. Ville
17. NOM Prenom
18. Adresse
19. Ville
20. Nom Prenom
21. Adresse
22. Ville
23. Vide
24. Vide
25. Vide
26. Vide
27. NOM Prenom
28. Adresse
29. Ville
30. Nom Prenom
31. Adresse
32. Ville
33. .....

J'aurais besoin de faire 3 colonnes, le 1er avec Nom Prenom, la 2eme avec l'adresse, la 3eme la ville.

Pour être précis, tous les 18 lignes j'ai 4 lignes vides.

Je ne pense pas que cela soit compliqué mais quelqu'un peut-il m'aider a faire un code pour cela ?

Merci

[joe.levrai]

Bonjour,

en l'absence de précisions, j'ai pris pour règles du jeu :

- les données sources sont dans une feuille
- les données réagencées arrivent dans une autre
- les deux plages sont sur la colonne A

je te laisse modifier selon tes besoins.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
 
Sub Arrange()
 
Dim Wb As Workbook
 
Dim ShSource As Worksheet
Dim ShDest As Worksheet
 
Dim CellSource As Range
Dim Celldest As Range
 
Dim Cpt as Integer
 
Set Wb = ThisWorkbook
Set ShSource = Wb.Worksheets("LaFeuilleOùSontTesLignes")
Set ShDest = Wb.Worksheets("LaFeuilleOùExporterLeTri")
 
 
Cpt = 0
For Each CellSource In ShSource.Range("A1", "A" & ShSource.UsedRange.Rows.Count)
    If CellSource <> "" Then
        If Cpt = 0 Then
            Set Celldest = ShDest.Range("A65535").End(xlUp)(2)
            Celldest = CellSource
            Cpt = Cpt + 1
        ElseIf Cpt = 1 Then
                Celldest.Offset(0, 1) = CellSource
                Cpt = Cpt + 1
        ElseIf Cpt = 2 Then
                Celldest.Offset(0, 2) = CellSource
                Cpt = 0
        End If
    End If
Next CellSource
End Sub

Edit : correction terminologique, ce n'est pas un tri mais un agencement

[Gegedj]

Merci pour la réponse, sa me donne une erreur :

L'indice n'appartient pas a la sélection

a la ligne : Set ShSource = Wb.Worksheets("LaFeuilleOùSontTesLignes")

Sinon j'ai effectivement 1 feuille avec 1 seul colonne utilisé comme montré en haut et j'aimerais créer une seconde feuille avec un trie sur les 3 colonnes.

[Marc-L]

Bonjour, bonjour,

cela n'a rien à voir avec un tri !

Ce serait plus facile à partir d'un classeur exemple en pièce jointe (.xls / .xlsx) …

Si les données proviennent d'une importation, mieux vaut travailler directement depuis le fichier d'import …

[joe.levrai]

Bonsoir

Est effectivement employé à tort le mot "tri", mais ça ne reste qu'une considération terminologique.

Chez moi, le code est conforme à la demande, il suffit maintenant de modifier selon tes besoins. Il prend tout ce qu'il y a dans la colonne A, et le restitue par ligne avec les trois champs spécifiés, sans se préoccuper des espaces.

Mais il est vrai que je suis également partisan du travail en Amont, plutôt qu'en Aval, ça évite de passer par deux procédures (import / "agencement") quand une seule suffit

La macro plante parce que les noms de feuilles que j'ai mis dans le code sont des exemples, il suffit d'indiquer les feuilles de ton choix.

[Gegedj]

Merci pour vos réponse, le code fonctionne parfaitement, effectivement fallait juste modifier ce qui était en rouge avec mes feuilles !

Mais en amont je ne peux rien faire, a la base c'est un fichier pdf de plus de 400 pages que j'ai convertie en xls qui contenait 400 feuilles.
J'avais réussi a tout regroupé mais en 1 seul feuilles d'une colonne.

Maintenant c'est bon j'ai mes 3 colonnes ^^