Discussion :

[sebastien-16600]

Bonjour,
Dans mon tableau, j'ai plusieurs colonne pour inscrire plusieurs informations sur des personnes en utilisant un userform.
J'aimerais savoir comment je peux faire pour rechercher si j'ai deja rentrer cette personne en recherchant dans les colonnes nom et prenom, pour pouvoir ensuite recuperer le numero de la ligne qui correspond a cette personne pour inserer d'autre infos dans les colonne de cette ligne.
J'ai vu qu'il y avait la fonction find mais je ne comprends pas vraiment son fonctionnement.
merci

[Theze]

Bonjour,

Regarde ce qui suit et adapte :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
 
Sub test()
 
    'pour le test de recherche
    MsgBox Rechercher("Lebouteiller", "Sébastien")
 
End Sub
 
Function Rechercher(Nom As String, Prenom As String) As String
 
    Dim plage As Range
    Dim Cel As Range
    Dim Adr As String
    Dim Message As String
 
    'sur la feuille "Feuil1" en colonne A à partire de A2 <-- à adapter...
    With Worksheets("Feuil1")
 
        Set plage = .Range(.Cells(2, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
    'défini le message par défaut
    Message = "'" & Nom & " " & Prenom & "' n'existe pas dans la base de données !"
 
    'effectue la recherche exacte du nom
    Set Cel = plage.Find(Nom, , xlValues, xlWhole)
 
    'si trouvé, compare le prénom. Si le prénom correspond aussi, change le message
    If Not Cel Is Nothing Then
 
        Adr = Cel.Address
 
        Do
 
            If Cel.Offset(, 1).Value = Prenom Then
 
                Message = "'" & Nom & " " & Prenom & "' existe dans la base de données et est situé(e) à la ligne " & Cel.Row
 
                Exit Do
 
            End If
 
            Set Cel = plage.FindNext(Cel)
 
        Loop While Adr <> Cel.Address
 
    End If
 
    'retourne le message
    Rechercher = Message
 
End Function

Hervé.

[sebastien-16600]

Merci je vais testé

[sebastien-16600]

Encore merci pour votre aide et vos explications,
J'ai compris comment fonctionner le code que vous m'avez ecrit mais a la place du message je voudrais juste etre en mesure de recuperer le numero de la ligne pour l'integrer dans un .Range("A" & Lig) pour remplir un tableau.
Par exemple si la recherche n'aboutit pas alors la fonction s'arrete et mon code continue mais si elle trouve une correpondance, je voudrais recuperer le numero de la ligne pour finir de remplir des informations concernant la personne recherchée.

Je vais continuer à essayer, c'est trés existant la programmation...BIZ

merci

je bloque pour attribuer le numero de la ligne trouvé dans une variable.
J'ai trouvé comment faire pour que le remplissage du tableau se fasse differemment suivant le resultat de la recherche mais je galere pour affecter le numero de la ligne a une variable
J'ai essayé de mettre dans le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
  If Cel.Offset(, 1).Value = Prenom Then
                LigEx = Cel.Row
                Message = "V"
 
                Exit Do

la variable LigEx serait reutiliser dans le reste du code.

merci

[gFZT82]

Bonjour,

Une adaptation du code de Hervé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Sub test()
Dim Ligne As Long
    'pour le test de recherche
    Ligne = RechercherLigne("Lebouteiller", "Sébastien")
    If Ligne > 0 Then
        MsgBox "Le nom a été trouvé à la ligne " & Ligne
    Else
        MsgBox "Le nom n'a pas été trouvé "
    End If
End Sub
Function RechercherLigne(Nom As String, Prenom As String) As Long
Dim Plage As Range
Dim Cel As Range
Dim Adr As String
Dim Message As String
 
    'sur la feuille "Feuil1" en colonne A à partire de A2 <-- à adapter...
    With Worksheets("Feuil1")
        Set Plage = .Range(.Cells(2, 1), .Cells(.Rows.Count, 1).End(xlUp))
    End With
 
    'défini le message par défaut
    Message = "'" & Nom & " " & Prenom & "' n'existe pas dans la base de données !"
 
    'effectue la recherche exacte du nom
    Set Cel = Plage.Find(Nom, , xlValues, xlWhole)
    'si trouvé, compare le prénom. Si le prénom correspond aussi, change le message
    If Not Cel Is Nothing Then
        Adr = Cel.Address
        Do
            If Cel.Offset(, 1).Value = Prenom Then
                LigEx = Cel.Row
                Exit Do
            End If
            Set Cel = Plage.FindNext(Cel)
        Loop While Adr <> Cel.Address
    End If
    'retourne le message
    RechercherLigne = LigEx
End Function

Cordialement.