Discussion :

[hehee]

Bonjour,
J'ai un Tableau croisé dynamique que j'aimerais filtrer pour n'avoir que élément numérique (0 à 9), car j'ai aussi des lettres de A à Z.
Serait-il possible de faire un code qui permet de tester l'élément, et s'il n'est pas numérique, alors le rendre invisible ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
Dim pi As PivotItem
 
'Active tous les éléments  
With ActiveSheet.PivotTables("Tableau croisé dynamique1").PivotFields("Gauche component")
    .EnableMultiplePageItems = True
    .CurrentPage = "(All)" 'ou TOUS
End With
 
'PAr la suite, il faudrait que je cache les "non-numériques"
'J'ai donc testé avec ça, mais ca bug à la première ligne :( 
 
For Each pi In ActiveSheet.PivotTables("Tableau croisé dynamique1").PivotFields( _
        "Gauche component")
    If Not IsNumeric(pi) Then
 
        pi.Visible = False
 
    End If
Next pi

Merci de votre aide !

[Philippe Tulliez]

Bonjour,
La boucle ci-dessous n'est pas correcte (ce n'est pas une collection)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each pi In ActiveSheet.PivotTables("Tableau croisé dynamique1").PivotFields("Gauche component")

Il fallait ajouter .PivotItems

Le code ci-dessous fonctionne. Il faut juste changer la valeur de la constante FldName par le nom de ton champ.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub PivotField_VisibleNumeric()
 Dim pvtItem As PivotItem
 Const FldName As String = "Division" ' Nom du champ du filtre de rapport à sélectionner
 
 Dim pvtTable As PivotTable, pvtField As PivotField
 Set pvtTable = ActiveSheet.PivotTables("Tableau croisé dynamique1")
 Set pvtField = pvtTable.PivotFields(FldName)
 For Each pvtItem In pvtField.PivotItems: pvtItem.Visible = True: Next ' Tous les filtres visibles pour éviter une erreur
 For Each pvtItem In pvtField.PivotItems
  pvtItem.Visible = IsNumeric(pvtItem) ' Active les numériques
  'pvtItem.Visible = Not (IsNumeric(pvtItem)) ' Active les non numérique
 Next
End Sub

La propriété CurrentPage = "(All)" ne fonctionne pas. Ni avec la valeur "All" ni avec "Tous". Je ne sais pas pourquoi mais il me semble avoir déjà rencontré ce problème

[hehee]

En plein une réponse qu'il me fallait ! Un gros merci!