Discussion :

[ThomasParis]

Bonjour a tous,

Voila je ne suis vraiment pas excellent en script batch et j'aurai besoin de votre aide...
Dans un script batch, l'utilisateur passe en parametre (%1) un nom de dossier.
Je me position dans une arborescence (du type C:\Temp\Test\) et celle ci contient divers dossiers, sous-dossiers, sous-sous dossiers ,etc.

Ainsai j'aimerai faire une recherche de ce dossier, au sein de cette arborescence totale, sachant que le nom peut etre legerement different (miniscule/majuscule; une lettre en plus ou en moins) - je ne sais pas s'il existe en batch l'équivalent d'un 'LIKE' en sql - et que le script écrase la valeur de %1 par le path absolu oú se situe le dossier.
Dans ce cas, si %1 = MyFolder, je voudrais que %1 soit remplacé par qq chose du type:
C:\Temp\Test\Dossier1\Sous-dossier1\sous-sous-Dossier1\MyFolder

Est-ce possible?Simple?

Merci pour votre aide,

[sachadee]

Salut oriente toi sur qqe chose comme ça :

Place le bat dans le dossier racine d'où dois commencer la recherche (C:\Temp\Test\ dans ton exemple)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
@echo off&cls
set $path=Rien trouv‚

for /f "delims=" %%a in ('dir /ad/b/s ^| findstr /i "%1"') do set $path=%%a

echo %$path%

Le problème avec ce genre de recherche est que si tu as une lettre en moins
et qu'il y a plusieurs occurences de Myfolder tu va récuperer la dernière.

Exemple :

ton string de recherche est : Myfolder et il existe myfolder1 et myfolder2
le résultat en retour sera myfolder2.

Inversement si tu recherches Myfolder5 tu ne trouveras rien.

Donc à utiliser vraiment avec précaution.

Maintenant tu peux appliquer une batterie de filtres et test sur cette variable en sortie selon ton problème.

[ThomasParis]

Merci beaucoup.
J'ai lancé ce batch et il ré pond cela:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
find: unable to access "/i": The system cannot find the file specified.
find: unable to access "MyFolder": The system cannot find the file specified.

Juste pour confirmer 'MyFolder' existe et s'ecrit bien comme ça.
En ce qui concerne les limitations que tu m'as expliqué, je te remercie pour m'avertir, cependant (et heureusement) c'est un cas qui n'arrivera pas!

Merci bcp!

[ThomasParis]

Bon a vrai dire je pense avoir résolu ce pb en ajoutant un '.' apres le 'find':

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
@echo off &cls
set $recherche=%1

for /f "delims=" %%a in ('dir /ad/b/s ^| find . /i "%$recherche%" ') do (if %errorlevel%==0 echo $Path=%%~dpna)

echo %$Path

Cependant, il devrait me retourner un path unique.
Or il me retourne une liste enorme de path, a tel point que je suis obligé d'arreter le script.

Voici mon arborescence de test (réduite):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
-C
  -Temp
    -Test --> Positionne le .bat a cet endroit avec en parametre B2
      -Project1
        -A1
          -voiture
        -B2
          -avion
        -C3
          -bus
        -D4
          -train
      -Project2
      -Project3

Et il me retourne:
$Path=C:\Temp\Test
$Path=C:\Temp\Test\Project1\
$Path=C:\Temp\Test\Project1\A1
$Path=C:\Temp\Test\Project1\A1\voiture
$Path=C:\Temp\Test\Project1\B2
$Path=C:\Temp\Test\Project1\B2\avion
$Path=C:\Temp\Test\Project1\C3
$Path=C:\Temp\Test\Project1\C3\bus
$Path=C:\Temp\Test\Project1\D4
$Path=C:\Temp\Test\Project1\D4\train
$Path=C:\Temp\Test\Project2
$Path=C:\Temp\Test\Project3

Bref, tous les path possibles a apartir de la ou je suis...
Peut etre que finalement le . aprés le find n'est pas la bonne solution pour résoudre ce probleme...

Merci pour votre aide,

[ThomasParis]

Bonsoir a tous,

