Discussion :

[rolco]

Bonjour,

Ce code de la FAQ Excel importe des données csv dans une nouvelle table Access.

Pouvez vous me dire ce qu'il faut modifier pour que les données soient importées toujours dans la même table ?

Merci d'avance,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
 
Sub tranfertCSV_Vers_NouvelleTableAccess()
    'Transfére un fichier CSV vers une nouvelle table Access
    'depuis une macro Excel.
    '
    'Nécessite d'activer la référence
    '"Microsoft ActiveX Data Objects x.x Library
    '
 
    Dim AccessCn As ADODB.Connection
    Dim AccessRst As ADODB.Recordset
    Dim Csv_CN As New ADODB.Connection
    Dim Csv_Rst As New ADODB.Recordset
    Dim DossierCSV As String, NomTable As String
    Dim FichCSV As String, MaBase As String
    Dim nbEnr As Long
 
    'Répertoire du fichier CSV
    DossierCSV = "C:\Documents and Settings\mimi\dossier"
    'Nom du fichier CSV à transfèrer
    FichCSV = "LeFichierCSV.csv"
    'Chemin et nom de la base Access
    MaBase = "C:\Documents and Settings\mimi\dossier\dataBase.mdb"
    'Nom de la nouvelle Table Access
    NomTable = "MaNouvelleTable"
 
 
    'Connection au fichier CSV
    Csv_CN.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & _
        DossierCSV & ";Extended Properties='text;FMT=Delimited'"
    'Requète dans le fichier CSV
    Csv_Rst.Open "SELECT * FROM " & FichCSV, Csv_CN, _
        adOpenStatic, adLockOptimistic
 
    'Connection à la base de données Access
    Set AccessCn = New ADODB.Connection
    AccessCn.Open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
                   "Data Source=" & MaBase
 
 
    Csv_CN.Execute "SELECT * INTO [" & NomTable & "] IN '" & _
        MaBase & "' From [" & FichCSV & "]", nbEnr
 
 
    AccessCn.Close
    Csv_Rst.Close
    Csv_CN.Close
    Set AccessRst = Nothing
    Set AccessCn = Nothing
    Set Csv_Rst = Nothing
    Set Csv_CN = Nothing
End Sub

[PipoWIL]

bonjour,

Si ce code te convient pourquoi ne pas le garder ?
Tu peux :

1. exécuter cette Sub tranfertCSV_Vers_NouvelleTableAccess()
2. ajouter une APPEND Query qui va ajouter touttes les données de "MaNouvelleTable" à "MaTable existante"
3. detruire "MaNouvelleTable" dont tu n'as plus besoin

[rolco]

Merci de ton aide, je pensais qu'il était possible d'ajouter directement les données du csv à une table existante.

Peux tu m'aider pour l'APPEND ? je débute.

Pour le DELETE de la table temporaire j'espère y arriver !

Merci encore.

[LedZeppII]

Bonjour,

Voici un exemple basé sur le code que tu as posté.
Les données du fichier CSV sont ajoutées à la table Access désignée.
Il faut impérativement que la table Access comporte tous les champs qui seront trouvés dans le fichier CSV.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Sub tranfertCSV_Vers_TableAccessExistante()
    'Transfére un fichier CSV vers une table Access existante
    '
    'Nécessite d'activer la référence
    '"Microsoft ActiveX Data Objects x.x Library
 
    Dim Csv_CN As New ADODB.Connection
    Dim DossierCSV As String, NomTable As String
    Dim FichCSV As String, MaBase As String
    Dim nbEnr As Long
 
    'Répertoire du fichier CSV
    DossierCSV = "C:\Documents and Settings\mimi\dossier"
    'Nom du fichier CSV à transfèrer
    FichCSV = "LeFichierCSV.csv"
    'Chemin et nom de la base Access
    MaBase = "C:\Documents and Settings\mimi\dossier\dataBase.mdb"
    'Nom de la nouvelle Table Access
    NomTable = "MaNouvelleTable"
 
    'Connexion au fichier CSV
    Csv_CN.Open "Provider=Microsoft.Jet.OLEDB.4.0" & _
                ";Data Source=" & DossierCSV & _
                ";Extended Properties='text;FMT=Delimited'"
 
    ' Requête Ajout
    Csv_CN.Execute "INSERT INTO [" & NomTable & "] IN '" & MaBase & "' " & _
                   "SELECT TCSV.* " & _
                   "FROM [" & FichCSV & "] As TCSV", nbEnr
 
    Csv_CN.Close
    Set Csv_CN = Nothing
End Sub

A+

[rolco]

Merci LedZeppII, c'est exactement ce que je voulais obtenir.

Il me reste juste à gérer un étrange problème de TextQualifier dans mes csv.

Merci encore.