Discussion :

[beabourbon]

Bonjour,
Je travaille actuellement sur un projet pour une association qui permettrait de gérer les participants aux réunions et d'en retirer des statistiques.
J'ai pour l'instant un tableau rempli grâce à des userforms, le bouton "ajouter session" permet de rajouter une colonne avec la date de la réunion. En face de chaque participant, dans la colonne correspondante à la session, j'ai écris des "X" pour noter la présence.

J'aimerais qu'au lieu de s'écrire manuellement, ces "X" soit dépendants de checkbox créées en même temps que la colonne de la session.
Donc quand je cliquerai sur créer, une liste de checkbox s'afficherait avec en face le nom et prénom dans chaque ligne remplie du tableau.

J'ai pour l'instant ce code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Private Sub btn_creer_Click()
    Dim i As Integer
            i = 11
                Do While (Sheets("Participants").Cells(6, i).Value <> "")
            i = i + 1
                Loop
 
    Sheets("Participants").Cells(6, i).Value=UserFormChantier.txt_session.Value
 
    Dim DLV As Long
            DLV = Range("B65536").End(xlUp).Row
    Dim k As Integer
    Dim nCheckTopPosition As Integer
    Dim nLabelTopPosition As Integer
 
    nCheckTopPosition = 15
    nLabelTopPosition = 18
 
    For nControlIndex = 1 To DLV
 
            Dim chkBox As Control
 
            Set chkBox = Me.Controls.Add("Forms.CheckBox.1", "chkCheck" & DLV, True)
            chkBox.Left = 100
            chkBox.Top = nCheckTopPosition
 
            nCheckTopPosition = nCheckTopPosition + 20
 
            Dim lblLab As Control
            Set lblLab = Me.Controls.Add("Forms.Label.1", "lblCheck" & DLV, True)
            lblLab.Left = 115
            lblLab.Top = nLabelTopPosition
            nLabelTopPosition = nLabelTopPosition + 20
            For k = 7 To DLV
            lblLab.Caption = Sheets("Participants").Cells(k, 4).Value & Sheets("Participants").Cells(k, 5).Value
' colonne4=nom, colonne5= prenom
            Exit For
            Next k
    Next
End Sub

Ce code ne m'affiche qu'un nombre limité de checkbox avec toutes comme label le premier nom de la liste.

Quelqu'un a t-il une idée?
Merci beaucoup!!

[PMO2017]

Bonjour,

Une piste avec le code suivant qui crée des Excel.CheckBox de manière dynamique. Ce sont donc des contrôles de formulaire et, non pas, des contrôles ActiveX (OLEObjects).
J'ai lié chaque cellule à son Excel.CheckBox pour pouvoir garder l'état de la CheckBox et travailler l'information (même après sa suppression).
Il y a 2 procédures : une qui crée et l'autre qui supprime.
****
Si cela vous convient, à vous d'intégrer ce code dans votre projet.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
Sub AddExcelCheckBox()
Dim S As Worksheet
Dim R As Range
Dim CBX As Excel.CheckBox
Dim LastLig As Long
Dim i As Long
Dim j As Long
'---
Set S = Sheets("Participants")    'à adapter
'--- Recherche de la dernière ligne ---
LastLig = S.[d65536].End(xlUp).Row
 
 
For j = 2 To S.[iv6].End(xlToLeft).Column           'colonnes (de colonne 2 à la dernière)
  If IsNumeric(Right(S.Cells(6, j), 4)) Then        'si les 4 derniers caractères forment un nombre (2013, 2014, etc)
    For i = 7 To LastLig                            'de la ligne 7 à la dernière ligne
      Set R = S.Range(S.Cells(i, j), S.Cells(i, j)) 'c'est la cellule cible dont la valeur sera aligné sur la droite
      R.HorizontalAlignment = xlRight
                                                    'on y crée une CheckBox Excel (Contrôle de formulaire)
      Set CBX = ActiveSheet.CheckBoxes.Add( _
          Left:=R.Left, Top:=R.Top, Width:=R.Width, Height:=R.Height)
 
      With CBX                        'avec la CheckBox
        .Caption = ""                 'on vide son texte
        '---
        .LinkedCell = R.Address       'on lui affecte la cellule cible en tant que cellule liée
        '---
        .Value = True                 'pour que la cellule liée affiche l'état de la CheckBox
        .Value = False                'on est forcé d'affecter à cette dernière True puis False
      End With
     Next i
  End If
Next j
End Sub
 
Sub DeleteExcelCheckBox()
Dim S As Worksheet
Dim CBX As Excel.CheckBox
'---
Set S = Sheets("Participants")    'à adapter
For Each CBX In S.CheckBoxes
  CBX.Delete
Next CBX
End Sub

[beabourbon]

Merci PMO2017 et désolée pour ma réponse tardive,
Je vais tester ce code pour voir s'il convient à mon projet et vous tiendrai au courant!