Bon je viens de modifier le script afin de ne plus avoir l'erreur du find et de ne plus avoir des centaines de resultats.
Voici ce que j'ai changé:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
@echo off &cls
set $recherche=%1

SET SYS32_HOME=%SystemRoot%\System32
SET FIND_CMD=%SYS32_HOME%\find.exe

for /f "delims=" %%a in ('dir /ad/b/s ^| "%FIND_CMD%" /i "%$recherche%" ') do (if %errorlevel%==0 set $Path=%%~dpna)

echo %$Path%

En reprenant mon exemple d'arborescence:

Il me retourne maintenant le path correct jusqu'a mon parametre %1.

C'est parfait!

Cependant, une derniere petite question, comment puis-je faire pour ajouter un critere en plus a ma recherche...?
En gros, reprenant un exemple d'arborescence:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
-C:
  -Temp
    -Test --> Positionne le .bat a cet endroit avec en parametre B2
      -Project1
        -A1
          -voiture
        -B2
          -avion
        -C3
          -bus
        -D4
          -train
      -Project2
        -B2
      -Project3

En gros je voudrais passer en parametre B2 et Project1, afin qu'il ne prenne pas en compte le edossier B2 au sein de Project2...
Est ce possible?

Merci pour votre aide,

[sachadee]

Salut,

En fait j'ai corrigé mon premier code il y avait effectivement des erreurs qui sont donc corrigé et j'ai encore simplifié le code.

Pour ton second problèmes en fait tu veux faire un :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8

@echo off&cls
set $path=Rien trouv‚

for /f "delims=" %%a in ('dir /ad/b/s ^| findstr /i "%1" ^| findstr /i "%2"') do set $path=%%a

echo %$path%

Si tu mets comme argument b2 project1 il va te ressortir seulement le b2 de project1.

Voilà

[ThomasParis]

Merci beaucoup!

Cependant, j'ai un doute, comment forcer á ne chercher que dans les nom de dossiers?


Car, dans mon arborescence:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
-C:
  -Temp
    -Test --> Positionne le .bat a cet endroit avec en parametre B2
      -Project1
        -A1
          -voiture
        -B2
          -avion
            -concorde
            -fichier.txt --> au sein de ce fichier il y a du texte qui contient la chaine de caractere 'B2'
        -C3
          -bus
        -D4
          -train
      -Project2
        -B2
      -Project3

Ainsi, il me retourne le path suivant:
C:\Temp\Test\Project1\B2\avion\concorde\
Au lieu de C:\Temp\Test\Project1\

Merci bcp!

[sachadee]

Avec le dernier code que je t'ai fait. Tu mets en paramètre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
c:\test > test.bat b2 project1

ou le premier avec seulement b2 en paramètre.

Il ne va pas chercher dans les fichiers mais uniquement dans le résultat du DIR.

[ThomasParis]

je met exactement ces 2 parametres.
Ce qui a pour resultat de bien aller prendre la dossier B2 au sein de Project1 et non de Project2, cependant il descend jusqu qu repertoire contenant ce fichier qui possede la chaine de caratere 'b2' au sein du texte...

voici exactement mon script:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
@echo off&cls
set $recherche=%1
set $param=%2

SET SYS32_HOME=%SystemRoot%\System32
SET FIND_CMD=%SYS32_HOME%\find.exe

for /f "delims=" %%a in ('dir /ad/b/s ^| "%FIND_CMD%" /i "%$recherche%" ^| "%FIND_CMD%" /i "%$param%"') do (if %errorlevel%==0 set $Path=%%a)

echo %$Path%

Merci pour votre aide,

[sachadee]

Test simplement ceçi sans rien changer et dis moi ce qu'il te retourne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8

@echo off&cls
set $path=Rien trouv‚

for /f "delims=" %%a in ('dir /ad/b/s ^| findstr /i "%1" ^| findstr /i "%2"') do set $path=%%a

echo %$path%

avec les 2 paramètres b2 et project1

[ThomasParis]

Bonjour,

Il me retourne exactement la meme chose qu'avec mon script legerement modifié, cad:
C:\Temp\Test\Project1\B2\avion\concorde\

Merci pour votre aide,

[sachadee]

