Discussion :

[r4v3n]

Bonjour, après avoir fait plusieurs recherche, je n'ai pas trouvé, enfin, ce que j'ai trouvé ne fonctionne pas à 100%, et je ne vois pas ou ça coince.

Voici mon code actuel (Trouvé sur internet et modifié pour moi):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Sub copie_dans_fichier_text()
'
Dim Chemin As String
Dim DerniereLigne As Long        'Index de la dernière ligne
Dim Tableau() As Variant
Dim Ligne As Long
 
Chemin = "D:\"
DerniereLigne = Range("D1").SpecialCells(xlCellTypeLastCell).Row
 
'Création du tableau par une boucle
Ligne = 1
Do While Ligne <= DerniereLigne
 'Ajout 1 élément à l'array en conservant les éléments précédents
    ReDim Preserve Tableau(Ligne)
'Affectation de la valeur au nouvel élément
    Tableau(Ligne) = Range("D" & Ligne).Value
    Ligne = Ligne + 1
Loop
 
'Ecrit dans le fichier txt
Ligne = 0
Do While Ligne <= DerniereLigne
    Open Chemin & "fichier_sauvegarde.txt" For Output As #1
    'Print #Ligne, Tableau(Ligne) & vbCrLf
    Print #1, Tableau(Ligne) '& vbCrLf
    Close
    Ligne = Ligne + 1
Loop
 
MsgBox ("A ton tour de travailler !")
 
End Sub

Pour ce qui est du fonctionnement, je dois juste copier la colonne D dans le fichier texte. J'ai pourtant l'impression que ma variable "Tableau(Ligne)" correspond bien à ma colonne D vu que j'ai mis:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Tableau(Ligne) = Range("D" & Ligne).Value

Donc actuellement, je fichier ce créer correctement, mais seule la dernière ligne ce mets dedans, et je ne vois pas ou je dois modifier pour qu'il fasse correctement le travail.

Cordialement

[pijaku]

Bonjour,

Normal.
Tu ouvres ton fichier texte et le ferme dans chaque itération de boucle.
Il convient de l'ouvrir, boucler sur toutes les valeurs et le fermer.

Regarde ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub copie_dans_fichier_text()
'
Dim Chemin As String
Dim DerniereLigne As Long        'Index de la dernière ligne
Dim Tableau() As Variant
Dim Ligne As Long
 
Chemin = "D:\"
DerniereLigne = Range("D1").SpecialCells(xlCellTypeLastCell).Row
 
Tableau = Range("D1:D" & DerniereLigne)
 
'Ecrit dans le fichier txt
Ligne = 1
Open Chemin & "fichier_sauvegarde.txt" For Output As #1
   Do While Ligne <= DerniereLigne
       Print #1, Tableau(Ligne, 1) '& vbCrLf
       Ligne = Ligne + 1
   Loop
Close
 
MsgBox ("A ton tour de travailler !")
 
End Sub

[r4v3n]

Ceci va régler déjà une partie du problème, quand on est dans le fichier on cherche tout sauf ce qu'il faut ^^

Par contre, maintenant, alors que je ne l'avais pas avant, j'ai une erreur sur cette ligne:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Open Chemin & "fichier_sauvegarde.txt" For Output As #1

Est ce normal?

PS: C'est bon en faite, erreur de ma part sur le "close". Merci à toi Pijaku !