Discussion :

[fusee2013]

Bonjour à tous !

J'ai crée près d'une cinquantaine de ToggleButton dans ma feuille Excel, chaque bouton pour une ligne.

Voici le code pour chaque togglebutton :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
Private Sub ToggleButton1_Click()
 
If ToggleButton1 = True Then
    ToggleButton1.Caption = "Enregistré"
    ToggleButton1.Enabled = False
End If
 
End sub

J'aimerai pouvoir créer qu'une seule procedure et pouvoir faire quelque chose comme :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
Call ToggleButton & i & _Click
 
if toggleButton & i = True then
...
End if

Est-ce possible ?

[mercatog]

C'est la cas pour utiliser les module de classe

Insère un module de classe (par défaut nommé Classe1)
Y insère le code suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Public WithEvents TB As MSForms.ToggleButton
 
Private Sub TB_Click()
 
With TB
    If .Value Then
        .Caption = "Enregistré"
        .Enabled = False
    End If
End With
End Sub

Et enfin dans le module de ton userform

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Dim Tbl() As New Classe1
 
Private Sub UserForm_Initialize()
Dim Ct As Control
Dim i As Integer
 
For Each Ct In Me.Controls
    If TypeOf Ct Is MSForms.ToggleButton Then
        i = i + 1
        ReDim Preserve Tbl(1 To i)
        Set Tbl(i).TB = Ct
    End If
Next Ct
End Sub

[fusee2013]

Super merci je ne connaisssais pas .

Par contre mes boutons sont des boutons activeX dans la feuille de calcul (et donc pas d'userform...)

J'ai essayé de remplacer userform_initialize par worksheet_activate mais ca ne marche pas...

[mercatog]

Remplace le code par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Dim Tbl() As New Classe1
 
Private Sub Worksheet_Activate()
Dim Ct As OLEObject
Dim i As Integer
 
For Each Ct In ActiveSheet.OLEObjects
    If TypeOf Ct.Object Is MSForms.ToggleButton Then
        i = i + 1
        ReDim Preserve Tbl(1 To i)
        Set Tbl(i).TB = Ct.Object
    End If
Next Ct
End Sub

Le code de la classe Classe1 reste intact

[fusee2013]

J'ai copié collé exactement le code, mais lorsque je clique sur un togglebutton, il ne se passe pas ce qui est prévu, j'ai ajouté un msgbox, mais rien non plus...

[Invité]

C'est la cas pour utiliser les module de classe

Insère un module de classe (par défaut nommé Classe1)
Y insère le code suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Public WithEvents TB As MSForms.ToggleButton
 
Private Sub TB_Click()
 
With TB
    If .Value Then
        .Caption = "Enregistré"
        .Enabled = False
    End If
End With
End Sub

Et enfin dans le module de ton userform

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
Public WithEvents TB As MSForms.ToggleButton
  Public I As Long
Private Sub TB_Click()
UserForm1.ToggleButton_Click I, TB
 
End Sub

UserForm:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Dim Tbl() As New Classe1
Private Sub UserForm_Initialize()
Dim Ct As Control
Dim I As Integer
 
For Each Ct In Me.Controls
    If TypeOf Ct Is MSForms.ToggleButton Then
        I = I + 1
        ReDim Preserve Tbl(1 To I)
        Set Tbl(I).TB = Ct
        Tbl(I).I = I
    End If
Next Ct
End Sub
Public Sub ToggleButton_Click(Index As Long, ByVal TB As MSForms.ToggleButton)
Select Case Index
        Case 1
            MsgBox "Click sur le bouton : " & Index
        Case 2
            MsgBox "Même chose pour  sur le bouton : " & Index
        Case 3
            MsgBox "Et enfin le bouton : " & Index
End Select
End Sub

[fusee2013]

Merci de nouveau, mais comme dit dans mon precedent post, ce n'est pas un userform (je me suis trompee dans le titre), mais des controles ActiveX dans la feuille de calcul...

[mercatog]

Pour initialiser la classe, tu dois activer ta feuille X. Pour cela, active une autre feuille et réactive ta feuille X.

[fusee2013]

WONDERFUL ! Merci 1000 fois

Autre question :

Comment recuperer le numero du togglebutton qui est cliqué ?
Car je souhaite appeler une procedure qui prendrai en parametre ce numéro...