En fait c'est logique. Il te retourne le dernier PATH trouvé contenant B2 et project1. C'est le problème dont je te parlais plus haut.

Donc il faut créer faire une réduction du PATH jusqu'au premier paramètre. (J'ai également traité le cas où on aurait un nom composé dans le PATH) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
@echo off&cls
setlocal EnableDelayedExpansion

set $path=Rien trouv‚

for /f "delims=" %%a in ('dir /ad/b/s ^| findstr /i "%1" ^| findstr /i "%2"') do set $path=%%a
:::Au cas ou l'on a des espaces dans le PATH
set $path=!$path: =#!
:::
set $TPath=!$Path:%1\=%1 !
for %%a in (%$Tpath%) do (set $path=%%a
                          set $path=!$path:#= !
                          echo !$path!
                          exit /b)

[minnesota]

salut tout le monde...
sachadee

Dans ce genre de cas, il est pertinent de rediriger la sortie de "dir" vers un fichier temporaire.
Ensuite, afficher les lignes qui correspondent à la requête de l'utilisateur.
Enfin, ce dernier sélectionne la ligne qui lui convient ou adresse une nouvelle requête.

[ThomasParis]

Merci bcp pour votre aide.

Cependant j'obtiens maintenant:
C:\Temp\Test\Project1\b2 --> b2 de la meme forme que je le passe en parametre via le script, alors que le nom du répertoire reel est B2
De plus, j'ai l'impression qu'il ne prend plus en compte le second parametre.
A vrai dire je voudrais qu'il aille jusqu'au dernier nom de dossier etant egal (a la case pres) á mon premier paraetre et pour lequel le path jusqu'a ce dernier contienne aussi le second parametre...
Est ce a peu pres clair?

Globalement, j ái une arborescence comme cela:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
-C:
  -Temp
    -Test --> Positionne le .bat a cet endroit avec en parametre b2 et project1
      -Project1
        -A1
          -voiture
        -B2
          -avion
            -concorde
              -B2
            -fichier.txt
        -C3
          -bus
        -D4
          -train
      -Project2
        -B2
      -Project3

en fait je voudrais:

C:\Temp\Test\Project1\B2\Avion\Concorde\B2

Merci encore,

[sachadee]

Quant on saura tout......

Une dernière solution :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
@echo off&cls
setlocal EnableDelayedExpansion

set $path=
set $pathfinal=

for /f "delims=" %%a in ('dir /ad/b/s ^| findstr /i "%1" ^| findstr /i "%2"') do set $path=%%a
:::Au cas ou l'on a des espaces dans le PATH
set $path=!$path: =#!
set $path=!$path:\= !
:::
:::ON iNVERSE LA LISTE
for %%a in (%$path%) do set $IPath=%%a !$IPath!
set $path=!$IPath!

set $sw=[OFF]
for %%a in (!$path!) do (
                         if "%%a"=="%1" set $sw=[ON]
                         if !$sw!==[ON] set $pathfinal=%%a\!$pathfinal!)

if not defined $pathfinal (echo rien touv‚) else (set $pathfinal=!$pathfinal:#= !
                                                  echo !$pathfinal!)

[ThomasParis]

En effet, excusez moi.

C'est parfait!!
Je me permet juste d'ajouter '/i' apres les if, afin de ne pas prendre en compte la case:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
@echo off&cls
setlocal EnableDelayedExpansion

set $path=
set $pathfinal=

for /f "delims=" %%a in ('dir /ad/b/s ^| findstr /i "%1" ^| findstr /i "%2"') do set $path=%%a
:::Au cas ou l'on a des espaces dans le PATH
set $path=!$path: =#!
set $path=!$path:\= !
:::
:::ON iNVERSE LA LISTE
for %%a in (%$path%) do set $IPath=%%a !$IPath!
set $path=!$IPath!

set $sw=[OFF]
for %%a in (!$path!) do (
                         if /i "%%a"=="%1" set $sw=[ON]
                         if /i !$sw!==[ON] set $pathfinal=%%a\!$pathfinal!)

if not defined $pathfinal (echo rien touve) else (set $pathfinal=!$pathfinal:#= !
                                                  echo !$pathfinal!)