Discussion :

[le sportif]

Bonjour à tous
j'ai un document qui comporte des données qui sont espacés càd ce qui les a saisi il a rempli une ligne et sauté la suivante.
Y a t-il une astuce qui me permet de supprimer les lignes sautées en une seule fois au lieu de les effacer une à une
Merci d'avance pour toute réponse

[casefayere]

Bonjour,
avec Vba, ce code exécuté dans un module :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub suplignes()
Dim Dl As Long, Dc As Long, x As Long, y As Long, verif As String
verif = ""
With Sheets("Feuil1") '"Feuil1" à remplacer par le nom de ta feuille
  Dl = .Range("A" & .Rows.Count).End(xlUp).Row 'dernière ligne utilisée en A
  Dc = .Cells(1, .Columns.Count).End(xlToLeft).Column 'dernière colonne utilisée sur la ligne 1
  For x = Dl To 1 Step -1 'tu remontes de la dernière ligne à la première pour vérifier si vide
    For y = 1 To Dc
      verif = verif & .Cells(x, y)
    Next y
    If verif = "" Then
      .Rows(x).Delete
    End If
    verif = ""
  Next x
End With
End Sub

[Philippe Tulliez]

Bonjour,
Une autre solution avec la méthode SpecialCells (similaire à l'action manuelle de l'outil Atteindre option Cellules vides).
Exemple pour une liste de données débutant en A1 et dont on supprime les lignes dont les cellules de la première colonne sont vides.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub DeleteRowsEmpty()
  Dim sht As Worksheet, rng As Range
  Set sht = ThisWorkbook.Worksheets("Feuil1")
  With sht
   Set rng = .Range(.Range("A1"), .Range("A" & .Rows.Count).End(xlUp))
  End With
  rng.SpecialCells(xlCellTypeBlanks).EntireRow.Delete
End Sub

[Daniel.C]

Bonjour,

Tu n'en as sans doute plus besoin, mais bon... En admettant que les lignes remplies aient quelque chose en colonne A, mais cette formule en ligne 1 d'une colonne inutilisée :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(A1<>"";LIGNE();"")

et recopie vers le bas.
et trie les données, cette colonne incluse.
Efface la colonne. C'est tout.