Discussion :

[ecailley]

Bonjour à tous,

J'ai créé une macro qui permet d'ajouter des onglets à chaque fois qu'il y a un nouveau poste. Ces onglets se mettent à jours automatiquement avec la grille de valeur principale. Je souhaite ajouter sur ces feuilles qui sont crées un diagramme secteur qui se base sur certaines cellules de la feuille crée. Le problème c'est que j'ai un message d'erreur par rapport à la ligne où la macro recupere les valeurs (en rouge). Si quelqu'un peut m'aider, ce serai gentil.

Le Code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub Inserer_poste()

Dim N As String 'Nom
Dim Tempo As String 'Nom temporaire pour la page créé
N = Sheets("Interface").Range("c3") 'Page où je rentre le nom du poste et je l'ajoute via le bouton macro
Tempo = "Temporary" 
Sheets("Grille").Select
Sheets.Add After:=Sheets(Sheets.Count) 'Insertion d'une feuille
    ActiveSheet.Name = Tempo
    ActiveSheet.Range("c2") = N
    ' Ajout Graph
    ActiveSheet.Shapes.AddChart.Select
    ActiveChart.ChartType = xlPie
    ActiveChart.ChartArea.Select
    ActiveChart.SeriesCollection.NewSeries
    ActiveChart.SeriesCollection(1).Name = Range("A4")
    ActiveChart.SeriesCollection(1).Values = _
        "=Temporary!$G$11;Temporary!$G$15;Temporary!$G$19;Temporary!$G$22"    ActiveChart.SeriesCollection(1).XValues = "={""M"".""E"".""F"".""A""}"
    ActiveChart.SeriesCollection(1).Select
    ActiveChart.SeriesCollection(1).Points(1).Select
    With Selection.Format.Fill
        .Visible = msoTrue
        .ForeColor.RGB = RGB(255, 255, 0)
        .Solid
    End With
    
    ActiveSheet.Name = N
    
End Sub

[mercatog]

Quelque chose comme ceci à adapter car tu créé une feuille vide et tu y insère le graphique se rapportant à des cellules vides de la nouvelle feuille
En plus, tu ne gère pas si la feuille existe déjà

Une première approche

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub Inserer_poste()
Dim Ws As Worksheet
Dim Ch As Chart
 
Set Ws = Worksheets.Add(After:=Sheets(Sheets.Count))    'Insertion d'une feuille
Ws.Range("C2").Value = Worksheets("Interface").Range("C3").Value
' Ajout Graph
Set Ch = Ws.ChartObjects.Add(100, 100, 400, 260).Chart
 
With Ch
    .ChartType = xlPie
    With .SeriesCollection.NewSeries
        .Name = Ws.Range("A4")
        .XValues = "={""M"";""E"";""F"";""A""}"
        .Values = "=" & Ws.Name & "!$G$11," & Ws.Name & "!$G$15," & Ws.Name & "!$G$19," & Ws.Name & "!$G$22"
        With .Points(1).Format.Fill
            .Visible = msoTrue
            .ForeColor.RGB = RGB(255, 255, 0)
            .Solid
        End With
    End With
End With
Set Ch = Nothing
Ws.Name = Worksheets("Interface").Range("C3").Value
Set Ws = Nothing
End Sub

[ecailley]

Marci beaucoup Mercatog c'est top, ça fait 4 jours que j'épluche le net pour trouver, j'ai encore pas mal de progrès à faire...
En tout cas merci pour le coup de main.
Je passe le sujet en résolu.