Discussion :

[flo1411]

Bonjour à tous,
J'ai un tableau qui ressemble à ça :

CI	           Nb Heures
713501.MP 	4:00:00
713501.SC 	5:00:00
713594	   	6:00:00
713573	   	7:00:00
713501.DE 	8:00:00
713501.AM    	4:00:00
713571	   	5:00:00
713501.DM 	6:00:00
713501.AM 	7:00:00
713573	   	8:00:00

Ce que je veux faire, c'est comparer les cellules de la première colonne et si il y a des doublons, additionner les nombres d'heures dans la ligne que je vais garder et supprimer l'autre ligne.
Mais je ne vois pas du tout comment faire... Pouvez-vous m'aider svp ?

Voilà le code que j'ai réalisé :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Dim fin As Integer
fin = 30
For k = 22 To fin Step 1
    If Cells(k, 5).Value = Cells(k + 1, 5).Value Then
        Cells(k, 6).Value = Cells(k, 6).Value + Cells(k + 1, 6).Value
        Cells(k + 1, 1).EntireRow.Delete
        k = k - 1
        fin = fin - 1
    End If
Next

Je dois avoir une boucle infinie quelque part parce que la macro ne s'arrète pas et je dois toujours arrêter Excel...

[gFZT82]

Bonjour,

Essaie comme cela.
A supposer que les lignes à tester débutent à la ligne 22 et terminent à la dernière ligne renseignée de la colonne A.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub test()
Dim i As Long
Dim C As Range
    i = 22
    With Worksheets("Feuil1")
    Do Until .Range("A" & i) = ""
        Set C = .Range(.Range("A" & i), .Range("A" & Rows.Count).End(xlUp)).Offset(1, 0).Find(.Range("A" & i).Value, , xlValues, xlWhole)
        If Not C Is Nothing Then
            .Range("A" & i).Offset(0, 1) = .Range("A" & i).Offset(0, 1) + C.Offset(0, 1)
            C.EntireRow.Delete Shift:=xlUp
        End If
        i = i + 1
    Loop
    End With
End Sub

Cordialement.

[Daniel.C]

Bonjour,

Mes deux sous :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub test()
    Dim C As Range
    For Each C In Range([A2], Cells(Rows.Count, 1).End(xlUp))
        C.Offset(, 2) = Application.SumIf([A:A], C.Value, [B:B])
    Next C
    Range([B2], Cells(Rows.Count, 2).End(xlUp)).Value = Range([C2], Cells(Rows.Count, 3).End(xlUp)).Value
    [B:B].NumberFormat = "[hh]:mm"
    [C:C].ClearContents
    Range([A2], Cells(Rows.Count, 1).End(xlUp)).Resize(, 2).RemoveDuplicates Columns:=Array(1, 2), Header:=xlYes
End Sub

[sophieceuzin]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Sub SousTotal()
  Set d = CreateObject("Scripting.Dictionary")
  For Each C In Range("a2", [a65000].End(xlUp))
     d(C.Value) = d(C.Value) + C.Offset(, 1).Value
  Next C
  Rows("2:100").Delete
  [A2].Resize(d.Count, 1) = Application.Transpose(d.keys)
  [B2].Resize(d.Count, 1) = Application.Transpose(d.items)
  [B:B].NumberFormat = "[hh]:mm"
End Sub

Ceuzin

[flo1411]

Merci sophieceuzin ça fonctionne