Discussion :

[Hobbi1]

Bonjour,

J'ai un curseur explicite dont la requête exécutée directement me retourne 2 enregistrements. Mais le curseur ne me retourne rien.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
OPEN cur_niv2;
LOOP
    FETCH cur_niv2 BULK COLLECT INTO vDonneeNiv2;
    IF cur_niv2%NOTFOUND THEN
         => log( 'NOTFOUND ' || cur_niv2%ROWCOUNT);
    ELSE
         => log( 'FOUND ' || cur_niv2%ROWCOUNT);
    END IF;
 
    EXIT WHEN cur_niv2%NOTFOUND;
 
    FOR cpt_niv2 IN vDonneeNiv2.FIRST..vDonneeNiv2.LAST
    LOOP
        => log(vDonneeNiv2(cpt_niv2).ReferenceBoutEnBout);
    END LOOP;
END LOOP;
CLOSE cur_niv2;

Et la log (que j'ai tronquée dans le code ici) donne :

NOTFOUND 2

Je précise que vDonneeNiv2 est de type TABLE OF d'un RECORD.
Et la définition du record correspond bien au curseur.

Je trouve ça bizarre et je n'ai pas d'explications.
Pouvez-vous m'aider SVP

[pachot]

Bonjour,

%NOTFOUND n'a pas vraiment de sens avec BULK COLLECT. Car on reçoit %NOTFOUND lorsque le dernier bulk n'est pas complet.

Une possibilité, le remplacer par:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

EXIT WHEN vDonneeNiv2.COUNT=0

Cordialement,
Franck.

[Hobbi1]

Ah OK.
Merci pour l'information.

Mais par contre, du coup j'aurais plutôt mis :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

EXIT WHEN cur_niv2%ROWCOUNT=0;

[pachot]

Ah OK.
Merci pour l'information.

Mais par contre, du coup j'aurais plutôt mis :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

EXIT WHEN cur_niv2%ROWCOUNT=0;

Peut-être. Mais c'est pas forcément une bonne idée de ne pas suivre les conseils de Steven Feuerstein lorsqu'il s'agit de PL/SQL:
http://www.oracle.com/technetwork/is...ql-095155.html

When you are using BULK COLLECT and collections to fetch data from your cursor, you should never rely on the cursor attributes to decide whether to terminate your loop and data processing.

[mnitu]

Quand vous travaillez avec des collections il ya deux cas possible:

1. vous sélectionnez un ensemble des données pour lequel la limite supérieure est inconnue (exemple tous les employés d’une société)
2. vous sélectionnez un ensemble des données pour lequel une limite supérieure est définie fonctionnellement (exemple une commande ne peut pas avoir plus de mille lignes)

Le premier cas vous impose de travailler par lot. Le modèle (pattern) de programmation dans ce cas est le suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
Declare
  Taille_Lot  Constant Pls_Integer := 100;      -- ou autre valeur habituellement <= 1000
  Type rec_va Is Varray(100) Of Table%RowType;  -- même taille du tableau que la taille du lot
  collection  rec_va;
  --
  cursor crs Is
    Select *
      from table;
Begin  
  Open crs;
  Loop
    Fetch crs Bulk Collect Into collection Limit Taille_Lot;
    --
    Traitement_Donnees(collection);
    --
    Exit When collection.Count() < Taille_Lot;
  End Loop;
  Close crs;
End;

Le pattern de programmation du deuxième cas est le suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
Declare
  Tableau_Trop_Petit exception;
  pragma Exception_Init(Tableau_Trop_Petit, -22165);
  Type rec_va Is Varray(1000) Of Table%RowType;  
  collection  rec_va;
Begin  
  Select *
    Bulk Collect Into collection
    From Table;
  --
  Traitement_Donnees(Collection);  
  --
Exception
  When Tableau_Trop_Petit Then
    Raise_Application_Error(-20000, 'Régle de gestion #123 violée.');
End;

Comme vous pouvez le constater il n’y a plus de place pour crs%NOTFOUND

[Hobbi1]

OK.
Après avoir tout lu, je me range du côté de Steven Feuerstein

Merci à tous