Discussion :

[paupau83]

Bonjour,
Voici mon problème : je travaille sur une liste immense et pour simplifier on va dire que j'ai une première colonne remplie de numéros et une deuxième où j'ai des noms associés mais parfois j'ai des cellules vides. Exemple:
1010
1010
1010 PH
1010 PH
1015
1020
1020 PH
1027 AD
...
Chaque nom peut correspondre à plusieurs numéros.
Chaque numéro a un seul nom associé.
Mon problème c'est que je veux compléter les cases vides par le nom correspondant au numéro afin de pouvoir faire un tri par nom par exemple et avoir les références complètes de mes lignes.
A savoir qu'avec toutes les autres colonnes dans mon fichier de base (omises pour l'exemple) j'ai une ligne unique donc je ne peux pas supprimer de lignes.

Voilà j'espère que vous pourrez m'aider. J'ai essayé en utilisant des boucles de recherche et comparaison avec compteur mais ça ne donne rien. Je l'ai certainement mal fait aussi, je suis novice. Et il y a peut-être une astuce simple que je ne vois pas.
Merci

[Theze]

Bonjour,

A tester sur une copie du classeur. Il est important qu'au moins une fois dans la plage chaque numéro est un nom qui lui soit attribué sinon, ce numéro restera sans nom lié :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
 
Sub Associer()
 
    Dim Plage As Range
    Dim Cel As Range
    Dim Dico As Object
 
    'plage en colonne "A" de feuille "Feuil1"
    With Worksheets("Feuil1")
 
        Set Plage = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
    'crée l'objet
    Set Dico = CreateObject("Scripting.Dictionary")
 
    'parcours la plage et récupère la valeur de la cellule si ce n'est déjà fait
    'à condition que la cellule voisine (colonne B) ne soit pas vide
    'note, il est évident que chaque numéro de la colonne "A" doit avoir un nom associé
    'au moins une fois dans la plage
    For Each Cel In Plage
 
        If Dico.exists(Cel.Value) = False And Cel.Offset(, 1).Value <> "" Then
 
            Dico.Add Cel.Value, Cel.Offset(, 1).Value
 
        End If
 
    Next Cel
 
    'reboucle sur la plage pour affecter le nom au numéro
    For Each Cel In Plage
 
        Cel.Offset(, 1).Value = Dico(Cel.Value)
 
    Next Cel
 
End Sub

Hervé.

[paupau83]

Ca marche nickel !!! Merci beaucoup