Discussion :

[Annibal3]

Bonjour,

je ne sais si ce sujet a déjà été abordé mais je n'ai rien trouvé dans les forums.

J'ai écris un sript simple suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub ComboBox1_Change()
Sheets("Immatricule").Select
Columns("c").Select
Selection.AutoFilter Field:=1, Criteria1:=ComboBox1.Value
Range("A2:O40").Select
    Selection.Copy    
    Sheets("Feuil13").Select
    Range("AA1").Select
    ActiveSheet.Paste
    Sheets("Immatricule").Select
    Rows("1:1").Select
    Application.CutCopyMode = False
    Selection.AutoFilter

si je l'insère dans un 'combobox' le message suivant apparait : "erreur d'execution 1004 : La methode autofilter de la classe range a échoué"

En revanche cela fonctionne sans problème avec un 'commandbutton'.

Quelle différence y a til entre une liste deroulante et un bouton de commande ?

[Invité]

Désolé mais ton code est horrible.

Est-ce que ça ne fonctionne pas mieux comme ça:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub ComboBox1_Change()
 
  With Worksheets("Immatricule")
 
    If .FilterMode = True Then .AutoFilterMode = False
    .UsedRange.AutoFilter Field:=1, Criteria1:=ComboBox1.Value
    .Range("A2:O40").Copy Worksheets("Feuil13").Range("AA1")
    Application.CutCopyMode = False
    .AutoFilterMode = False
 
  End With
 
End Sub

La colonne qui sert de tri dans ce cas est la colonne A.
La zone à filtrer est la zone utilisée dans la feuille Excel. Il faut peut être préciser cette zone dans ton cas.

[Annibal3]

merci de prendre le temps de me répondre,

avec ce code ( g remplacé 1 par 3 car le filtre s'effectue en colonne c) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub ComboBox1_Change() 
  With Worksheets("Immatricule") 
    If FilterMode = True Then .AutoFilterMode = False
    UsedRange.AutoFilter Field:=3, Criteria1:=ComboBox1.Value
    Range("A2:O40").Copy
    Worksheets("Feuil13").Range ("AA1")
    Application.CutCopyMode = False
    AutoFilterMode = False 
  End With 
End Sub

j'ai un autre message d'erreur "objet requis"

neanmoins même si g conscience que mon code est degueulasse il fonctionnait avec un bouton de commande mais pas avec une liste déroulante

[Invité]

Pourquoi tu as enlevé les '.' ?

Le code pour filtrer en fonction de la colonne 3 est:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub ComboBox1_Change()
 
  With Worksheets("Immatricule")
    If .FilterMode = True Then .AutoFilterMode = False
    .UsedRange.AutoFilter Field:=3, Criteria1:=ComboBox1.Value
    .Range("A2:O40").Copy Worksheets("Feuil13").Range("AA1")
    Application.CutCopyMode = False
    .AutoFilterMode = False
  End With
 
End Sub

[Annibal3]

l'objet requis était les points a priori, le message d'erreur reste toujours le même "erreur 1004 : la methode autofilter de la classe range a échoué"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub ComboBox1_Change()
 
  With Worksheets("Immatricule")
 
    If FilterMode = True Then .AutoFilterMode = False
    .UsedRange.AutoFilter Field:=3, Criteria1:=ComboBox1.Value
    .Range("A2:O40").Copy Worksheets("Feuil13").Range("AA1")
    ActiveSheet.Paste
    Application.CutCopyMode = False
    .AutoFilterMode = False
 
  End With
 
End Sub

[Invité]

Mets ton fichier en PJ sans données confidentielles

[Invité]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub ComboBox1_Change()
  With Worksheets("Immatricule")
    .AutoFilterMode = False
    .Cells(1, 1).AutoFilter
    'If .FilterMode = True Then .FilterMode = False
    .UsedRange.AutoFilter Field:=3, Criteria1:=ComboBox1.Value
    .Range("A2:O40").Copy Worksheets("Feuil13").Range("AA1")
    .Application.CutCopyMode = False
    .AutoFilterMode = False
  End With
End Sub

[Annibal3]

Bonjour, j'obtiens toujours le meme message d'erreur, voici mon fichier son extension est xlsm :

[Invité]

Bonjour, j'obtiens toujours le meme message d'erreur, voici mon fichier son extension est xlsm :

Premièrement tu as dupliqué les appels à la méthode 'ComboBox1_Change()' (module standard et module de feuille).
Ensuite la source de ton 'ComboBox1' dépend de la feuille qui est triée. Ça ne peut pas fonctionner.

[Invité]

Bonjour,
la source de ton contrôle est la colonne A:A, donc quand tu filtre ton tableau tu modifie la ComboBox1 donc tu déclenche ComboBox1_Change() d'ou l'erreur.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub ComboBox1_Change()
Static N As Boolean
If N = False Then
N = True
  With Worksheets("Immatricule")
    .AutoFilterMode = False
     .Cells(1, 1).AutoFilter
    'If .FilterMode = True Then .FilterMode = False
    .UsedRange.AutoFilter Field:=3, Criteria1:=ComboBox1.Value
    .Range("A2:O40").Copy Worksheets("Feuil13").Range("AA1")
    .Application.CutCopyMode = False
    .AutoFilterMode = False
  End With
  N = False
End If
End Sub

[Annibal3]

merci beaucoup c'est impécable.

J'espère ne pas vous avoir fait perdre trop de temps.

Bonne journée